清理 ExUnit 测试示例

Question

我在phoenix app中有以下测试：

defmodule TattooBackend.Web.API.V1.PasswordControllerTest do
  use TattooBackend.Web.ConnCase, async: true
  use Bamboo.Test

  alias TattooBackend.Web.Endpoint
  alias TattooBackend.Accounts.Account
  alias TattooBackend.Repo
  alias Phoenix.Token
  alias Comeonin.Bcrypt
  import TattooBackend.AuthenticationRequiredTest

  test "without passwords", %{conn: conn} do
    account = insert(:account)
    token   = Token.sign(Endpoint, "account_id", account.id)

    conn =
      conn
      |> put_req_header("authorization", "#{token}")
      |> post(api_v1_password_path(conn, :create))

    assert json_response(conn, 422)
  end

  test "with wrong password confirmation", %{conn: conn} do
    account = insert(:account)
    token   = Token.sign(Endpoint, "account_id", account.id)
    params  = %{password: "new-password", password_confirmation: "password"}

    conn =
      conn
      |> put_req_header("authorization", "#{token}")
      |> post(api_v1_password_path(conn, :create, params))

    assert json_response(conn, 422)
  end
end

这些行在测试中重复：

account = insert(:account)
token   = Token.sign(Endpoint, "account_id", account.id)

知道如何让它更干吗？

Answer 1

如果你想在所有测试中执行这两行代码，你可以将重复代码放在 setup 回调中，然后使用模式匹配在每个测试中获取它们：

defmodule TattooBackend.Web.API.V1.PasswordControllerTest do
  ...

  setup do
    account = insert(:account)
    token   = Token.sign(Endpoint, "account_id", account.id)
    [account: account, token: token]
  end

  test "without passwords", %{conn: conn, account: account, token: token} do
    conn =
      conn
      |> put_req_header("authorization", "#{token}")
      |> post(api_v1_password_path(conn, :create))

    assert json_response(conn, 422)
  end

  test "with wrong password confirmation", %{conn: conn, account: account, token: token} do
    params  = %{password: "new-password", password_confirmation: "password"}

    conn =
      conn
      |> put_req_header("authorization", "#{token}")
      |> post(api_v1_password_path(conn, :create, params))

    assert json_response(conn, 422)
  end
end

setup 将在每次测试之前执行其代码，然后将 account 和 token 传递给每个测试。

清理 ExUnit 测试示例

Cleanup ExUnit test examples

elixir

phoenix-framework

ex-unit