无法在 tcl 中对列表进行排序

Question

我在 NS2 中有以下代码，它计算两个节点之间的距离并将其放入列表 "nbr"。我想根据值 "d" 按升序整理该列表，然后再次将其存储在列表中以供我使用 lsort 命令进一步使用，但它给了我相同的未排序列表。请帮忙

代码：.

proc distance { n1 n2 nd1 nd2} {
    set x1 [expr int([$n1 set X_])]
    set y1 [expr int([$n1 set Y_])]
    set x2 [expr int([$n2 set X_])]
    set y2 [expr int([$n2 set Y_])]
    set d [expr int(sqrt(pow(($x2-$x1),2)+pow(($y2-$y1),2)))]
    if {$d<300} {
        if {$nd2!=$nd1 && $nd2 == 11} {
            set nbr "{$nd1 $nd2 $x1 $y1 $d}"
            set m [lsort -increasing -index 4 $nbr]
            puts $m
        }
    }
}

for {set i 1} {$i < $val(nn)} {incr i} {
    for {set j 1} {$j < $val(nn)} {incr j} {
        $ns at 5.5 "distance $node_($i) $node_($j) $i $j"
    }
}

输出：

{1 11 305 455 273}
{4 11 308 386 208}
{5 11 378 426 274}
{7 11 403 377 249}
{8 11 244 405 215}
{9 11 256 343 154}
{10 11 342 328 172}
{12 11 319 192 81}
{13 11 395 196 157}
{14 11 469 191 231}
{15 11 443 140 211}
{16 11 363 115 145}
{17 11 290 135 75}
{18 11 234 121 69}
{19 11 263 60 132}
{20 11 347 60 169}

Answer 1

现在，您正在分别计算每个距离，但实际上并没有将它们全部收集到一个可以排序的列表中。

让我们先重写 distance 来解决这个问题，让它自己进行距离计算：

proc distance {n1 n2 nd1 nd2} {
    set x1 [expr int([$n1 set X_])]
    set y1 [expr int([$n1 set Y_])]
    set x2 [expr int([$n2 set X_])]
    set y2 [expr int([$n2 set Y_])]

    set d [expr int(sqrt(pow(($x2-$x1),2)+pow(($y2-$y1),2)))]
    # Why not: set d [expr hypot($x2-$x1,$y2-$y1)]

    # I'm keeping *everything* we know at this point
    return [list $nd1 $nd2 $n1 $n2 $d $x1 $y1 $x2 $y2]
}

然后，我们需要另一个过程来处理整个集合（在模拟器调用它时）并进行排序。它将调用 distance 来获取单个记录，因为我们已经将该信息分解出来。

proc processDistances {count threshold {filter ""}} {
    global node_
    set distances {}
    for {set i 1} {$i < $count} {incr i} {
        for {set j 1} {$j < $count} {incr j} {
            # Skip self comparisons
            if {$i == $j} continue

            # Apply target filter
            if {$filter ne "" && $j != $filter} continue

            # Get the distance information
            set thisDistance [distance $node_($i) $node_($j) $i $j]

            # Check that the nodes are close enough
            if {[lindex $thisDistance 4] < $threshold} {
                lappend distances $thisDistance
            }
        }
    }

    # Sort the pairs, by distances
    set distances [lsort -real -increasing -index 4 $distances]

    # Print the sorted list
    foreach tuple $distances {
        puts "{$tuple}"
    }
}

然后我们安排在正确的时间调用整个过程：

# We recommend building callbacks using [list], not double quotes
$ns at 5.5 [list processDistances $val(nn) 300 11]

无法在 tcl 中对列表进行排序

not able to sort list in tcl

sorting

tcl

ns2