从两个命名图中插入？

Question

我正在寻找一种简单的方法将来自两个或多个命名图（但不是整个未命名的默认图）的三元组插入到另一个命名图中。我正在使用GraphDB.

我想这可以通过在 WHERE 部分多次写出相同的查询，包装在多个 GRAPH 规范中，然后将它们联合在一起来完成，但是我的 WHERE 很长，我不想多次写出来。

假设我加载了一些这样的数据：

INSERT DATA {
  GRAPH <http://example.com/ngA> {
    <http://example.com/person1> <http://example.com/name> "Arthur" .
  }
  GRAPH <http://example.com/ngB> {
    <http://example.com/person1> <http://example.com/name> "Brian" .
  }
  GRAPH <http://example.com/ngC> {
    <http://example.com/person1> <http://example.com/name> "Charlie" .
  }
}

我可以将特定模式的所有三元组从默认的未命名图形复制到一个新的命名图形中，如下所示：

INSERT {
  GRAPH <http://example.com/ngZ> {
    ?s <http://example.com/moniker> ?o .
  }
}
WHERE
  { ?s  <http://example.com/name>  ?o }

从两个或多个（但不是全部）命名图中对给定模式的三元组进行 SELECT 的简单方法是

SELECT  *
FROM <http://example.com/ngA>
FROM <http://example.com/ngB>
WHERE
  { ?s  <http://example.com/name>  ?o }

如果我想将这些三元组从那些指定的图中复制到另一个图中怎么办？

当我尝试

时，GraphDB 8.3（以及 sparql.org 验证器）出现错误

INSERT {
  GRAPH <http://example.com/ngZ> {
    ?s <http://example.com/moniker> ?o .
  }
}
WHERE
  { SELECT  *
FROM <http://example.com/ngA>
FROM <http://example.com/ngB>
WHERE
  { ?s  <http://example.com/name>  ?o } }

Answer 1

试试这个查询：

PREFIX ex: <http://example.com/>

INSERT {
  GRAPH ex:ngZ { ?s ex:moniker ?o }
}
WHERE {
  GRAPH ?g { ?s ex:name ?o }  
  FILTER (?g IN ( ex:ngA, ex:ngB ) )
}

然后：

PREFIX ex: <http://example.com/>

SELECT * 
FROM NAMED ex:ngZ
WHERE { 
    GRAPH ?g { ?s ?p ?o }
} LIMIT 100

是你需要的吗？

顺便说一句，存在COPY (use with caution!) and ADD。

Answer 2

谢谢，@Stanislav Kralin

想想看，这也行：

PREFIX ex: <http://example.com/>
INSERT {
    GRAPH ex:ngZ {
        ?s ex:moniker ?o 
    }
}
WHERE {
    values ?g {
        ex:ngA ex:ngB 
    }
    GRAPH ?g {
        ?s ex:name ?o 
    }  
}

Answer 3

SPARQL Update 提供 USING 和 USING NAMED 类似于查询中的 FROM 和 FROM NAMED：

The USING and USING NAMED clauses affect the RDF Dataset used while evaluating the WHERE clause. This describes a dataset in the same way as FROM and FROM NAMED clauses

您可以像这样将需求表达为更新：

INSERT {
  GRAPH <http://example.com/ngZ> {
    ?s <http://example.com/moniker> ?o .
  }
}
USING <http://example.com/ngA>
USING <http://example.com/ngB>
WHERE
  {  ?s  <http://example.com/name>  ?o }

另请注意，根据 SPARQL query grammar，子查询不允许使用数据集子句。这就是 SPARQL 解析器拒绝您的查询的原因。

从两个命名图中插入？

insert from two named graphs?

sparql

graphdb

named-graphs