如何从 4D 的工具箱中导出图片？

Question

我在远程模式下使用 4D 版本 11.6 (72398) 并尝试从数据库中导出三张图片。你如何从工具箱中提取图片？可以避免的截图和编辑是不可接受的。

Answer 1

工具箱的图片库区域没有导出功能。但是，以下命令将帮助您导出图片：

PICTURE LIBRARY LIST 获取图片名称数组和图片参考 ID 数组

GET PICTURE FROM LIBRARY 使用图片参考 ID 将图片从图片库中获取到图片变量中。

WRITE PICTURE FILE 将 Picture 变量写入磁盘。

以下代码可用于将图片库中的所有图片作为 PNG 文件导出到磁盘。

C_TEXT($vsPicName;$vsFileName)
C_LONGINT($vlNbPictures;$vlPicture;$vlPicRef)
C_PICTURE($vgPicture)
ARRAY TEXT($asPicName;0)
PICTURE LIBRARY LIST($alPicRef;$asPicName)
$vlNbPictures:=Size of array($alPicRef)
If ($vlNbPictures>0)
    For ($vlPicture;1;$vlNbPictures)
        $vlPicRef:=$alPicRef{$vlPicture}
        $vsPicName:=$asPicName{$vlPicture}
        GET PICTURE FROM LIBRARY($alPicRef{$vlPicture};$vgPicture)
        If (OK=1)
            $vsFileName:=String($vlPicRef)+$vsPicName+".png"
            WRITE PICTURE FILE($vsFileName;$vgPicture;".png")
        End if 
    End for 
Else 
    ALERT("The Picture Library is empty.")
End if

如果您运行上面的代码来自单用户或服务器，文件将放在结构文件旁边。

如果您运行来自客户端的上述代码，文件将被放入 4D 客户端缓存文件夹中，可以使用以下代码快速打开该文件夹：

SHOW ON DISK(Get 4D folder(4D Client Database Folder);*)

如何从 4D 的工具箱中导出图片？

How do you export pictures from 4D's tool box?

4d-database