使用 XSL 转换版本 1 将子节点移动到兄弟节点级别

Question

我的 XSL：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="text/text()" name="tokenize">
        <xsl:param name="text" select="."/>
        <xsl:param name="separator" select="','"/>
        <xsl:choose>
            <xsl:when test="not(contains($text, $separator))">
                <item>
                    <xsl:value-of select="normalize-space($text)"/>
                </item>
            </xsl:when>
            <xsl:otherwise>
                <item>
                    <xsl:value-of select="normalize-space(substring-before($text, $separator))"/>
                </item>
                <xsl:call-template name="tokenize">
                    <xsl:with-param name="text" select="substring-after($text, $separator)"/>
                </xsl:call-template>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

我的输入：

<root>
<text>Item1, Item2, Item3</text>
</root>

我的输出：

<root>
    <text>
        <item>Item1</item>
        <item>Item2</item>
        <item>Item3</item>
    </text>
</root>

我想要的输出：

<root>
<item>Item1</item>
<item>Item2</item>
<item>Item3</item>
</root>

你能帮忙吗？

Answer 1

您需要做的就是添加另一个匹配 text 的模板，这样它就不会被身份模板匹配来复制它。新模板只需要对children进行处理，并不真正复制text节点本身。

<xsl:template match="text">
    <xsl:apply-templates select="node()"/>
</xsl:template>

或者，您可以更改现有 tokenize 模板的模板匹配以匹配 text 节点，而不是 child 文本节点。

<xsl:template match="text" name="tokenize">

Answer 2

只需添加另一个模板：

<xsl:template match="text">
    <xsl:apply-templates/>
</xsl:template>

此模板将匹配 text 并处理其子元素（不创建 <text> 标记。

使用 XSL 转换版本 1 将子节点移动到兄弟节点级别

move child node to sibling node level using XSL Transform version 1

xml

xslt

xslt-1.0