MKVMerge 和批处理文件

Question

我一直在使用批处理文件来编辑不同电视剧的元数据和曲目'，到目前为止一切顺利。不过我现在正在做的剧，每一集都有感叹号。

文件格式始终采用以下格式：S00E00 - 剧集名称

这是我在大多数节目中使用的模板。

setlocal enabledelayedexpansion
set mkvmerge="C:/Program Files/MKVToolNix\mkvmerge.exe"
set output_folder="C:\Games-And-Stuff\#Anime\zAnime\_Muxing\[[EPISODE_NAME]]"
for /r %%a in (*.mkv) do (
    set ep=%%~na
    set ep_name=!ep:~9!
    set ep_num=!ep:~4,2!
    call %mkvmerge% -o "%output_folder%\%%~na.mkv" --track-name ^"0:!ep_name!^" --track-name ^"1:[ENG] AAC 5.1^" --track-name ^"2:[JAP] AAC 2.0^" --track-name ^"3:[ENG] Signs and Songs^" --track-name ^"4:[ENG]^" --language 0:und --language 1:eng --language 2:jpn --language 3:eng --language 4:eng --default-track 0:yes --default-track 1:yes --default-track 2:no --default-track 3:yes --default-track 4:no --forced-track 3:yes "%%a" --track-order 0:0,0:1,0:2,0:3,0:4 --title ^"? - Episode !ep_num! - !ep_name!^"
)

我的问题是在 call %mkvmerge% 中使用带有感叹号的变量。有没有办法解决这个问题？

Answer 1

setlocal DISabledelayedexpansion
set "mkvmerge=C:\Program Files\MKVToolNix\mkvmerge.exe"
set "output_folder=C:\Games-And-Stuff\#Anime\zAnime\_Muxing\[[EPISODE_NAME]]"
for /r %%a in (*.mkv) do (
    set ep=%%~na
    call :merge
)
goto :eof

:merge
set ep_name=%ep:~9%
set ep_num=%ep:~4,2%
call "%mkvmerge%" -o "%output_folder%\%ep%.mkv" --track-name "0:%ep_name%" --track-name "1:[ENG] AAC 5.1" --track-name "2:[JAP] AAC 2.0" --track-name "3:[ENG] Signs and Songs" --track-name "4:[ENG]" --language 0:und --language 1:eng --language 2:jpn --language 3:eng --language 4:eng --default-track 0:yes --default-track 1:yes --default-track 2:no --default-track 3:yes --default-track 4:no --forced-track 3:yes "%ep%" --track-order 0:0,0:1,0:2,0:3,0:4 --title "? - Episode %ep_num% - %ep_name%"
goto :eof

（由于缺少示例未经测试）

delayedexpansion如果使用子程序可以避免。语法 SET "var=value"（其中值可能为空）用于确保分配的值中不包含任何杂散尾随空格。 set /a 可以放心使用 "quoteless".

MKVMerge 和批处理文件

MKVMerge and Batch File

batch-file

escaping

mkv