标准 ML：搜索列表列表

Question

我编写此函数是为了确定给定元素是否存储在元组列表中，但目前它只搜索第一个列表。我将如何搜索其余列表？

fun findItem (name : command, ((x,y)::firstlist)::tail : (command*command) list list) = 
    if x = name then true else findItem(name, firstlist::tail)
    | findItem(name, [[]]) = false

Answer 1

您将递归列表的其余部分（您需要三种情况）：

fun findItem (name, ((x,_)::firstlist)::tail) = x = name orelse findItem(name, firstlist::tail)
  | findItem (name, []::tail) = findItem (name, tail) 
  | findItem(name, []) = false

但是，如果您先编写一个搜索列表的函数，然后在另一个函数中使用它，这样看起来会容易得多：

fun findItemHelper (_, []) = false
  | findItemHelper (name, (n', _)::ns) = name = n' orelse findItemHelper (name, ns)

fun findItem (_, []) = false
  | findItem (name, n::ns) = findItemHelper (name, n) orelse findItem (name, ns)

除了orelse之前的部分外，这些完全相同，所以我们可以用谓词函数将其抽象出来：

fun find (_, []) = false
  | find (found, x::xs) = (found x) orelse find (found, xs)

并使用它：

fun findItemHelper (name, ns) = find (fn (n, _) => name = n, ns)

fun findItem (name, nss) = find (fn ns => findItemHelper (name, ns), nss)

Answer 2

为了补充 molbdnilo 的回答，下面是我将如何实现它。使用标准的 List.exists 库函数，它变成了一行代码：

fun findItem (x, ll) = List.exists (List.exists (fn (y,_) => x = y)) ll

标准 ML：搜索列表列表

Standard ML: Searching through a list of lists

list

functional-programming

sml

ml