Gradle: 解析后无法更改配置“:compile”的依赖项

Question

我正在使用带有 Gradle 支持插件 1.3.8 的 Netbeans 8.0.2。

我添加了一个生成 uber-Jar 的任务，同时排除了一些签名文件，但是当我运行该任务时，它在第 38 行（compile group 行）显示错误如下：

apply plugin: 'java'
apply plugin: 'application'

mainClassName = 'br.com.myproject.Sample'
sourceCompatibility = '1.8'
[compileJava, compileTestJava]*.options*.encoding = 'UTF-8'
version='1.0.0'

// For DEBUG to work
ext.mainClass = mainClassName

task uniqueJar(type: Jar) {
    baseName = project.name

    from(configurations.compile.collect { it.isDirectory() ? it : zipTree(it) }) {
        exclude "META-INF/*.SF"
        exclude "META-INF/*.DSA"
        exclude "META-INF/*.RSA"
    }

    manifest {
        attributes 'Implementation-Title': project.name,  
                'Implementation-Version': version,
                'Main-Class': mainClassName
    }
    with jar
}

repositories {
    mavenCentral()
    // You may define additional repositories, or even remove "mavenCentral()".
    // Read more about repositories here:
    //   http://www.gradle.org/docs/current/userguide/dependency_management.html#sec:repositories
}

dependencies {
    // https://mvnrepository.com/artifact/org.eclipse.paho/org.eclipse.paho.client.mqttv3
    compile group: 'org.eclipse.paho', name: 'org.eclipse.paho.client.mqttv3', version: '1.1.1' // line 38


    testCompile group: 'junit', name: 'junit', version: '4.10'
}

错误信息：

Executing: gradle unique Jar Arguments: [uniqueJar, -c, D:\NetBeansProjects\testeMqtt\settings.gradle]

FAILURE: Build failed with an exception.

Where: Build file 'D:\NetBeansProjects\testeMqtt\build.gradle' line: 38

What went wrong: A problem occurred evaluating root project 'testeMqtt'.

Cannot change dependencies of configuration ':compile' after it has been resolved.

尝试：运行使用 --stacktrace 选项获取堆栈跟踪。运行使用 --info 或 --debug 选项以获得更多日志输出。

构建失败

总时间：0.102 秒

如何修复 uber-Jar 任务？

Answer 1

使用 Shadow gradle plugin 生成 uber-Jar 解决了我的问题：

apply plugin: 'java'
apply plugin: 'application'

mainClassName = 'br.com.myproject.Sample'
sourceCompatibility = '1.8'
[compileJava, compileTestJava]*.options*.encoding = 'UTF-8'
version='1.0.0'

// For DEBUG to work
ext.mainClass = mainClassName

repositories {
    mavenCentral()
}

dependencies {
    compile 'org.eclipse.paho:org.eclipse.paho.client.mqttv3:1.1.1'
    testCompile group: 'junit', name: 'junit', version: '4.10'
}

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.github.jengelman.gradle.plugins:shadow:1.2.4'
    }
}

apply plugin: 'com.github.johnrengelman.shadow'

Gradle: 解析后无法更改配置“:compile”的依赖项

Gradle: Cannot change dependencies of configuration ':compile' after it has been resolved

java

gradle

gradle-plugin