如何在屏幕上的键盘和按钮组之间移动焦点？

Question

因此，对于工作中的项目，我们的任务是为客户创建 Roku 应用程序。对不起，如果这是一个愚蠢的问题，但我从来没有接触过 brightscript 或 Roku 开发，而且我主要是 react/javascript 开发人员。

我正在堵住我的路，现在我正在尝试创建一个场景图组件来显示键盘和下面显示的 ButtonGroup。按钮组主要用于选择是提交键盘文本字段中的内容，还是取消输入。

至此，组件渲染中的所有元素和焦点都设置到键盘上了（这似乎是必要的，否则，仅通过遥控器上下键将无法选择键盘）。

但是，在键盘周围导航时，我找不到任何方法将焦点移动到按钮组。基本上，如果我按下键盘底行的遥控器，它什么也不做。它从不将焦点向下移动到按钮组。

我只是希望有人能帮我解决这个问题。我知道答案可能很明显，我只是想念它，但我整个上午都在为此苦苦思索，摆弄一些东西，但我似乎无法弄清楚。

下面是包含键盘和按钮组的组件示例。随意批评你看到我做的不好的任何其他事情，再一次，关于 Roku 开发我没有真正的线索。

<?xml version="1.0" encoding="utf-8" ?>
<!-- Copyright 2016 Roku Corp.  All Rights Reserved. -->
<component name="MemberEmail" extends="Group">

  <children>
    <LayoutGroup id="MemberEmailLayout" translation = "[ 0, 0 ]" itemSpacings="[20]">
      <Keyboard id="EmailKeyboard" />
      <ButtonGroup id="EmailButtonGroup" />
    </LayoutGroup>
  </children>
  <script type = "text/brightscript" >

    <![CDATA[

    sub init()
      m.parentNode = m.top.getParent()

      m.memberEmailLayout = m.top.findNode("MemberEmailLayout")
      m.emailKeyboard = m.top.findNode("EmailKeyboard")
      m.emailButtonGroup = m.top.findNode("EmailButtonGroup")

      m.emailButtonGroup.buttons = ["Submit", "Cancel"]
      m.emailButtonGroup.observeField("buttonSelected","buttonPressed")

      emailKeyboardRect = m.memberEmailLayout.boundingRect()
      emailKeyboardCenterX = (1920 - emailKeyboardRect.width) / 2
      emailKeyboardCenterY = (1080 - emailKeyboardRect.height) / 2
      m.memberEmailLayout.translation = [ emailKeyboardCenterX, emailKeyboardCenterY ]

    end sub

    sub buttonPressed()
      if m.emailButtonGroup.buttonSelected = 1 then
        print "SUBMIT BUTTON SELECTED"
        print "Input Value is"; m.emailKeyboard.text
        m.parentNode.currentStep = "password"
      else if m.emailButtonGroup.buttonSelected = 2 then
        print "CANCEL BUTTON SELECTED"
      end if
    end sub
    ]]>

  </script>

</component>

Answer 1

您可能需要阅读文档中的 onKeyEvent 函数。将此功能添加到您的组件：

    function onKeyEvent(key as String, press as Boolean) as Boolean
        handled = false

        if press
            if key = "down" and not m.emailButtonGroup.hasFocus()
                m.emailButtonGroup.setFocus(true)
                handled = true
            else if key = "up" and not m.emailKeyboard.hasFocus()
                m.emailKeyboard.setFocus(true)
                handled = true
            end if
        end if

        return handled
    end function

如何在屏幕上的键盘和按钮组之间移动焦点？

How to move focus between a keyboard and button group on a screen?

roku

brightscript