matmul 内在函数的 Fortran 数组等级

Question

以下 link https://gcc.gnu.org/onlinedocs/gcc-5.4.0/gfortran/MATMUL.html 明确指出 gfortran 期望输入到 matmul 的矩阵为 1 或 2。但是以下代码片段无法编译：

Program scratch
  real(kind=8) :: A(10)=(/0,1,2,3,4,5,6,7,8,9/)
  real(kind=8) :: B(10)=(/0,1,2,3,4,5,6,7,8,9/)
  real(kind=8) :: C(10,10)
  print *,rank(A),rank(B)
  C=matmul(A,B)  
End Program scratch

gfortran 给出错误：

$gfortran scratch.f90 
scratch.f90:6:13:

   C=matmul(A,B)
         1
Error: ‘matrix_b’ argument of ‘matmul’ intrinsic at (1) must be of rank 2

我的gfortran是5.4.0（兼容上面的link）。我真的在做傻事吗？

Answer 1

您必须对两个向量的张量积执行此操作

Program scratch
  integer, parameter :: dp = kind(1.d0)
  real(dp) :: A(10,1)=reshape((/0,1,2,3,4,5,6,7,8,9/), (/ 10, 1 /))
  real(dp) :: B(1,10)=reshape((/0,1,2,3,4,5,6,7,8,9/), (/ 1, 10 /))
  real(dp) :: C(10,10)
  print *,rank(A),rank(B)
  C=matmul(A,B)
  print *, C
End Program scratch

如果你这样做

   A(1,10)
   B(10,1)

你会得到一个标量积。只有两个一维数组，不清楚你想要这两种产品中的哪一种（尽管对于点产品有一个特殊的功能可用）。

矩阵乘以向量时，A 或 B 可以是一维数组。

Answer 2

您可以使用 RESHAPE 将它们变成 MATMUL 喜欢的形式：

Program scratch
  real(kind=8) :: A(10)=(/0,1,2,3,4,5,6,7,8,9/)
  real(kind=8) :: B(10)=(/0,1,2,3,4,5,6,7,8,9/)
  real(kind=8) :: C(10,10)
  print *,rank(A),rank(B)
  C = matmul( RESHAPE(A,(/10,1/)), RESHAPE(B,(/1,10/)) )
  WRITE(*,"(10F7.2)") C
End Program scratch

matmul 内在函数的 Fortran 数组等级

Fortran array rank for matmul intrinsic

fortran

gfortran

intrinsics