CMake install TARGETS 给定的目标不是可执行文件、库或模块

Question

我正在尝试构建一个包含单个 bash 脚本的 debian 软件包。脚本生成者：

go.sh:

#!/bin/bash

cat >main <<EOF
#!/bin/bash
echo $@
EOF

chmod +x main

和我的 CMakeLists.txt:

cmake_minimum_required(VERSION 3.5)

add_custom_command(OUTPUT main ${CMAKE_CURRENT_SOURCE_DIR}/go.sh ${PROJECT_NAME})

add_custom_target(main ALL)

install(
    TARGETS main
    DESTINATION /usr/local/lib/
)

set(CPACK_GENERATOR "DEB")
set(CPACK_DEBIAN_PACKAGE_MAINTAINER "Me")

include(CPack)

这给我带来了一条神秘的错误消息：

CMake Error at CMakeLists.txt:7 (install):
  install TARGETS given target "main" which is not an executable, library, or
  module.

有谁知道这条错误消息是什么意思，我应该怎么做？

编辑 - 我迷路了。

我已将 go.sh 生成的脚本重命名为 program，这样它就不会与应该生成文件的目标名称冲突：

#!/bin/bash

MAIN=program

cat >$MAIN <<EOF
#!/bin/bash
echo $@
EOF

chmod 'x $MAIN

我也更改了我的 CMakeLists.txt 文件：

cmake_minimum_required(VERSION 3.5)

add_custom_target(
    main
    DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/program
)

add_custom_command(
    OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/program
    COMMAND ${CMAKE_CURRENT_SOURCE_DIR}/go.sh ${PROJECT_NAME}
)

install(FILES ${CMAKE_CURRENT_BINARY_DIR}/program DESTINATION /usr/local/lib/)

set(CPACK_GENERATOR "DEB")
set(CPACK_DEBIAN_PACKAGE_MAINTAINER "Me")

include(CPack)

但是，我的构建仍然无法正常工作。在这种情况下，我的 main 目标没有构建。如果我运行:

rm -rf ./* && cmake .. && make package

我收到关于 file INSTALL cannot find program

的错误

我想我从根本上误解了文件和目标之间的区别。我无法想象，使用 cmake，人们应该为每个生成的文件命名，然后为每个生成的文件指定一个不同的目标名称，以避免命名冲突。这对我来说没有任何意义。

Answer 1

命令流 install(TARGETS) 仅适用于使用 add_executable() 或 add_library() 创建的目标。

对于使用 自定义目标构建的文件 使用 install(FILES):

install(FILES ${CMAKE_CURRENT_BINARY_DIR}/main DESTINATION /usr/local/lib/)

Answer 2

已修复。我不得不将 add_custom_command 折叠成 add_custom_target:

cmake_minimum_required(VERSION 3.5)

add_custom_target(
    main ALL
    COMMAND ${CMAKE_CURRENT_SOURCE_DIR}/go.sh ${PROJECT_NAME}
)

install(FILES ${CMAKE_CURRENT_BINARY_DIR}/main DESTINATION /usr/local/bin/)

set(CPACK_GENERATOR "DEB")
set(CPACK_DEBIAN_PACKAGE_MAINTAINER "Me")

include(CPack)

Answer 3

@tsyvarev 的回答为您指明了正确的方向，您编辑的问题几乎是正确的。您遗漏了 add_custom_target() 的 ALL 选项，这就是默认情况下未构建 main 目标的原因。更正您的 CMakeLists.txt 文件以解决此问题，以下内容应该符合您的要求：

cmake_minimum_required(VERSION 3.5)

add_custom_target(
    main ALL
    DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/program
)

add_custom_command(
    OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/program
    COMMAND ${CMAKE_CURRENT_SOURCE_DIR}/go.sh ${PROJECT_NAME}
)

install(FILES ${CMAKE_CURRENT_BINARY_DIR}/program DESTINATION /usr/local/lib/)

set(CPACK_GENERATOR "DEB")
set(CPACK_DEBIAN_PACKAGE_MAINTAINER "Me")

include(CPack)

这是 CMake 的一个非常标准的模式，有一个自定义命令创建一个文件和一个依赖它的自定义目标，以便它可以根据需要触发。

CMake install TARGETS 给定的目标不是可执行文件、库或模块

CMake install TARGETS given target which is not an executable, library, or module

cmake

deb

cpack