从多个存储库部署到 Azure Web App

Question

正在寻找一种从 3 个单独的 github 存储库部署到 Azure Web 应用程序的方法。其中一个存储库是主要网站，另外两个是其他项目使用的公共库。我们希望部署从所有三个存储库下拉到工件目录运行 msbuild 并将工件复制到 wwwroot。

我假设我需要一个自定义的 .deployment 文件和一个 kudu 批处理文件。但是我找不到任何关于如何从多个 github 存储库中提取的示例。

编辑：拼写

Answer 1

根据您的描述，您可以创建自己的 .deployment 和 deploy.cmd 文件，首先将第二个和第三个 github 存储库公共库克隆到 Web 应用程序文件夹，然后使用 msbuild 命令来建造它。

注意：您无法将第二个和第三个 github 存储库克隆到 artifact 目录。因为，您有 3 个独立的 github 存储库，每个存储库都有自己的 .git 文件。我们无法将这三者结合起来。所以我建议你可以先将第二个和第三个仓库克隆到新文件夹，然后使用 msbuild 来构建它。

更多详情，您可以参考以下步骤：

首先，我建议您可以从KUDU控制台下载部署脚本。

注意：在您已经从git部署之后，这个文件可以downloaded.We以这个文件为例来添加代码。如果你没有，你可以关注我的deployment.cmd。记得更改项目名称。

如下：

打开 Kudu。

下载部署脚本。

然后您可以更改，发现它包含 .deployment 和 deploy.cmd 文件。

将以下代码添加到 deploy.cmd 文件并将这两个文件添加到您的 git 文件夹中以进行推送。

  git clone https://github.com/{yourgithubname}/BrandoGitTestLibrary.git D:\home\site\{foldername}

  echo  second project
  :: 1. Start restore second project
  dotnet restore "D:\home\site\{foldername}\BrandoGitTestLibrary\BrandoGitTestLibrary.csproj"

  :: 2. Build to DEPLOYMENT_TEMP wait copy
  dotnet build  "D:\home\site\{foldername}\BrandoGitTestLibrary\BrandoGitTestLibrary.csproj" --output "%DEPLOYMENT_TEMP%"

此代码用于将您的公共库构建到临时文件夹等待复制。

主站发布后，会将临时文件夹复制到wwwrot。

总共 deploy.cmd 个文件。

注意：本例只构建两个仓库。如果你想构建和发布3个仓库，你只需要添加代码再次克隆。

    git clone https://github.com/BrandoTest/BrandoGitTestLibrary.git D:\home\site\sencondproject

    echo  second project
    :: 3. Start restore second project
    dotnet restore "D:\home\site\sencondproject\BrandoGitTestLibrary\BrandoGitTestLibrary.csproj"

    :: 4. Build and publish
    dotnet build  "D:\home\site\sencondproject\BrandoGitTestLibrary\BrandoGitTestLibrary.csproj" --output "%DEPLOYMENT_TEMP%"




@if "%SCM_TRACE_LEVEL%" NEQ "4" @echo off

:: ----------------------
:: KUDU Deployment Script
:: Version: 1.0.15
:: ----------------------

:: Prerequisites
:: -------------

:: Verify node.js installed
where node 2>nul >nul
IF %ERRORLEVEL% NEQ 0 (
  echo Missing node.js executable, please install node.js, if already installed make sure it can be reached from current environment.
  goto error
)

:: Setup
:: -----

setlocal enabledelayedexpansion

SET ARTIFACTS=%~dp0%..\artifacts

IF NOT DEFINED DEPLOYMENT_SOURCE (
  SET DEPLOYMENT_SOURCE=%~dp0%.
)

IF NOT DEFINED DEPLOYMENT_TARGET (
  SET DEPLOYMENT_TARGET=%ARTIFACTS%\wwwroot
)

IF NOT DEFINED NEXT_MANIFEST_PATH (
  SET NEXT_MANIFEST_PATH=%ARTIFACTS%\manifest

  IF NOT DEFINED PREVIOUS_MANIFEST_PATH (
    SET PREVIOUS_MANIFEST_PATH=%ARTIFACTS%\manifest
  )
)

IF NOT DEFINED KUDU_SYNC_CMD (
  :: Install kudu sync
  echo Installing Kudu Sync
  call npm install kudusync -g --silent
  IF !ERRORLEVEL! NEQ 0 goto error

  :: Locally just running "kuduSync" would also work
  SET KUDU_SYNC_CMD=%appdata%\npm\kuduSync.cmd
)
IF NOT DEFINED DEPLOYMENT_TEMP (
  SET DEPLOYMENT_TEMP=%temp%\___deployTemp%random%
  SET CLEAN_LOCAL_DEPLOYMENT_TEMP=true
)

IF DEFINED CLEAN_LOCAL_DEPLOYMENT_TEMP (
  IF EXIST "%DEPLOYMENT_TEMP%" rd /s /q "%DEPLOYMENT_TEMP%"
  mkdir "%DEPLOYMENT_TEMP%"
)

IF DEFINED MSBUILD_PATH goto MsbuildPathDefined
SET MSBUILD_PATH=%ProgramFiles(x86)%\MSBuild.0\Bin\MSBuild.exe
:MsbuildPathDefined
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Deployment
:: ----------

echo Handling ASP.NET Core Web Application deployment.

:: 1. Restore nuget packages
call :ExecuteCmd dotnet restore "%DEPLOYMENT_SOURCE%\TestForCore2.csproj"
IF !ERRORLEVEL! NEQ 0 goto error

:: 2. Build and publish
call :ExecuteCmd dotnet publish "%DEPLOYMENT_SOURCE%\TestForCore2.csproj" --output "%DEPLOYMENT_TEMP%" --configuration Release
IF !ERRORLEVEL! NEQ 0 goto error

:: 5. KuduSync
call :ExecuteCmd "%KUDU_SYNC_CMD%" -v 50 -f "%DEPLOYMENT_TEMP%" -t "%DEPLOYMENT_TARGET%" -n "%NEXT_MANIFEST_PATH%" -p "%PREVIOUS_MANIFEST_PATH%" -i ".git;.hg;.deployment;deploy.cmd"
IF !ERRORLEVEL! NEQ 0 goto error

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
goto end

:: Execute command routine that will echo out when error
:ExecuteCmd
setlocal
set _CMD_=%*
call %_CMD_%
if "%ERRORLEVEL%" NEQ "0" echo Failed exitCode=%ERRORLEVEL%, command=%_CMD_%
exit /b %ERRORLEVEL%

:error
endlocal
echo An error has occurred during web site deployment.
call :exitSetErrorLevel
call :exitFromFunction 2>nul

:exitSetErrorLevel
exit /b 1

:exitFromFunction
()

:end
endlocal
echo Finished successfully.

结果：

从多个存储库部署到 Azure Web App

Deploy to Azure Web App from Multiple Repositories

azure

kudu

azure-web-app-service