在 PL/SQL 函数中的 EXECUTE IMMEDIATE 中使用 UDT 变量

Question

我正在使用 Oracle 11g 在 PL/SQL 上构建一个函数。

我试图在 EXECUTE IMMEDIATE 语句中使用 table 变量，但它不起作用，如您所见：

ERROR at line 1:
ORA-00904: "CENTER_OBJECTS": invalid identifier
ORA-06512: at "HIGIIA.KNN_JOIN", line 18

我使用的代码是...

首先，类型定义

CREATE TYPE join_t IS OBJECT (
   inn                          char(40),
   out                        char(40)
);
/


CREATE TYPE join_jt IS TABLE OF join_t;
/

CREATE TYPE blob_t IS OBJECT (
   id           CHAR(40),
   fv           BLOB
);
/

CREATE TYPE blob_tt IS TABLE OF blob_t;
/

函数为：

create or replace FUNCTION knn_join (tab_inn IN varchar2, tab_out IN varchar2, blob_col1 IN varchar2, blob_col2 IN varchar2, dist_alg in VARCHAR2, kv in NUMBER ) RETURN join_jt
IS
var_fv BLOB;
var_id CHAR(40);
center_objects blob_tt := blob_tt();
retval join_jt := join_jt ();
join_table join_jt := join_jt();
sql_stmt1 varchar2(400);
sql_stmt2 varchar2(400);
BEGIN
    sql_stmt1 := 'SELECT blob_t(ROWIDTOCHAR(rowid),' || blob_col1 || ') FROM ' || tab_out;
    sql_stmt2 := 'SELECT join_t(ROWIDTOCHAR(r.rowid), center_objects(idx).id) FROM ' || tab_inn || ' r  WHERE ' || dist_alg || '_knn(r.' || blob_col2 || ',  center_objects(idx).' ||   blob_col1 || ')<=' || kv;
    dbms_output.put_line(sql_stmt2);    
    EXECUTE IMMEDIATE sql_stmt1 BULK COLLECT INTO center_objects;
    for idx in center_objects.first()..center_objects.last()
                loop
                --SELECT join_t(ROWIDTOCHAR(r.rowid), center_objects(idx).id) BULK COLLECT INTO join_table FROM londonfv r WHERE manhattan_knn(r.fv, center_objects(idx).fv) <=5;
                EXECUTE IMMEDIATE sql_stmt2 BULK COLLECT INTO join_table;   
            for idx2 in join_table.first()..join_table.last()
                   loop
                            retval.extend();
                        retval(retval.count()) := join_table(idx2);
                       end loop;
            end loop;
RETURN retval;
END;
/

到运行函数：

select * from TABLE(knn_join('london','cophirfv','fv','fv','manhattan',5));

我正在尝试使用运行语句 'SELECT join_t(ROWIDTOCHAR(r.rowid), center_objects(idx).id) BULK COLLECT INTO join_table FROM london r WHERE manhattan_knn(r.fv, center_objects(idx).fv) <=5' 使用 EXECUTE IMMEDIATE，但它不起作用，因为我在其中使用了一个变量。

有人可以帮助我吗？

提前致谢！

Answer 1

您不能在动态 SQL 语句中引用局部 PL/SQL 变量，因为它超出了动态调用使用的 SQL 上下文的范围。您可以替换您的第一个电话：

SELECT join_t(ROWIDTOCHAR(r.rowid), center_objects(idx).id) FROM ' ...

绑定变量：

