从 VB 访问 "Undefined function <function name> in expression" 调用 UDF（Sql 服务器）

Question

我正在尝试从访问中的 Vb 代码调用 udf（SQL 服务器）。连接到数据库成功，我可以运行查询 SQL 服务器表。但是，当我尝试调用 UDF 时，它抛出一个错误 undefined function.

请看下面的代码：

Private Sub cmd_Login_Click()
    ' some code here
    Set db = CurrentDb()

    sSQL = "SELECT UserID FROM TBL_User_Login WHERE UserName = '" & cbo_User & "' AND Status = 0"
    Set recset = db.OpenRecordset(sSQL)


    recset.Close
    Set rectset = Nothing

    sSQL = "SELECT fn_validate_user(" & gb_UserId & ",'" & Hash(Me.txt_Password + cbo_User) & "') AS PasswordValid"
    Set recset = db.OpenRecordset(sSQL)  ' this is where i get error for undefined function fn_validate_user
    PasswordValid = recset("PasswordValid")

谁能看看我是不是遗漏了什么。

Answer 1

当您运行在 Access 中执行标准查询时，它首先由 Access 数据库引擎处理，即使该查询引用 ODBC 链接表也是如此。 Access 可以识别 Access 用户定义函数（使用 VBA 创建），但它无法识别 SQL 服务器用户定义函数。

为了使用 SQL 服务器用户定义函数，您需要使用传递查询。顾名思义，它绕过 Access 数据库引擎并将查询直接发送到远程数据库（通过 ODBC）。 VBA 代码看起来像这样：

Dim db As DAO.Database, qdf As DAO.QueryDef, recset As DAO.Recordset
Dim sSQL As String, PasswordValid As Boolean
Set db = CurrentDb
sSQL = "SELECT fn_validate_user(" & gb_UserId & ",'" & Hash(Me.txt_Password + cbo_User) & "') AS PasswordValid"
Set qdf = db.CreateQueryDef("")
' get .Connect property from existing ODBC linked table
qdf.Connect = db.TableDefs("TBL_User_Login").Connect
qdf.ReturnsRecords = True
qdf.SQL = sSQL
Set recset = qdf.OpenRecordset(dbOpenSnapshot)
PasswordValid = recset.Fields("PasswordValid").Value
recset.Close
Set recset = Nothing
Set qdf = Nothing

从 VB 访问 "Undefined function <function name> in expression" 调用 UDF（Sql 服务器）

Calling a UDF (Sql server) from VB Access "Undefined function <function name> in expression"

ms-access

sql-server-2008-r2

vba

ms-access-2010