UrlDownloadToFile 的替代方案

Question

UrlDownloadToFile 是 AutoHotkey 中的一个很好的命令，在大多数情况下工作得很好，但有时下载机制对它来说太复杂了。例如，如果下载需要设置特定的用户代理，或者下载需要 cookie 甚至密码。

所以问题是：
有没有更高级的下载功能，可以解决上述所有问题？

Answer 1

我很久以前写过这篇文章，我认为将它包装在一个函数中是个不错的主意，post 在这里：

Download(UrlToFile,SaveFileAs:="",Overwrite:=True,headers:="",method:="GET",postData:="") {
    WinHttpObj := ComObjCreate("WinHttp.WinHttpRequest.5.1")
    WinHttpObj.Open(method, UrlToFile)
    For header, value in headers 
        WinHttpObj.SetRequestHeader(header, value)
    WinHttpObj.Send(postData)

    ADODBObj := ComObjCreate("ADODB.Stream")
    ADODBObj.Type := 1
    ADODBObj.Open()
    ADODBObj.Write(WinHttpObj.ResponseBody)
    If !SaveFileAs {
        urlSplitArray := StrSplit(UrlToFile, "/")
        SaveFileAs := urlSplitArray[urlSplitArray.MaxIndex()]
    }        
    ADODBObj.SaveToFile(SaveFileAs, Overwrite ? 2:1)
    ADODBObj.Close()
}

示例 1

Download("http://ahkscript.org/download/1.1/AutoHotkey111402_Install.exe")

示例 2

customHeaders := {"User-Agent": "Mozilla/5.0 (Windows NT 6.3; WOW64; rv:37.0) Gecko/20100101 Firefox/37.0"
                 ,"Cache-Control": "max-age=0"
                 ,"Cookie": "downloadtoken=b82416fdb23e421fb5a"}
Download("http://download.piriform.com/ccsetup410.exe","",True,customHeaders)

示例 3

Download("http://foo.bar/example.exe","example.exe",True,{"Cookie":"sessionid=abc123"},"POST","username=foo_bar&password=qwerty")

UrlDownloadToFile 的替代方案

Alternative to UrlDownloadToFile

download

autohotkey