antlr4 无法将文字提取到令牌中

Question

我有以下语法，我正在尝试慢慢开始，逐步处理复杂的论点。

grammar Command;

commands : command+ EOF; 
command : NAME args NL;
args : arg | ;

arg : DASH LOWER | LOWER;
//arg : DASH 'a' | 'x';

NAME : [_a-zA-Z0-9]+;
NL : '\n';
WS : [ \t\r]+ -> skip ; // spaces, tabs, newlines
DASH : '-';
LOWER: [a-z];//'a' .. 'z';

我希望（现在）像这样解析文件：

cmd1
cmd3 -a

如果我运行通过 g运行输入我得到一个错误：

$ java org.antlr.v4.gui.TestRig Command commands -tree
...
`line 3:6 mismatched input 'a' expecting LOWER`

LOWER 似乎应该匹配 'a'。如果我将 arg 定义更改为注释掉的行，它可以正常工作，并且我将“-a”作为 arg。使用 LOWER 和显式使用 'a' 有什么区别？

Answer 1

一旦出现 "mismatched" 错误，将 -tokens 添加到 grun 以显示标记，这有助于找出您认为词法分析器将执行的操作与实际执行的操作之间的差异。用你的语法 :

$ alias grun='java org.antlr.v4.gui.TestRig'
$ grun Command commands -tokens -diagnostics t.text
[@0,0:3='cmd1',<NAME>,1:0]
[@1,4:4='\n',<'
'>,1:4]
[@2,5:8='cmd3',<NAME>,2:0]
[@3,10:10='-',<'-'>,2:5]
[@4,11:11='a',<NAME>,2:6]
[@5,12:12='\n',<'
'>,2:7]
[@6,13:12='<EOF>',<EOF>,3:0]
line 2:6 mismatched input 'a' expecting LOWER

您立即看到字母 a 是 NAME 而不是预期的 LOWER。

另请注意空选项的规则：

args
    :   arg
    |
    ;

在某些情况下可能会导致问题。我更喜欢显式添加 ? 后缀，这意味着零次或一次。所以我的解决方案是：

grammar Command;

commands
@init {System.out.println("Question last update 1829");}
    :   command+ EOF
    ; 

command
    :   NAME args? NL
    ;

args
    :   arg
    ;

arg : DASH? LOWER ;

LOWER : [a-z] ;
NAME  : [_a-zA-Z0-9]+;
DASH  : '-' ;
NL    : '\n' ;
WS    : [ \t\r]+ -> skip ;

执行：

$ grun Command commands -tokens -diagnostics t.text
[@0,0:3='cmd1',<NAME>,1:0]
[@1,4:4='\n',<'
'>,1:4]
[@2,5:8='cmd3',<NAME>,2:0]
[@3,10:10='-',<'-'>,2:5]
[@4,11:11='a',<LOWER>,2:6]
[@5,12:12='\n',<'
'>,2:7]
[@6,13:12='<EOF>',<EOF>,3:0]
Question last update 1829

antlr4 无法将文字提取到令牌中

antlr4 can't extract literal into token

lexer

antlr4