具有单击和双击事件的 MS Access 按钮 (VBA)

Question

我在 ms-access 的表单上有一个按钮，我在其中填充了 "On Click" 和 "on Dbl Click" 事件。我运行遇到单击事件起作用但双击不起作用的问题，除非在第二次单击时，我一直按住它并在释放它之前将鼠标拖离按钮。这个按钮的作用是根据两次不同的点击，用特定的文本填充一个文本框。我如何解决这个双击问题？按钮的代码如下。请注意，Task_ID_AfterUpdate() 还根据 Me.Task_ID 的内容填充文本字段，方法是在查询中查找它。

'single click
Private Sub getBtn_Click()
    btnUpdateHelper (1162)
End Sub

'double click
Private Sub getBtn_DblClick(cancel As Integer)
    btnUpdateHelper (1449)
End Sub

Private Sub btnUpdateHelper(Task As Variant)
    'helper method for buttons, only pass task id
    'Me.Task_ID is a textfield
    Me.Task_ID = Task
    Task_ID_AfterUpdate
End Sub

Private Sub Task_ID_AfterUpdate()
    Dim taskIdNum As String
    taskIdNum = Me.Task_ID
    'updates all fields to display the selected task
    Me.Area = DLookup("Area", "Query", "TaskID=" & taskIdNum)
    Me.Activity = DLookup("Activity", "Query", "TaskID=" & taskIdNum)
    Me.Description = DLookup("Description", "Query", "TaskID=" & taskIdNum)
    Me.Comments = DLookup("Comments", "Query", "TaskID=" & taskIdNum)
    Me.Task_Group = DLookup("[Task Group]", "Query", "TaskID=" & taskIdNum)
    Me.Mul = DLookup("Mul", "Query", "TaskID=" & taskIdNum)
    Me.Time = DLookup("Time", "Query", "TaskID=" & taskIdNum)
End Sub

Answer 1

在按钮上放置 Click 和 DblClick 事件在我看来是一个相当混乱的 UI 设计。更好的方法是使用右键单击或 Shift+单击（或 Alt 或 Ctrl）来实现替代功能。

Click 事件不捕获这些修饰符，仅捕获 MouseDown 和 MouseUp。如果将动作放在 MouseUp 事件过程中感觉最自然，例如

Private Sub cmdMultiClick_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)

    Dim SelectedFunction As String

    If Button = acLeftButton Then
        If (Shift And acShiftMask) Then
            SelectedFunction = "Shift-Left click!"
        Else
            SelectedFunction = "Left click!"
        End If
    ElseIf Button = acRightButton Then
        SelectedFunction = "Right click!"
        ' Cancel the default right-click behavior (open context menu)
        DoCmd.CancelEvent
    End If

    MsgBox SelectedFunction, vbInformation

End Sub

具有单击和双击事件的 MS Access 按钮 (VBA)

MS Access button with on click and on double click events (VBA)

ms-access

vba

ms-access-2010

ms-access-2007