如何在Word中find/replace带有复选框控件的符号

Question

我的 Word 2010 文档中有邮件合并字段，其中包含一个复选框控件，该控件是否选中取决于输入列表中的内容。

{IF NEW = "NEW" "☒" "☐"} 这些框实际上是复选框控件

但是，邮件合并完成后，复选框控件将根据情况替换为选中或未选中框的符号。因此，在最终文档中无法再像复选框控件那样从选中状态切换到未选中状态。

一个类似的问题是 asked here，但没有得到解决（一个带有解决方案的回复对我不起作用）。

我正在寻找一种简单的方法来在输出文档中找到选中或未选中的符号，并将其替换为处于适当状态的复选框文档控件。

我不太擅长编程，但如果你能给我指出正确的方向，我会尽力而为。我过去玩过 VB 宏（非常业余），所以我再次尝试并得到了 "proof of concept":

Sub Checkbox()
' ChrW(9744) is unchecked box; 9746 is checked box
    Selection.HomeKey Unit:=wdStory
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = ChrW(9744)
        .Replacement.Text = ChrW(9746)
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
    Selection.HomeKey Unit:=wdStory
End Sub

我也找到了添加复选框控件的方法：

Selection.Range.ContentControls.Add (wdContentControlCheckBox)

但我还没有想出如何将最后一段代码结合到 'replace' 行中，也没有想出如何根据搜索将复选框定义为选中或未选中。

感谢您的帮助。

Answer 1

您可以执行以下操作：

Selection.Find.ClearFormatting
Selection.Find.Replacement.ClearFormatting
Do
  With Selection.Find
    .Text = ChrW(9744) ' ChrW(9746)
    .Forward = True
    .Wrap = wdFindStop 'wdFindContinue
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
  End With
  If Selection.Find.Execute = False Then Exit Do
  ' This adds the checkbox at the selected position
  Set f = ActiveDocument.FormFields.Add(Range:=Selection.Range, _
                                        Type:=wdFieldFormCheckBox)      
  'f.CheckBox.Value = True ' Add this for checked checkboxes
Loop

Answer 2

对于 Office 2010，可以使用支持格式设置的更高级的复选框控件。代码为：

Selection.Find.ClearFormatting
Selection.Find.Replacement.ClearFormatting
Do
  With Selection.Find
    .Text = ChrW(9744)
    .Forward = True
    .Wrap = wdFindStop 'wdFindContinue
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
  End With
  If Selection.Find.Execute = False Then Exit Do
  ' This adds the checkbox at the selected position
  Set f = Selection.Range.ContentControls.Add(wdContentControlCheckBox)
  f.SetCheckedSymbol CharacterNumber:=254, Font _
        :="Wingdings"
  f.SetUncheckedSymbol CharacterNumber:=168, _
        Font:="Wingdings"
  f.Checked = False' Change this for checked checkboxes
Loop

如何在Word中find/replace带有复选框控件的符号

How to find/replace a symbol with a check box control in Word

vba

ms-word

mailmerge

word-contentcontrol