如何禁用然后重新启用 Arduino 的看门狗中断？

Question

我正在尝试使用看门狗中断作为定时器，让我的 Arduino 休眠一段时间。我的问题在于，在唤醒时，我需要执行超过 8 秒的操作。

目前，我的 Arduino 将休眠 1 分钟，使用看门狗的连续中断将其唤醒并使其重新进入休眠状态。然而，1分钟后，我开始进行超过8秒的操作，看门狗中断超时。

我想关闭看门狗定时器，进行操作，然后重新启用它并return休眠。

这是我的代码：

#include "Adafruit_FONA.h"
#include <avr/sleep.h>
#include <avr/power.h>
#include <avr/wdt.h>

#define FONA_RX 10
#define FONA_TX 9
#define FONA_RST 4
#define LED_PIN 8

// this is a large buffer for replies
char replybuffer[255];
char *SMSnumber = "6015962842";
char stack[128] = {'c'};

//Value for watchdog timer interrupt.
volatile int f_wdt = 1;
int seconds = 0;
int minutes = 1;
int hours = 0;
int interval = ((hours*60*60) + (minutes*60) + (seconds))/8;
int timerCounter = 0;

//Setup for pulse sensor.
volatile int Signal;                // holds the incoming raw data
int pulsePin = 0;                   //Pin to read at analog 0 for the pulse.
volatile int IBI = 600;             // int that holds the time interval between beats! Must be seeded!
volatile boolean Pulse = false;     // "True" when User's live heartbeat is detected. "False" when not a "live beat".
volatile int BPM;                   // int that holds raw Analog in 0. updated every 2mS
volatile boolean QS = false;        // becomes true when Arduoino finds a beat.
unsigned long lastTime; // used to time the Pulse Sensor samples
unsigned long thisTime; // used to time the Pulse Sensor samples

//ISR for watchdog timer.
ISR(WDT_vect)
{
  if(f_wdt == 0)
  {
    f_wdt=1;
    timerCounter++;
  }
  else
  {
    Serial.println("WDT Overrun!!!");
  }
}

// We default to using software serial. If you want to use hardware serial
// (because softserial isnt supported) comment out the following three lines 
// and uncomment the HardwareSerial line
#include <SoftwareSerial.h>
SoftwareSerial fonaSS = SoftwareSerial(FONA_TX, FONA_RX);
SoftwareSerial *fonaSerial = &fonaSS;

// Hardware serial is also possible!
//HardwareSerial *fonaSerial = &Serial;

// Use this for FONA 800 and 808s
Adafruit_FONA fona = Adafruit_FONA(FONA_RST);

void setup() {
  pinMode(LED_PIN, OUTPUT);
  digitalWrite(LED_PIN, HIGH);
  delay(3000);
  digitalWrite(LED_PIN, LOW);
  while (!Serial);
  Serial.begin(115200);
  setupGsm();
  setupWdt();
}

void loop()
{
  if(f_wdt == 1)
  {
    if (timerCounter == interval)
    {
      WDTCSR |= _BV(WDTON);
      Serial.println(F("Tried to stop the watchdog."));
      delay(20000);

      //Reset timer.
      timerCounter = 0;
      WDTCSR |= _BV(WDIE);
      Serial.println(F("Tried to re-enable watchdog."));
    }

    /* Don't forget to clear the flag. */
    f_wdt = 0;

    /* Re-enter sleep mode. */
    enterSleep();
  }
  else
  {
    /* Do nothing. */
  }
}

void setupGsm()
{
  fonaSerial->begin(4800);
  while (! fona.begin(*fonaSerial)) {
    Serial.println(F("Couldn't find FONA"));
    delay(1000);
  }
  digitalWrite(LED_PIN, HIGH);
  delay(500);
  digitalWrite(LED_PIN, LOW);
  delay(500);
  digitalWrite(LED_PIN, HIGH);
  delay(500);
  digitalWrite(LED_PIN, LOW);
  delay(500);
  digitalWrite(LED_PIN, HIGH);
}

void enterSleep(void)
{
  set_sleep_mode(SLEEP_MODE_PWR_DOWN);
  sleep_enable();

  /* Now enter sleep mode. */
  sleep_mode();

  /* The program will continue from here after the WDT timeout*/
  sleep_disable(); /* First thing to do is disable sleep. */

  /* Re-enable the peripherals. */
  power_all_enable();
}

void setupWdt()
{
  /*** Setup the WDT ***/

  /* Clear the reset flag. */
  MCUSR &= ~(1<<WDRF);

  /* In order to change WDE or the prescaler, we need to
   * set WDCE (This will allow updates for 4 clock cycles).
   */
  WDTCSR |= (1<<WDCE) | (1<<WDE);

  /* set new watchdog timeout prescaler value */
  WDTCSR = 1<<WDP0 | 1<<WDP3; /* 8.0 seconds */

  /* Enable the WD interrupt (note no reset). */
  WDTCSR |= _BV(WDIE);
}

在 void loop() 函数中，我试图使用 WDTCSR |= _BV(WDTON); 关闭看门狗，但是我的编译器抱怨 WDTON 未在其范围内声明。

Answer 1

不要直接从您的代码访问控制器的寄存器，而是使用 avr/wdt.h 库中的 wdt_enable() 和 wdt_disable() 来启动和停止看门狗定时器。

此外，为了系统的可靠性，实际上保留看门狗定时器运行（而不是禁用它）可能更好，并在长循环和函数中添加对 wdt_reset() 的周期性调用以防止不适当的系统重置。

例如，您可以将代码中的 delay(20000); 行替换为重复语句 20 次的循环：delay(1000); wdt_reset();

如何禁用然后重新启用 Arduino 的看门狗中断？

How to disable then re-enable a watchdog interrupt for Arduino?

arduino

watchdog