QT Creator：如何为自定义小部件生成库和测试可执行文件

Question

有以下文件：

MyWidget
   |- MyWidget.cpp
   |- MyWidget.hpp
   |- MyWidget_UnitTest.cpp

我想立即生成以下文件：

MyWidget.dll（或等效于非 windows OS）
MyWidget_UnitTest.exe（或等效于非 windows OS）

因此很容易测试小部件的错误，而且还可以在其他小部件或项目中获得结果。

我试图操作 .pro 文件，但没有成功：

# ONLY TESTING UNIT
QT       += core gui
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
TARGET = MyWidget_UnitTest
TEMPLATE = app
SOURCES +=\
    MyWidget.cpp \
    MyWidget_UnitTest.cpp
HEADERS  += \
    MyWidget.hpp
CONFIG += c++11 -Wall

#ONLY LIB
QT       += core gui
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
TARGET = MyWidget_UnitTest
TEMPLATE = lib
SOURCES +=\
    MyWidget.cpp \
    MyWidget_UnitTest.cpp
HEADERS  += \
    MyWidget.hpp
CONFIG += c++11 -Wall
CONFIG += dll

我无法将两者合并到一个项目中。

可能会添加更多结果：静态库与动态库等

Answer 1

使用不同的 CONFIG 标志：

QT += core gui
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
SOURCES +=MyWidget.cpp
HEADERS += MyWidget.hpp
CONFIG += c++11 -Wall

testmode {
    # ONLY TESTING UNIT
    TARGET = MyWidget_UnitTest
    SOURCES += MyWidget_UnitTest.cpp
    TEMPLATE = app
}

libmode {
    #ONLY LIB
    TARGET = MyWidget
    TEMPLATE = lib
    CONFIG += dll
}

同时构建：

qmake "CONFIG+=libmode"
make
qmake "CONFIG+=testmode"
make

Answer 2

使用 SUBDIRS 项目组织。

project_dir/
  src/
    your_dll/
      ... sources, headers ...
      your_dll.pro
    your_exe/
      ... sources, headers ...
      your_exe.pro
  project_dir.pro

project_dir.pro

TEMPLATE = subdirs
CONFIG += ordered

SUBDIRS += src/your_dll
SUBDIRS += src/your_exe

your_exe.depends = your_dll

your_exe.pro

TARGET = your_exe
TEMPLATE = app
QT += widgets
LIBS += -L$${YOUR_DLL_PATH} -lyour_dll

etc...

your_dll.pro

TARGET = your_dll
TEMPLATE = lib
QT += widgets

etc...

现在构建时，将构建 DLL 和 EXE，并将 EXE 链接到 DLL。

QT Creator：如何为自定义小部件生成库和测试可执行文件

QT Creator: How to generate the library and testing executable for a custom widget

c++

dll

qt

unit-testing

qt-creator