vbscript 上 aes/rijndael 的自定义键

Question

我正在开发一个 JAVA 程序，该程序向 asp 文件发出请求并且运行良好。

现在我想加密 POST 请求，但我需要在 JAVA 和 ASP 上使用相同的加密密钥才能正确解密（或者这就是我的想法）。

如何从 vbscript 上的字符串生成密钥？我需要定制 IV 吗？我不知道那是什么:(

（我从来没有加密过任何东西，我是新手）

set obj = server.CreateObject("System.Security.Cryptography.RijndaelManaged")
set utf = CreateObject("System.Text.UTF8Encoding")
s="This is a private message"
bytes=utf.GetBytes_4(s)
obj.GenerateKey()   'need to custom this
obj.GenerateIV()    'need to custom this?
set enc=obj.CreateEncryptor()
set dec=obj.CreateDecryptor()

bytec=enc.TransformFinalBlock((bytes),0,lenb(bytes))
sc=utf.GetString((bytec))
response.write sc

byted=dec.TransformFinalBlock((bytec),0,lenb(bytec))
sd=utf.GetString((byted))
response.write sd

Answer 1

经过几天的调查，我会 post 我最终做了什么。我知道这不是一个好的做法，我会尽快更改它，但现在还可以。

ASP CODE（解密 java 请求）

response.write desencriptar(encryptedStringHere)

Function desencriptar(str)
  set obj= CreateObject("System.Security.Cryptography.RijndaelManaged")
  set utf8 = CreateObject("System.Text.UTF8Encoding")
  ekey = "16byteskeyhere" 'you'll need to change this 
  eiv = "16bytesIVhere"   'you'll need to change this 
  obj.BlockSize = 128
  obj.Key = utf8.GetBytes_4(ekey)
  obj.IV = utf8.GetBytes_4(eiv)
  obj.Padding = 5
  set decryptor=obj.CreateDecryptor()
  desencriptado = Base64ToByte(str)
  byted=decryptor.TransformFinalBlock((desencriptado),0,lenb(desencriptado))
  desencriptado = utf8.getString((byted))
  desencriptar = desencriptado
end function

Function Base64ToByte(ByVal vCode)
  Dim oXML, oNode
  Set oXML = CreateObject("Msxml2.DOMDocument.3.0")
  Set oNode = oXML.CreateElement("base64")
  oNode.dataType = "bin.base64"
  oNode.text = vCode
  Base64ToByte = oNode.nodeTypedValue
  Set oNode = Nothing
  Set oXML = Nothing
End Function

JAVA CODE（加密函数）

public static String aesEncrypt(String value, String key, String initVector) {
    try {
        IvParameterSpec iv = new IvParameterSpec(initVector.getBytes("UTF-8"));
        SecretKeySpec skeySpec = new SecretKeySpec(key.getBytes("UTF-8"), "Rijndael");
        Cipher cipher = Cipher.getInstance("Rijndael/CBC/PKCS5PADDING");
        cipher.init(Cipher.ENCRYPT_MODE, skeySpec, iv);
        byte[] encrypted = cipher.doFinal(value.getBytes());
        return Base64.getEncoder().encodeToString(encrypted);
    } catch (Exception ex) {
        ex.printStackTrace();
    }
    return null;
}

Docs: RijndaelManaged | PaddingMode | CipherMode

vbscript 上 aes/rijndael 的自定义键

Custom key for aes/rijndael on vbscript

java

encryption

vbscript

asp-classic