如何在 Prolog 中做一个解析器？

Question

我想在序言中做一个解析器。这个应该能够解析这样的东西：

a = 3 + (6 * 11);

目前我只完成了这个语法。它正在工作，但我想改进它以获得 id 例如 (a..z)+ 和 digit 例如 (0. .9)+.

parse(-ParseTree, +Program, []):-
    parsor(+Program, []).

parsor --> [].
parsor --> assign.
assign --> id, [=], expr, [;].
id --> [a] | [b].
expr --> term, (add_sub, expr ; []).
term --> factor, (mul_div, term ; []).
factor --> digit | (['('], expr, [')'] ; []).
add_sub --> [+] | [-].
mul_div --> [*] | [/].
digit --> [0] | [1] | [2] | [3] | [4] | [5] | [6] | [7] | [8] | [9].

其次，我想在 ParseTree 变量中存储一些内容，以便像这样打印 ParseTree：

PARSE TREE:
assignment
    ident(a)
    assign_op
    expression
        term
            factor
                int(1)
            mult_op
            term
                factor
                    int(2)
        add_op
        expression
            term
                factor
                    left_paren
                    expression
                        term
                            factor
                                int(3)
                        sub_op
                        ...

这是我要用来打印 ParseTree 的函数：

output_result(OutputFile,ParseTree):- 
    open(OutputFile,write,OutputStream),
    write(OutputStream,'PARSE TREE:'), 
    nl(OutputStream), 
    writeln_term(OutputStream,0,ParseTree), 
    close(OutputStream).

writeln_term(Stream,Tabs,int(X)):-
    write_tabs(Stream,Tabs), 
    writeln(Stream,int(X)).
writeln_term(Stream,Tabs,ident(X)):-
    write_tabs(Stream,Tabs), 
    writeln(Stream,ident(X)).
writeln_term(Stream,Tabs,Term):-
    functor(Term,_Functor,0), !,
    write_tabs(Stream,Tabs),
    writeln(Stream,Term).
writeln_term(Stream,Tabs1,Term):-
    functor(Term,Functor,Arity),
    write_tabs(Stream,Tabs1),
    writeln(Stream,Functor),
    Tabs2 is Tabs1 + 1,
    writeln_args(Stream,Tabs2,Term,1,Arity).

writeln_args(Stream,Tabs,Term,N,N):-
    arg(N,Term,Arg),
    writeln_term(Stream,Tabs,Arg).
writeln_args(Stream,Tabs,Term,N1,M):-
    arg(N1,Term,Arg),
    writeln_term(Stream,Tabs,Arg), 
    N2 is N1 + 1,
    writeln_args(Stream,Tabs,Term,N2,M).

write_tabs(_,0).
write_tabs(Stream,Num1):-
    write(Stream,'\t'),
    Num2 is Num1 - 1,
    write_tabs(Stream,Num2).

writeln(Stream,Term):-
    write(Stream,Term), 
    nl(Stream).

write_list(_Stream,[]). 
write_list(Stream,[Ident = Value|Vars]):-
    write(Stream,Ident),
    write(Stream,' = '),
    format(Stream,'~1f',Value), 
    nl(Stream), 
    write_list(Stream,Vars).

希望有人能帮助我。谢谢！

Answer 1

id//0 的递归规则，更通用一些：

id --> [First], {char_type(First,lower)}, id ; [].

可以构建树 'by hand'，用适当的术语扩充每个非终结符，例如

...
assign(assign(Id, Expr)) --> id(Id), [=], expr(Expr), [;].
...

id//0 可以变成 id//1

id(id([First|Rest])) --> [First], {memberchk(First, [a,b])}, id(Rest) ; [], {Rest=[]}.

如果您要经常编写此类解析器的代码，可以轻松实现重写规则...

Answer 2

这是您编写的解析器的增强功能，可以帮助您入门。这是对@CapelliC 指出的概念的阐述。

parser([]) --> [].
parser(Tree) --> assign(Tree).

assign([assignment, ident(X), '=', Exp]) --> id(X), [=], expr(Exp), [;].

id(X) --> [X], { atom(X) }.

expr([expression, Term]) --> term(Term).
expr([expression, Term, Op, Exp]) --> term(Term), add_sub(Op), expr(Exp).

term([term, F]) --> factor(F).
term([term, F, Op, Term]) --> factor(F), mul_div(Op), term(Term).

factor([factor, int(N)]) --> num(N).
factor([factor, Exp]) --> ['('], expr(Exp), [')'].

add_sub(Op) --> [Op], { memberchk(Op, ['+', '-']) }.
mul_div(Op) --> [Op], { memberchk(Op, ['*', '/']) }.

num(N) --> [N], { number(N) }.

我这里可能有一些小问题，但我添加到您的代码中的关键元素是：

将 digit 替换为 num，它接受任何 number(N) 为真的 Prolog 术语 N
已使用 atom(X) 识别有效标识符
添加了一个参数来保存解析给定表达式项的结果

举个例子：

| ?- phrase(parser(Tree), [a, =, 3, +, '(', 6, *, 11, ')', ;]).

Tree = [assignment,ident(a),=,[expression,[term,[factor,int(3)]],+,[expression,[term,[factor,[expression,[term,[factor,int(6)],*,[term,[factor,int(11)]]]]]]]]] ? ;

这可能不是解析树的理想表示。它可能需要根据您的需要进行一些调整，您可以通过修改我展示的内容来完成。然后你可以写一个谓词来格式化你喜欢的解析树。

您还可以考虑如下所示的嵌入式 Prolog 术语结构，而不是列表结构：

parser([]) --> [].
parser(Tree) --> assign(Tree).

assign(assignment(ident(X), '=', Exp)) --> id(X), [=], expr(Exp), [;].

id(X) --> [X], { atom(X) }.

expr(expression(Term)) --> term(Term).
expr(expression(Term, Op, Exp)) --> term(Term), add_sub(Op), expr(Exp).

term(term(F)) --> factor(F).
term(term(F, Op, Term)) --> factor(F), mul_div(Op), term(Term).

factor(factor(int(N))) --> num(N).
factor(factor(Exp)) --> ['('], expr(Exp), [')'].

add_sub(Op) --> [Op], { memberchk(Op, ['+', '-']) }.
mul_div(Op) --> [Op], { memberchk(Op, ['*', '/']) }.

num(N) --> [N], { number(N) }.

结果如下：

| ?- phrase(parser(T), [a, =, 3, +, '(', 6, *, 11, ')', ;]).

T = assignment(ident(a),=,expression(term(factor(int(3))),+,expression(term(factor(expression(term(factor(int(6)),*,term(factor(int(11)))))))))) ? ;

如何在 Prolog 中做一个解析器？

How to do a parser in Prolog?

parsing

prolog

dcg