如何在 AppEngine 项目中使用 Kotlin Gradle

Question

正如标题所说，如何在开发AppEngine项目时使用Kotlin？我正在使用 IntelliJ/Android Studio 和 Gradle 作为我的构建工具。

Answer 1

由于 AppEngine 执行已编译的 .class 文件，因此它不关心生成这些文件的 JVM 语言是什么。这意味着我们可以使用 Kotlin。

一种方法是使用 Gradle 和 Gradle App Engine plugin. Create a project with a build.gradle that looks something like this。然后添加 Kotlin 依赖项并应用插件。最终构建文件如下所示：

buildscript {
    ext.kotlin_version = '1.0.6' //replace with latest Kotlin version
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.google.appengine:gradle-appengine-plugin:1.9.32' //Replace with latest GAE plugin version
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

repositories {
    mavenCentral();
}

apply plugin: 'java'
apply plugin: 'kotlin'
apply plugin: 'war'
apply plugin: 'appengine'

sourceCompatibility = JavaVersion.VERSION_1_7
targetCompatibility = JavaVersion.VERSION_1_7

dependencies {
    appengineSdk 'com.google.appengine:appengine-java-sdk:1.9.32' //Replace with latest GAE SDK version
    compile 'javax.servlet:servlet-api:2.5'
    compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
}

appengine {
    downloadSdk = true
    appcfg {
        oauth2 = true
    }
}

从 M11 开始，您不需要为 Kotlin 文件创建单独的目录，因此您只需将 .kt 文件添加到 src/main/java。

如何在 AppEngine 项目中使用 Kotlin Gradle

How to use Kotlin in AppEngine projects using Gradle

google-app-engine

gradle

kotlin