我可以在对 Perl 6 列表进行分类时修改值吗？

Question

List.classify方法可以通过我定义的一些映射将列表转换为散列。该映射的结果是散列键和原始值

my @list = (
    <Camelia 5>,
    <Camelia 6>,
    <Camelia 7>,
    <Amelia 1>,
    <Amelia 2>,
    <Amelia 3>
    );

my %hash = @list.classify: *.[0];

say %hash;

哈希值是列表的列表，因为它分类的原始thinygs是列表：

{
Amelia => [(Amelia 1) (Amelia 2) (Amelia 3)],
Camelia => [(Camelia 5) (Camelia 6) (Camelia 7)]
}

但是，我真的想要这个：

{
Amelia => ( 1 2 3 ),
Camelia => ( 5 6 7 )
}

我可以做一些额外的工作，但这似乎有点太多了：

my @list = (
    <Camelia 5>,
    <Camelia 6>,
    <Camelia 7>,
    <Amelia 1>,
    <Amelia 2>,
    <Amelia 3>
    );

my %hash = @list
    .classify( *.[0] )
    .kv
    .map( {
        $^a => $^b.map: *.[*-1]
        } )
    ;

say %hash;

Answer 1

您可以使用 :as 副词：

my @list = (
    <Camelia 5>,
    <Camelia 6>,
    <Camelia 7>,
    <Amelia 1>,
    <Amelia 2>,
    <Amelia 3>
    );

my %hash = @list.classify: *.[0], as => *.[1];

say %hash;  # {Amelia => [1 2 3], Camelia => [5 6 7]}

（很遗憾，现在好像还没有documented。）

Answer 2

还有另一个未记录的副词 :into，我认为它主要用于 Hash (although something with "list" in the method name should be in List 中的 classify-list 的适配器）：

my @list = (
    <Camelia 5>,
    <Camelia 6>,
    <Camelia 7>,
    <Amelia 1>,
    <Amelia 2>,
    <Amelia 3>
    );

@list.classify: *.[0], :into(my %hash), :as( *.[1] );

say %hash;

这种形式似乎更有意义，但这也是您不使用 :into 副词时的结果。我认为那里有两个哈希值：

 my %hash = Hash.new.classify-list: *.[0], @list, :as( *.[1] );

我可以在对 Perl 6 列表进行分类时修改值吗？

Can I modify values as I classify a Perl 6 list?

list

hash

raku