分配日期是 "In Business Hours" 还是 "Outside Business Hours" in excel 的公式

Question

我正在尝试创建一个公式来根据通话的日期和时间确定 phone 通话是在工作时间之内还是之外进行的

营业时间为周一至周五上午 8 点至晚上 8 点，周六上午 8 点至下午 2 点。

基本上我需要创建的公式是；

如果通话时间为星期一、星期二、星期三、星期四、星期五且时间 >8 且 <20，或者通话时间为星期六且时间 >8 且 <14，则显示 "Inside Business Hours"

对于其他所有显示 "Outside Business Hours"

谢谢

Answer 1

这些是 D1:G8 范围内的营业时间：

日期和时间在A2中：04.09.2017 20:00:00

这是公式： =IF(AND(TIME(HOUR(A2);MINUTE(A2);SECOND(A2)) > VLOOKUP(WEEKDAY(A2);E:G;2;FALSE)/24;TIME(HOUR(A2);MINUTE(A2);SECOND(A2)) < VLOOKUP(WEEKDAY(A2);E:G;3;FALSE)/24); "inside"; "outside")

我希望我的英文名字是正确的。这是我的德文原文：

=WENN(UND(ZEIT(STUNDE(A2);MINUTE(A2);SEKUNDE(A2)) > SVERWEIS(WOCHENTAG(A2);E:G;2;FALSCH)/24;ZEIT(STUNDE(A2);MINUTE(A2);SEKUNDE(A2)) < SVERWEIS(WOCHENTAG(A2);E:G;3;FALSCH)/24); "inside"; "outside")

Answer 2

您可以试试下面的公式。

=IF(AND(WEEKDAY(A1)>1,WEEKDAY(A1)<7),IF(AND(A1-INT(A1)>=TIMEVALUE("08:00 AM"),A1-INT(A1)<=TIMEVALUE("08:00 PM")),"Inside Business Hours","Outside Business Hours"),IF(WEEKDAY(A1)=7,IF(AND(A1-INT(A1)>=TIMEVALUE("08:00 AM"),A1-INT(A1)<=TIMEVALUE("02:00 PM")),"Inside Business Hours","Outside Business Hours"),"Outside Business Hours"))

参见图片以供参考。

在上面的公式中，

WEEKDAY(A2) 将给出星期几（默认情况下，星期日为 1，星期六为 7）
A2-INT(A2) 将从 DataTime 单元格

Time

TIMEVALUE("08:00 AM") 将给出字符串中时间的十进制数

Answer 3

如果您的日期从单元格 A2 开始，请在单元格 B2 中输入此公式并将其拖到底部。您的日期应采用这种格式 9/16/2017 1:05:00 PM.

=IF(WEEKDAY(A2,2)=7,"Outside of Business hours",IF(WEEKDAY(A2,2)=6,IF(AND(MOD(A2,1)<TIME(14,0,0),MOD(A2,1)>TIME(8,0,0)),"Inside Business Hours","Outside of Business Hours"),IF(AND(MOD(A2,1)<TIME(20,0,0),MOD(A2,1)>TIME(8,0,0)),"Inside Business Hours","Outside of Business Hours")))

Answer 4

这个公式应该足够了：

=IF(AND(WEEKDAY(A2)>1,MOD(A2,1)*24>=8,MOD(A2,1)*24<=IF(WEEKDAY(A2)=7,14,20)),"In","Out")

分配日期是 "In Business Hours" 还是 "Outside Business Hours" in excel 的公式

Formula to Assign whether a date is "In Business Hours" or "Outside Business Hours" in excel

excel

formulas