在 cython 中实例化从 class 派生的 C++ 结构

Question

我正在尝试使用 Cython 将 Python 连接到 Bullet Physics C++ 库。我想以 C 速度或接近 C 的速度执行此操作，并且从 Python 进行最少的变量打包和解包。我能够使用这种方法为 OpenGL 创建一个 Cython 接口（尽管与 Bullet Physics 相比，OpenGL 有一个更简单的非 object-oriented C API）。我的 OpenGL 接口运行良好，但在与 Bullet Physics 接口方面进展缓慢。

我已经阅读了 Cython C++ 教程和其他相关文章，但到目前为止还没有成功。

Bullet Physics 的组织有点复杂，但对于这个例子，希望知道 btDbvtBroadphase 是一个 struct 就足够了，它派生自 btBroadphaseInterface class。正如您可能知道的那样，结构可以从 classes 派生（从它们继承）并且两者之间没有太大区别——至少在 C++ 中是这样。然而，Cython 似乎只允许 "new" 在 class 上完成，而不是在结构上。我认为这导致了我的第一个问题。

Bullet Physics .h 文件中的声明如下所示：

class btBroadphaseInterface
{
    ...

和

struct  btDbvtBroadphase : btBroadphaseInterface
{
    ...

我试图在 Cython 中有效复制的非常简单的 C++ 代码行是：

btBroadphaseInterface* broadphase = new btDbvtBroadphase();

因此，由于在 Cython 中我不能像在 C++ 中那样在 btDbvtBroadphase 结构上执行 "new"，我如何实例化这个从 class 派生的结构，以便所有调用初始化器并在其中设置方法？

我看到一些关于 Cython 中继承限制的参考资料。

我显然可以 malloc() the space 结构，但我认为这对我帮助不大。我看不出任何类型的转换会有什么帮助。

我有 Cython“.pxd”的东西显示我如何从 .h 文件中执行 cdef extern 但我不认为这有助于澄清这个问题，所以我将省略它，除非有人认为它可能有帮助。

我尝试了很多 cdef 变体，但都没有成功。这是现在的样子：

cdef extern from "bullet/btBulletDynamicsCommon.h":
    cdef cppclass btBroadphaseInterface:
        pass

    cdef cppclass btDbvtBroadphase(btBroadphaseInterface):
        pass

当我尝试编写一个构造函数时，它将对派生自 class 的结构执行 "new"，如下所示：

cdef class PbtDbvtBroadphase:
    cdef btBroadphaseInterface *bp

    def __cinit__(self):
        self.bp=<btBroadphaseInterface *> new btDbvtBroadphase()

编译器失败：

Error compiling Cython file: ------------------------------------------------------------ ...

cdef class PbtDbvtBroadphase: cdef btBroadphaseInterface *bp
def __cinit__(self):
    self.bp=<btBroadphaseInterface *> new btDbvtBroadphase()
^

fun4.pyx:173:46: new operator can only be applied to a C++ class

编辑：改进的标题，我最初输入的只是一串关键字

Edit2：添加了 cdef 和编译器输出

我接受了非常耐心的@DavidW 的回答，因为它证明了事情应该有效。我认为发生的事情是我有一个杂散的 .pxd 文件，其名称与我的 .pyx 文件的基本名称相同，并且它被集成到构建中 即使我没有使用 distutils 而只是来自 cython命令行。 .pxd 是早期测试遗留下来的，当时我认为我的构建方法可能不会给出与 distutils/setup.py 方法相同的结果。我确信我的构建方法与问题无关，然后回到我的首选方法（将 cdefs 放入 .pyx 文件中，然后通过一个简单的 shell 脚本进行编译和链接，如下面的评论之一所示) 但 .pxd 文件仍然存在，并且在我不知情的情况下仍然被 cython 编译器悄悄地拉入。当我注意到编译时出现 "redeclared" 错误时，我发现了这一点。我错过了正在滚动的 "redeclared"，只看到了新构造函数尝试的错误。

Answer 1

最简单的选择就是告诉 Cython 它是 class:

cdef cppclass btDvbtBroadphase(btBroadphaseInterface):
    #etc

C++ 中 struct 和 class 之间的区别只是成员的默认可见性。从 Cython 的角度来看，它的行为相同，因此您告诉 Cython 的内容与 C++ 代码不匹配并不重要。

（也可能值得省略告诉 Cython 关于继承的事情。如果你不在 Cython 中使用继承，那么它就不需要知道。不重现完整的层次结构而只重现位通常更容易你需要）

编辑： 以下代码适用于我：

header.hpp:

class btBroadphaseInterface {

};

struct btDbvtBroadphase : btBroadphaseInterface {

};

pymod.pyx:

cdef extern from "header.hpp":
    cppclass btBroadphaseInterface:
        pass

    cppclass btDbvtBroadphase(btBroadphaseInterface):
        pass

cdef class PyBroadphase:
    cdef btBroadphaseInterface* pt
    def __cinit__(self):
        self.pt = new btDbvtBroadphase()

    def __dealloc__(self):
        del self.pt

setup.py

from distutils.core import setup, Extension
from Cython.Build import cythonize

setup(ext_modules = cythonize(Extension(
           "pymod",                                # the extension name
           sources=["pymod.pyx",], # the Cython source and
                                                  # additional C++ source files
           language="c++",                        # generate and compile C++ code
      )))

在 cython 中实例化从 class 派生的 C++ 结构

Instantiating a C++ struct derived from a class in cython

python

inheritance

bullet

cython

^