SELECT join_t(ROWIDTOCHAR(r.rowid), :id FROM ' ...
EXECUTE IMMEDIATE ... USING center_objects(idx).id ...

但是当对象属性也是可变的时候你不能做什么:

... ',  center_objects(idx).' ||   blob_col1 || ')<='...

虽然 - 至少在您展示的示例中 - 唯一可用的对象属性名称是 fv，而不管传递给函数的 table 列名称 - 所以这可能是硬编码；因此可以使用绑定变量：

... ',  :fv)<='...
EXECUTE IMMEDIATE ... USING center_objects(idx).id, center_objects(idx).fv ...

和 kv 值也应该是一个绑定变量，所以你最终会得到：

create or replace FUNCTION knn_join (tab_inn IN varchar2, tab_out IN varchar2,
  blob_col1 IN varchar2, blob_col2 IN varchar2, dist_alg in VARCHAR2, kv in NUMBER )
RETURN join_jt
IS
  center_objects blob_tt := blob_tt();
  retval join_jt := join_jt ();
  join_table join_jt := join_jt();
  sql_stmt1 varchar2(400);
  sql_stmt2 varchar2(400);
BEGIN
  sql_stmt1 := 'SELECT blob_t(ROWIDTOCHAR(rowid),' || blob_col1 || ') FROM ' || tab_out;
  sql_stmt2 := 'SELECT join_t(ROWIDTOCHAR(r.rowid), :id) FROM ' || tab_inn || ' r  WHERE '
    || dist_alg || '_knn(r.' || blob_col2 || ',  :fv)<= :kv';
  dbms_output.put_line(sql_stmt1);    
  dbms_output.put_line(sql_stmt2);    
  EXECUTE IMMEDIATE sql_stmt1 BULK COLLECT INTO center_objects;
  for idx in center_objects.first()..center_objects.last()
  loop
    EXECUTE IMMEDIATE sql_stmt2 BULK COLLECT INTO join_table
    USING center_objects(idx).id, center_objects(idx).fv, kv;   
    for idx2 in join_table.first()..join_table.last()
    loop
      retval.extend();
      retval(retval.count()) := join_table(idx2);
    end loop;
  end loop;
  RETURN retval;
END;
/

据我所知，您仍然可以在动态 SQL 语句中执行连接，并消除循环和对中间 center_objects 和 join_table 集合的需要：

create or replace FUNCTION knn_join (tab_inn IN varchar2, tab_out IN varchar2,
  blob_col1 IN varchar2, blob_col2 IN varchar2, dist_alg in VARCHAR2, kv in NUMBER )
RETURN join_jt
IS
  retval join_jt;
  sql_stmt varchar2(400);
BEGIN
  sql_stmt := 'SELECT join_t(ROWIDTOCHAR(tinn.rowid), ROWIDTOCHAR(tout.rowid))'
    || ' FROM ' || tab_inn || ' tinn JOIN ' || tab_out || ' tout'
    || ' ON ' || dist_alg || '_knn(tinn.fv, tout.fv) <= :kv';

  dbms_output.put_line(sql_stmt);
  EXECUTE IMMEDIATE sql_stmt BULK COLLECT INTO retval USING kv;
  RETURN retval;
END;
/

当您按照显示的方式调用它时：

select * from TABLE(knn_join('london','cophirfv','fv','fv','manhattan',5));

这相当于硬编码：

SELECT join_t(ROWIDTOCHAR(tinn.rowid), ROWIDTOCHAR(tout.rowid))
FROM london tinn
JOIN cophirfv tout
ON manhattan_knn(tinn.fv, tout.fv) <= 5

... 所以我想您可以验证该硬编码版本是否首先为您提供了预期的结果。（当然，将示例数据和预期结果添加到问题中会有所帮助）。

连接条件可能很昂贵，这取决于函数在做什么，每个 table 中的行数（因为每个 table 中的每一行都必须与中的每一行进行比较另一个），你是否真的有其他过滤器，等等。循环版本会更糟。没有更多信息，无论如何也没什么可做的。

顺便说一句，使用 varchar2 而不是 char 作为对象属性会更正常；这也是 the rowidtochar() function.

返回的数据类型

在 PL/SQL 函数中的 EXECUTE IMMEDIATE 中使用 UDT 变量

Using UDT variable within an EXECUTE IMMEDIATE in a PL/SQL function

sql

oracle

plsql

execute-immediate