AS3 ArgumentError: Error #2025: The supplied DisplayObject must be a child of the caller

Question

我正在制作小黄人游戏。我的 minion 的实例名称是 sideMinion。香蕉掉下来了，一切正常，但我的 removeChild() 不能正常工作。我得到的错误是

Error #2025: The supplied DisplayObject must be a child of the caller. The removeChild() or the hitTestObject doesn't work properly.

这就是我香蕉里的东西。 class:

    package {
    import flash.display.MovieClip;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.MouseEvent;
    import flash.events.Event;
    import flash.events.Event;

    public class banana extends MovieClip {

        var velX: Number = 0;
        var velY: Number = 0;
        var falling: Boolean = false;
        var gravity: Number = 0;

        public function banana() {
            var timing: Timer = new Timer(25, 0);
            timing.addEventListener(TimerEvent.TIMER, moveMe);
            timing.start();

        }

         private function moveMe(event: TimerEvent)
    {
        x += velX;
        y += velY;

        if (falling) velY += gravity;

       /* trace("[BANANA] position:", x, y, "speed:", velX, velY);*/
    }


        public function setSpeed(dx,dy) {
            velX = dx;
            velY = dy;
        }

            public function setSpot(atX,atY){
            this.x=atX;
            this.y=atY;
        }


        public function makeItFall (){
            falling=true;
        }


    }

}

在我的主程序中：

import flash.display.MovieClip;
import flash.events.KeyboardEvent;
import flash.events.Event;

var leftKey:Boolean;
var rightKey:Boolean;
var upKey:Boolean;
var downKey:Boolean;
var jump:Boolean = false;
var xvelocity:int = 9;
var yvelocity:int = 3;
var gravity:Number = 7;


stage.addEventListener(Event.ENTER_FRAME, changeVelocity);
stage.addEventListener(KeyboardEvent.KEY_UP, checkKeyUp);
stage.addEventListener(KeyboardEvent.KEY_DOWN, checkKeyDown);

  function changeVelocity(evt:Event){
        moveMinion();
        yvelocity += gravity;
    }

    function moveMinion(){

        if (leftKey == true){
           sideMinion.x -= xvelocity;
            sideMinion.left();

        }
        if (rightKey == true){
            sideMinion.x += xvelocity;
            sideMinion.right();
        }

    }

    function checkKeyDown(e:KeyboardEvent){
        if (e.keyCode == Keyboard.LEFT){
            leftKey = true;
        }
        else if (e.keyCode == Keyboard.RIGHT){
            rightKey = true;
        }

    }

    function checkKeyUp(e:KeyboardEvent){
        if (e.keyCode == Keyboard.LEFT){
            leftKey = false;
        }
        else if (e.keyCode == Keyboard.RIGHT){
            rightKey = false;
        }

    }

    btnStart.addEventListener(MouseEvent.CLICK, makeItFall);

    function makeItFall(e:MouseEvent){



    var numBananas = 6;
    var theBananas: Array = new Array();
    theBananas = [];
    for (var i = 0; i < numBananas; i++) {
    var aBanana: banana = new banana();
    theBananas.push(aBanana);
    btnStart.visible=false;
    aBanana.y=30;
    theBananas[i].setSpot(Math.random()*450+50,Math.random()*200+20);
    theBananas[i].setSpeed((Math.random()), 1);
    stage.addChild(aBanana);

}   

var health: uint= 1;

addEventListener(Event.ENTER_FRAME, pickUpBananas);

function pickUpBananas(event:Event){
    for( var i= 0; i<theBananas.length; ++i){
        if (sideMinion.hitTestObject(theBananas[i])){
            removeChild(theBananas[i]);
            health=health+1;
            trace(health);
        }
    }

}

    }


stop();

编辑：格式化代码

Answer 1

在将 child 添加到舞台时，您还必须将其从舞台中删除：

stage.removeChild(theBananas[i]);

将来，在某些情况下，如果您不知道实际的 parent:

，也可以使用 parent 属性

theBananas[i].parent.removeChild(theBananas[i]);

在您的游戏中，我假设您还想在从舞台上删除香蕉时从 theBananas-array 中删除香蕉，这样您的数组就不会最终删除香蕉。所以，这里有一些修改：

for(var i:int = theBananas.length-1; i>-1; i--){ //inverted loop
    if (sideMinion.hitTestObject(theBananas[i])){
        stage.removeChild(theBananas[i]);
        theBananas.splice(i,1); //removing it from the array
        health=health+1;
        trace(health);
    }
}

反向循环显然是从最后一个元素一直循环到第一个元素，因为如果你从数组中删除第一个元素，那么第二个元素会 'jump' 到它的位置并且循环会跳过它.

希望我们都能尽快看到您的游戏！ :)

AS3 ArgumentError: Error #2025: The supplied DisplayObject must be a child of the caller

AS3 ArgumentError: Error #2025: The supplied DisplayObject must be a child of the caller

actionscript-3

flash