适应字段以存储到数据库

Question

假设我有一个字段 content，它是一个 json。我想将它存储在数据库中，以便我的域 class 只保留 1 个字段。（这更像是一项大脑任务；-）

class MyDomain{

   def content

   static constraints = {
        content nullable: false, blank: false, sqlType: "text" // adapter from JSON to String??
    }

def beforeInsert(){
    content = content.toString()
}

def beforeUpdate(){
    content = content.toString()
}

def afterInsert(){
    content = JSON.parse(content) as JSON
}

def afterUpdate(){
    content = JSON.parse(content) as JSON
}

def onLoad(){
    content = JSON.parse(content) as JSON
}

}

我希望我的域对象只公开 content 所以我不想使用另一个字段 String contentAsText 因为它会在外面可见。

在整个 GORM 文档中，我没有找到如何管理它的信息。我尝试了 beforeValidate()/beforeInsert() 和 onLoad() 方法，但没有成功...

如何在持久化之前调整该值？

Answer 1

class MyDomain{

   JSONElement content

   static constraints = {
        content nullable: false, blank: false, sqlType: "text" // adapter from Map to String??
    }

    def setContent(String textContent){
        content = JSON.parse(textContent)
    }
}

我必须做两件事。

将 def content 替换为 JSON content 以使其持久化，请参阅
通过 def setContent().

因为 content 是 JSONElement 使用 JSONObject 和 JSONArray 作为具体类.

Answer 2

您可以为 JSONElement 定义自定义休眠 user-type，如下所述：

在域 class 约束中：

static constraints = {
   content type: JSONObjectUserType
}

用户类型Class:

import org.grails.web.json.JSONObject
import org.hibernate.HibernateException
import org.hibernate.engine.spi.SessionImplementor
import org.hibernate.type.StandardBasicTypes
import org.hibernate.usertype.EnhancedUserType

import java.sql.PreparedStatement
import java.sql.ResultSet
import java.sql.SQLException
import java.sql.Types

class JSONObjectUserType implements EnhancedUserType, Serializable {

    private static final int[] SQL_TYPES = [Types.VARCHAR]

    @Override
    public int[] sqlTypes() {
        return SQL_TYPES
    }

    @Override
    public Class returnedClass() {
        return JSONObject.class
    }

    @Override
    public boolean equals(Object x, Object y) throws HibernateException {
        if (x == y) {
            return true
        }
        if (x == null || y == null) {
            return false
        }
        JSONObject zx = (JSONObject) x
        JSONObject zy = (JSONObject) y
        return zx.equals(zy)
    }

    @Override
    public int hashCode(Object object) throws HibernateException {
        return object.hashCode()
    }

    @Override
    public Object nullSafeGet(ResultSet resultSet, String[] names, SessionImplementor session, Object owner)
        throws HibernateException, SQLException {
        Object jsonObject = StandardBasicTypes.STRING.nullSafeGet(resultSet, names, session, owner)
        if (jsonObject == null) {
            return null
        }
        return new JSONObject((String) jsonObject)
    }

    @Override
    public void nullSafeSet(PreparedStatement preparedStatement, Object value, int index, SessionImplementor session)
        throws HibernateException, SQLException {
        if (value == null) {
            StandardBasicTypes.STRING.nullSafeSet(preparedStatement, null, index, session)
        } else {
            JSONObject jsonObject = (JSONObject) value
            StandardBasicTypes.STRING.nullSafeSet(preparedStatement, jsonObject.toString(), index, session)
        }
    }

    @Override
    public Object deepCopy(Object value) throws HibernateException {
        return value
    }

    @Override
    public boolean isMutable() {
        return false
    }

    @Override
    public Serializable disassemble(Object value) throws HibernateException {
        return (Serializable) value
    }

    @Override
    public Object assemble(Serializable cached, Object value) throws HibernateException {
        return cached
    }

    @Override
    public Object replace(Object original, Object target, Object owner) throws HibernateException {
        return original
    }

    @Override
    public String objectToSQLString(Object object) {
        throw new UnsupportedOperationException()
    }

    @Override
    public String toXMLString(Object object) {
        return object.toString()
    }

    @Override
    public Object fromXMLString(String string) {
        return new JSONObject(string)
    }
}

适应字段以存储到数据库

Adapt field to store to database

grails

grails-orm