为什么我会收到 F# 错误 FS0039：命名空间或模块 'Http' 未定义

Question

在 Visual Studio 2015 年和 2017 年，我在 FSharp Interactive 中尝试了几个 F# 示例中的 Http class，我不断得到：

error FS0039: The namespace or module 'Http' is not defined

示例如下：

open FSharp.Data
let response = Http.RequestString("http://api.themoviedb.org/3/search/movie", silentHttpErrors = true)

这显然是 FSharp.Data 版本的问题。有没有办法为 FSharp Interactive 指定正确的版本？ FSharp.Data 的哪个版本包含 Http 模块？

Answer 1

根据评论，我整理了一个脚本来安装 Paket，对其进行初始化，然后在脚本运行.

时可选择安装依赖项

/// install.paket.fsx
open System
open System.IO

printfn "Initialising..."
Environment.CurrentDirectory <- __SOURCE_DIRECTORY__
// invisibly run a command (paket.exe in this case)
let init paket =
    let psi = new System.Diagnostics.ProcessStartInfo(paket)
    psi.Arguments <- "init"
    psi.UseShellExecute <- false
    let p = System.Diagnostics.Process.Start(psi)
    p.WaitForExit()
    p.ExitCode

if not (File.Exists "paket.exe") then
    printfn "installing paket"
    let url = "http://fsprojects.github.io/Paket/stable"
    use wc = new Net.WebClient()
    let tmp = Path.GetTempFileName()
    let stable = wc.DownloadString(url)
    wc.DownloadFile(stable, tmp)
    File.Move(tmp,Path.GetFileName stable)
    printfn "paket installed"
    System.Threading.Thread.Sleep(100)
    printfn "initialising paket"
    init "paket.exe" |> ignore
    System.Threading.Thread.Sleep(200)
    printfn "paket initialised"
else
    printfn "paket already exists"

/// install.dependencies.fsx

open System.IO
printfn "Installing dependencies"
System.Environment.CurrentDirectory <- __SOURCE_DIRECTORY__
#r "paket.exe"

open Paket
let dependencies = Paket.Dependencies.Locate(__SOURCE_DIRECTORY__)

printfn "%s" dependencies.DependenciesFile

if not (File.Exists "packages/Newtonsoft.Json/lib/net40/Newtonsoft.Json.dll") then
    printfn "installing nuget depenencies"
    // either use the dependencies.Install to add dependencies in the paket.dependencies file
    //dependencies.Install true |> ignore
    // or install them by name
    // I remove the existing versions
    dependencies.Remove "FSharp.Data"
    dependencies.Remove "Newtonsoft.Json 8.0.3"
    // then add them (because I'm pedantic about the way the dependencies file looks)
    dependencies.Add "FSharp.Data"
    dependencies.Add "Newtonsoft.Json 8.0.3"
    printfn "nuget depenencies installed"
else
    printfn "nuget depenencies already exist"

printfn "Dependencies installed"

注意 Newtonsoft.Json 使用 8.0.3，最新版本带来了 20 多个额外的依赖项，所以我找到了一个很好的旧版本，它非常独立。如果你想要最新的，你可以留下版本号。

然后，我在共享 utilities.fsx 中使用这些脚本来实现可重用功能

System.Environment.CurrentDirectory <- __SOURCE_DIRECTORY__
#load "install.paket.fsx"
#load "install.dependencies.fsx"

#r "packages/fsharp.data/lib/net40/fsharp.data.dll"
#r "packages/Newtonsoft.Json/lib/net40/Newtonsoft.Json.dll"

open FSharp.Data
open FSharp.Data.HtmlAttribute
open FSharp.Data.HtmlNode
open FSharp.Data.HttpRequestHeaders
open Newtonsoft.Json
open System.Net
open System.IO
// utilities like authentication, Http requests and JSON (de)serialization

最后，我通过加载实用程序在我的目标脚本中引用了所有内容：

System.Environment.CurrentDirectory <- __SOURCE_DIRECTORY__
#load "utilities.fsx"
open Utilities

它负责所有的依赖关系。这些可以是运行从 Visual studio 使用 Alt + Enter 组合键或从命令行使用 fsi.exe MyScript.fsx

为什么我会收到 F# 错误 FS0039：命名空间或模块 'Http' 未定义

Why am I getting F# error FS0039: The namespace or module 'Http' is not defined

f#

f#-interactive

f#-data