使用 GemBox 更新 DOCPROPERTY 字段

Question

我的文档有 DOCPROPERTY 字段，我正在尝试更新它们（标题、副标题等）。

Dim title As String = "New Title"
Dim subTitle As String = "New Sub Title"
Dim document = DocumentModel.Load(inputFile)

document.DocumentProperties.BuiltIn(BuiltInDocumentProperty.Title) = title
document.DocumentProperties.Custom("SubTitle") = subTitle

document.Save(outputFile)

但是最后的文档没有显示更新的值，我只能在MS Word中按F9刷新它们才能看到它们。如何使用 GemBox.Document 刷新它们？

我还有一些用宏更新的 DOCVARIABLE 字段。我可以用 GemBox.Document 更新它们吗？

Answer 1

更新 02-01-2020：
GemBox.Document 的当前最新错误修复版本引入了 API 对 Field.Update 的支持，因此从现在开始，可以简化 DOCPROPERTY 和 DOCVARIABLE 字段的更新，如下所示：

For Each field As Field In document.GetChildElements(True, ElementType.Field)
    field.Update()
Next

2017 年 11 月 10 日更新：
GemBox.Document 的当前最新错误修复版本引入了 API 对 DocumentModel.Variables 的支持，因此从现在开始可以更新自己的 DOCVARIABLE 字段，例如使用如下内容：

Dim variables As VariablesDictionary = document.Variables

For Each field As Field In document.GetChildElements(True, ElementType.Field).Cast(Of Field)().Where(Function(f) f.FieldType = FieldType.DocVariable)
    Dim instruction As String = field.GetInstructionText()
    Dim variableName As String = If(instruction.IndexOf(" "c) < 0, instruction, instruction.Remove(instruction.IndexOf(" "c)))
    Dim value As String = Nothing

    If variables.TryGetValue(variableName, value) Then
        field.ResultInlines.Clear()
        field.ResultInlines.Add(New Run(document, value) With {.CharacterFormat = field.CharacterFormat.Clone()})
    End If
Next

原文：
GemBox.Document 保存到 DOCX 文件时不会自动更新 DOCPROPERTY 字段。但是，它们会在保存为 PDF、XPS 或图像格式以及打印时更新。
不过，您可以使用以下内容更新它们：

Dim properties As DocumentProperties = document.DocumentProperties

For Each field As Field In document.GetChildElements(True, ElementType.Field).Cast(Of Field)().Where(Function(f) f.FieldType = FieldType.DocProperty)
    Dim instruction As String = field.GetInstructionText()
    Dim propertyName As String = If(instruction.IndexOf(" "c) < 0, instruction, instruction.Remove(instruction.IndexOf(" "c)))
    Dim value As String = Nothing

    Dim customValue As Object = Nothing
    Dim buildInProperty As BuiltInDocumentProperty

    If properties.Custom.TryGetValue(propertyName, customValue) Then
        value = customValue.ToString()
    ElseIf [Enum].TryParse(propertyName, buildInProperty) Then
        properties.BuiltIn.TryGetValue(buildInProperty, value)
    End If

    If Not String.IsNullOrEmpty(value) Then
        field.ResultInlines.Clear()
        field.ResultInlines.Add(New Run(document, value) With {.CharacterFormat = field.CharacterFormat.Clone()})
    End If
Next

~~另外关于 DOCVARIABLE 字段，这些字段目前无法使用 GemBox.Document 更新。~~

使用 GemBox 更新 DOCPROPERTY 字段

Updating DOCPROPERTY fields with GemBox

vb.net

ms-word

docvariable

gembox-document