以编程方式防止 Windows 10 在更新后自动重启

Question

问题：是否有编程方式来防止 Windows 10 在更新后自动重启？

我们开发 "mission-critical" 运行于 Windows 的软件。一般来说，如果 Windows 自动更新中断了我们的流程，那是很糟糕的，因为这可能意味着在报废 material 中损失金钱（你不能停止并稍后恢复，工作必须从头到尾不间断地工作）。

过去，我们可以通过让我们的软件安装程序在 Windows 注册表中设置一个参数（在用户安装程序的同意下）来解决这个问题，该参数将防止在自动更新后自动重启用户已登录。因此，将通知用户有一个更新需要重新启动，并在他们准备好时单击按钮，而不是自动更新。这适用于 Windows Vista、7 和 8/8.1。但是，对于最新的 Windows 10（我正在使用 Creators 的更新），该参数似乎不再起作用，因为我观察到我的计算机进行了自动更新，我知道注册表项是已经生效。

在我的研究中，我发现了一个希望的地方，即可以选择一个设置，其中 Windows 将为用户提供安排更新的机会，而不是一次自动执行Windows认为合适（资料here）。但是，我不确定如何以编程方式设置 Windows，以便安排更新的选项成为默认选项。

是否有编程方式设置 Windows 10（以友好的方式，最好）以便它不会自动重启？

Answer 1

注册表项 HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsUpdate\UX\Settings 包含两个条目：ActiveHoursStart 和 ActiveHoursEnd。根据需要在程序中更改这些条目以禁止重新启动。通过这种方式，您可以控制在程序运行时不重新启动。请注意，您需要提升权限才能更改这些设置。

Answer 2

尝试关闭阻止原因 APIs。 ShutdownBlockReasonCreate

API 文档以 CD 刻录为例，但这同样适用于您的 "mission-critical" 过程。

Applications should call this function as they begin an operation that cannot be interrupted, such as burning a CD or DVD. When the operation has completed, call the ShutdownBlockReasonDestroy function to indicate that the system can be shut down.

请注意文档专门提到了用户关闭，但我不明白为什么它不应该也适用于更新重启。

注意：记得检查功能是否成功；并在进程完成时销毁关机原因。

根据您的评论，您似乎需要使用 Windows API 例程的帮助。我建议您在适当的库中声明外部函数。（但您可以放心地在同一单元中进行测试。）

function ShutdownBlockReasonCreate(hWnd: HWND; Reason: LPCWSTR): BOOL; stdcall; external user32;
function ShutdownBlockReasonDestroy(hWnd: HWND): BOOL; stdcall; external user32;

下面演示如何使用API。注意：注意错误检查。我已经演示了如何获取错误信息。你用它做什么取决于你。

要指出的另一件重要事情（在评论中重复）是你不应该阻塞主线程。有关更多信息，请参阅 Vista 中首次引入这些更改时的 Microsoft 文档 here。

procedure TForm1.JobStartClick(Sender: TObject);
var
  LErr: Cardinal;
begin
  ListBox1.Items.Add('Attempting to block shutdown:');
  if (not ShutdownBlockReasonCreate(Application.MainForm.Handle, 
      'Super Critical Job')) then
  begin
    LErr := GetLastError;
    ListBox1.Items.Add('... failed: ' + SysErrorMessage(LErr));
    //Probably not safe to start your job in this case, but perhaps you
    //choose to give it a shot anyway.
    Exit;
  end;
  ListBox1.Items.Add('... success');

  FJobRunning := True;
  //Start the job.
  //However, NB do not run the job here.
  //If it takes a long time and is not asynchronous, you should probably
  //run your job on a separate thread.   ***Do not block the main thread
  //  otherwise Windows will still kill your app for not responding***
end;

procedure TForm1.JobEndClick(Sender: TObject);
var
  LErr: Cardinal;
begin
  if (not FJobRunning) then Exit;
  //End the job.
  //Again, do not block the main thread, so perhaps this is rather something
  //to do after you already know the job is done.
  FJobRunning := False;

  ListBox1.Items.Add('Allow shutdown');
  if (not ShutdownBlockReasonDestroy(Application.MainForm.Handle)) then
  begin
    LErr := GetLastError;
    ListBox1.Items.Add('... failed: ' + SysErrorMessage(LErr));
  end;
end;

//Declare the handler for the WM_QUERYENDSESSION message as follows.
//procedure WMQueryEndSession(var AMsg : TWMQueryEndSession); message WM_QUERYENDSESSION;
procedure TForm1.WMQueryEndSession(var AMsg: TWMQueryEndSession);
begin
  ListBox1.Items.Add('WMQueryEndSession');
  if (FJobRunning) then
    //NB: This is very important.
    //You still need to confirm that your application wants to block
    //shutdown whenever you receive this message.
    AMsg.Result := 0
  else
    inherited;
end;

以编程方式防止 Windows 10 在更新后自动重启

Prevent Windows 10 from automatically restarting after an update programmatically

c#

windows

delphi

winapi

restart