如何检测点击 TListView 中的 CheckBox

Question

所以基本上当用户单击复选框时，我想将该项目添加到我的列表中，我尝试使用 OnChange 事件但这对我不起作用，因为即使未单击复选框也会触发它.

我的代码简单明了

procedure LvUserChange(Sender: TObject; Item: TListItem;Change: TItemChange);
 var
 objUser : TUsers;
begin
   if not assigned(objListOfChangedUsers) then
   objListOfChangedUsers := TObjectList.Create;

   objUser := Item.Data;
   objListOfChangedUsers.Add(objUser);
end;

我希望仅当在 ListView 中单击复选框时才触发此代码

Answer 1

在 Delphi 2009 及更高版本中，您可以使用 TListView.OnItemChecked 事件来检测复选框点击。 Delphi 2007 没有这样的事件，在这种情况下，您将需要在自己的代码中手动检测通知。我将使用中介层进行演示 class，但还有其他方法可以做到这一点。

uses
  ..., CommCtrl, ComCtrls, ...;

type
  TListView = class(ComCtrls.TListView)
  protected
    procedure CNNotify(var Message: TWMNotifyLV); message CN_NOTIFY;
  end;

....

procedure TListView.CNNotify(var Message: TWMNotifyLV);
begin
  inherited;
  if Message.NMHdr.code = LVN_ITEMCHANGED then
  begin
    if (Message.NMListView.uChanged = LVIF_STATE) and
       ( ((Message.NMListView.uOldState and LVIS_STATEIMAGEMASK) shr 12)
         <> ((Message.NMListView.uNewState and LVIS_STATEIMAGEMASK) shr 12)) then
    begin
      // changing check box state will land you here
    end;
  end;
end;

Answer 2

由于 OnItemChecked 不存在，您无法让您的事件仅在项目被选中时触发，但您可以像这样过滤您的事件

procedure LvUserChange(Sender: TObject; Item: TListItem;Change: TItemChange);
 var
 objUser : TUsers;
begin
   if Change = ctState then
   begin
     if Item.Checked then
     begin
       if not assigned(objListOfChangedUsers) then
       objListOfChangedUsers := TObjectList.Create;

       objUser := Item.Data;
       objListOfChangedUsers.Add(objUser);
     end
     else
     begin
       // just in case there are any actions when unchecking
     end;
   end;
end;

我没有 Delphi 2007，但已经检查了文档，它应该可以工作。

如何检测点击 TListView 中的 CheckBox

How to detect a click on the CheckBox in the TListView

delphi

delphi-2007

tlistview