使用 `once-only` 宏

Question

在 Practical Common Lisp 的第 8 章末尾，Peter Seibel 介绍了 once-only 宏。其目的是减轻用户定义宏中变量评估的一些微妙问题。请注意，此时我并没有像在其他一些帖子中那样试图理解这个宏是如何工作的，而是试图了解如何正确使用它：

(defmacro once-only ((&rest names) &body body)
  (let ((gensyms (loop for n in names collect (gensym))))
    `(let (,@(loop for g in gensyms collect `(,g (gensym))))
      `(let (,,@(loop for g in gensyms for n in names collect ``(,,g ,,n)))
        ,(let (,@(loop for n in names for g in gensyms collect `(,n ,g)))
           ,@body)))))

以下是一个示例（不正确的）人为设计的宏，它试图展示几个变量评估问题。它声称通过一些增量迭代一系列整数，return范围：

(defmacro do-range ((var start stop delta) &body body)
  "Sample macro with faulty variable evaluations."
  `(do ((,var ,start (+ ,var ,delta))
        (limit ,stop))
       ((> ,var limit) (- ,stop ,start))
     ,@body))

例如，(do-range (i 1 15 3) (format t "~A " i)) 应该打印 1 4 7 10 13 然后 return 14.

问题包括 1) 可能捕获第二次出现的 limit，因为它作为自由变量出现，2) 可能捕获第一次出现的绑定变量 limit，因为它与出现在宏参数中的其他变量一起出现在表达式中，3) 无序评估，因为 delta 将在 stop 之前评估，即使 stop 出现在 [=19 之前=] 在参数列表中，以及 4) 多变量评估，因为 stop 和 start 被评估了不止一次。据我了解，once-only 应该可以解决这些问题：

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta limit)
    `(do ((,var ,start (+ ,var ,delta))
          (limit ,stop))
         ((> ,var limit) (- ,stop ,start))
       ,@body)))

然而，(macroexpand '(do-range (i 1 15 3) (format t "~A " i))) 抱怨 limit 是一个未绑定的变量。如果我改用 with-gensyms，它应该只处理上面的问题 1 和 2，扩展会顺利进行。

这是 once-only 宏的问题吗？ once-only 是否真的解决了上面列出的所有问题（也许还有其他问题）？

Answer 1

一次性宏

要消除 N 未使用的警告，我会将宏更改为：

(defmacro once-only ((&rest names) &body body)
  (let ((gensyms (loop for nil in names collect (gensym))))
                           ; changed N to NIL, NIL is ignored
    `(let (,@(loop for g in gensyms collect `(,g (gensym))))
      `(let (,,@(loop for g in gensyms for n in names collect ``(,,g ,,n)))
        ,(let (,@(loop for n in names for g in gensyms collect `(,n ,g)))
           ,@body)))))

此宏的目的是确保表达式仅按定义的顺序计算一次。为此，它将引入新的 uninterned 变量并将评估结果绑定到这些变量。在宏内部，新变量可用。提供宏本身是为了方便编写宏。

在 DO-RANGE 中使用 ONCE-ONLY

您使用 ONCE-ONLY 的示例：

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta limit)
    `(do ((,var ,start (+ ,var ,delta))
          (limit ,stop))
         ((> ,var limit) (- ,stop ,start))
         ,@body)))

为什么 once-only 列表中有 LIMIT？ limit 在那里未定义。 LIMIT在ONCE-ONLY形式内部用作符号，但外部没有绑定。

ONCE-ONLY 期望名称列表是符号列表，并且这些名称绑定到表单。在你的情况下 limit 是一个符号，但它是未定义的。

我们需要从姓名列表中删除 limit：

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta)
    `(do ((,var ,start (+ ,var ,delta))
          (limit ,stop))
         ((> ,var limit) (- ,stop ,start))
         ,@body)))

现在，LIMIT 该怎么办？鉴于 once-only 为名称提供绑定，包括 STOP，我们可以删除符号 LIMIT 并将其替换为 ,stop:

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta)
    `(do ((,var ,start (+ ,var ,delta)))
         ((> ,var ,stop) (- ,stop ,start))
       ,@body)))

示例：

CL-USER 137 > (pprint
               (macroexpand
                '(do-range (i 4 10 2)
                   (print i))))

(LET ((#1=#:G2170 4)
      (#3=#:G2171 10)
      (#2=#:G2172 2))
  (DO ((I #1# (+ I #2#)))
      ((> I #3#) (- #3# #1#))
   (PRINT I)))

使用 `once-only` 宏

Using the `once-only` macro

macros

common-lisp

practical-common-lisp