请解释 Android build.gradle groovy 语法

Question

以下 groovy 语法的真正含义是什么？

Gradle 文档宣扬 build.gradle 如何只是 groovy。 Android 团队已将默认的 build.gradle 简化到它看起来不像代码的程度（至少对我而言）。请根据 groovy 语法解释这是做什么的。例如，Android 插件使用的这些全局变量声明？

如果您在解释中包含对 http://groovy-lang.org/syntax.html 的引用，则可加分。

apply plugin: 'com.android.application'

android {
    compileSdkVersion 21
    buildToolsVersion "21.1.2"

    defaultConfig {
        applicationId "com.crittercism"
        minSdkVersion 15
        targetSdkVersion 21
        versionCode 5
        versionName "5.0"
    }

}

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
}

Answer 1

您可以将 gradle 构建脚本视为一些代码，这些代码 委托给一个对象，该对象可以响应写入其中的方法调用。

脚本使用了很多 Groovy 语法糖，所以去掉它们，它应该是这样的：

apply( [plugin: 'com.android.application'] );

android({
    compileSdkVersion( 21 );
    buildToolsVersion( "21.1.2" );

    defaultConfig({
        applicationId( "com.crittercism" );
        minSdkVersion( 15 );
        targetSdkVersion( 21 );
        versionCode( 5 );
        versionName( "5.0" );
    });
});

dependencies({
    compile( fileTree([dir: 'libs', include: ['*.jar']]) );
});

所以脚本实际上是一堆方法调用：

def apply(Map)
def android(Closure)
def dependencies(Closure)

这个 android(Closure) 将接收一个闭包并将其中调用的方法委托给可以响应这些方法的对象：

def compileSdkVersion(Integer)
def buildToolsVersion(String)
...

鉴于此，我们可以解析脚本，将其委托给某个对象然后执行它。

使用 DelegatingBaseScript 委派是一种方法（不确定 Gradle 是否这样做）。这是一个简化的工作版本：

import org.codehaus.groovy.control.CompilerConfiguration

gradleScript = '''
apply plugin: 'com.android.application'
    
android({
    compileSdkVersion( 21 )
    buildToolsVersion( "21.1.2" )
})'''


class PocketGradle {
  def config = [apply:[]].withDefault { [:] }
  
  def apply(map) {
    config.apply << map.plugin
  }
  
  def android(Closure closure) {
    closure.delegate = new Expando(
        compileSdkVersion: { Integer version -> 
          config.android.compileSdkVersion = version 
        },
        buildToolsVersion : { String version ->
          config.android.buildToolsVersion = version
        },
    )
    closure()
  }
}
    
def compiler = new CompilerConfiguration(scriptBaseClass: DelegatingScript.class.name)

shell = new GroovyShell(this.class.classLoader, new Binding(), compiler)

script = shell.parse gradleScript
script.setDelegate( gradle = new PocketGradle() )
script.run()

assert gradle.config == [
  apply: ['com.android.application'],
  android: [
    compileSdkVersion: 21,
    buildToolsVersion: '21.1.2'
  ]
]

您可以在Groovy Web Console中执行脚本（单击“在控制台中编辑”，然后单击“执行脚本”）。

大部分语法解释在DSL section:

Command chains

Groovy lets you omit parentheses around the arguments of a method call for top-level statements. "command chain" feature extends this by allowing us to chain such parentheses-free method calls, requiring neither parentheses around arguments, nor dots between the chained calls.

还有GroovyConfigSlurper，但我不确定能不能达到Gradle想要的程度。

Answer 2

感谢 AndroidGuy 提供的精彩视频让我了解了以下信息。视频长 35 分钟，这里是 TL;DR。

此语法的大部分是 method calls and closures 的混合体。闭包由大括号表示。另请注意，方法调用不需要括号。

apply plugin: 'com.android.application'

这是使用单个命名参数 "plugin" 调用 apply method on the project 对象。项目对象是 Gradle 提供的顶级对象。

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
}

这是设置 dependencies property of the project object. Groovy properties are basically shorthand for getters and setters. The dependencies property is a Closure object that delegates to DependencyHandler. Groovy delegation is essentially a way to augment the scope resolution of a closure. The dependencies closure contains a single method call to compile, which takes a FileTree positional parameter. The FileTree is generated by the fileTree method which is defined in the project object. The compile method is still a bit nebulous to me. It appears to come from the Java plugin，但那里没有明确记录。 'compile' 部分对我来说还是有点神奇。

android {
    ...
}

我将把 'android' 部分留给 reader 作为练习。 Android Gradle 域特定语言 (DSL) 在 Web 上不可用。你必须 download it.

请解释 Android build.gradle groovy 语法

Please explain the Android build.gradle groovy syntax

groovy

gradle

android-studio

android-gradle-plugin