Return 从 Fortran 到 C++ 的字符串

Question

我在 C++ 中有以下函数调用：

int strLength = 20;
char* name;

getName(name, strLength);

printf("name: %s\n", name);

在 Fortran 中：

subroutine getName(name) bind (c, name='GETNAME')
use,intrinsic :: iso_c_binding
implicit none
character, intent(out) :: name

name = 'Martin'
end subroutine getName

当我执行 C++ 例程时，输出是：name: M。现在，我想这是因为 character, intent(out) :: name 声明了大小为 1 的 name 变量，但是如果我将声明更改为：character(len=6), intent(out) :: name 我会收到此错误消息：Error: Character argument 'name' at (1) must be length 1 because procedure 'getname' is BIND(C) .我也试过这个：character(len=6,kind=c_char), intent(out) :: name，有同样的错误信息。最后，我尝试了这个声明：character(c_char),dimension(6), intent(out) :: name，编译但产生了这个结果：name: MMMMMM.

我的问题归结为：如何 return 从 Fortran 到 C++ 的字符串？

Answer 1

问题在于将等级 n 的字符数组分配给长度 n 的字符标量，这在 this 问题中得到解决。如下所示更改 Fortran 例程解决了问题。

解决方案

因为我在遗留系统中工作，所以我不得不寻求下面指出的解决方案。显然不完全一样，但还是显示了大概的结构。如果其他人也应该采用此解决方案，您可能应该遵循 Matt P 评论中的建议。

虽然这是我寻求的解决方案，但我觉得 Matt P 的回答是对问题标题中所述一般问题的更好解决方案，这就是我接受它作为答案的原因。

C++

int strLength = 20;
char* name = new char[strLength];   
getName(name, strLength);    
printf("name: %s\n", name);

Fortran

subroutine getName(name) bind (c, name='GETNAME')
use,intrinsic :: iso_c_binding
implicit none
character(c_char),dimension(20), intent(out) :: name
character(20) :: fName

fName = 'Martin'//c_null_char

do j=1,len(fName )
  name(j) = fName (j:j)  
enddo

end subroutine getName

Answer 2

这种基于 Fortran 函数的方法简洁明了，非常适用于尚未在 C 例程中设置（或为其分配内存）的字符串。请注意，您不需要传入字符串长度参数，或使用假定大小的数组来 build/return 字符串值。¹

使用Fortran 可分配字符串常量，因此该函数可重复用于任何字符串。

一个整数参数也被传递到 Fortran 函数以演示，例如，您可以如何指示所需的响应应该是什么。

注意在本例中 "intent(out)" 用于指示整数参数在传入之前不需要定义，但可以在 returned 之前对其进行更新。因此，您可以修改其值并将其 return 修改为调用程序，以便它可以用作 "return code".

Fortran 函数

! f_string.f90
! Called from C routine as:  `myString = get_string(rc)`

function get_string(c_rc) bind(c, name='get_string')
    use, intrinsic :: iso_c_binding
    implicit none
    integer(c_int), intent(out) :: c_rc           ! <- Pass by reference; acts as return code in this example.
    type(c_ptr) :: get_string                     ! <- C_PTR to pass back to C
    character(len=:), allocatable, target, save :: fortstring   ! <- Allocatable/any length is fine

    fortstring = "Append C_NULL_CHAR to any Fortran string constant."//C_NULL_CHAR
    get_string = c_loc(fortstring)                ! <- C_LOC intrinsic gets loc of our string.
    c_rc = 1                                      ! <- Set the return code value.
end function get_string

C 程序

// c_string.c
#include <stdio.h>
#include <string.h>
#include <stdlib.h>

char *get_string(int *rc);              // <- The Fortran function signature.

int main(){
    int rc;                             // <- No value set.
    char *mynameptr;                    // <- Just a plain ol' char *, no memory allocation needed.

    mynameptr = get_string(&rc);

    printf("mynameptr=%s\n", mynameptr);
    printf("len =%d\n", strlen(mynameptr));
    printf("rc  =%d\n", rc);
    return rc;
}

编译、调用、输出：

ifort /c f_string.f90
icl c_string.c /link f_string.obj
c_string.exe
# example output: 
# mynameptr=Append C_NULL_CHAR to any Fortran string constant.
# len =48
# rc  =1

_{¹ 这也可以在没有警告的情况下干净地编译（在没有修改的中确实会发生我在评论中提出了建议）。}

Return 从 Fortran 到 C++ 的字符串

Return string from Fortran to C++

c++

fortran

fortran-iso-c-binding

解决方案