Netlogo：找到下一个目标折扣以前的目标

Question

我试图让我的代理在达到第一个目标后计算下一个补丁目标。目标定义为（最高补丁影响值/到代理的距离）。下一个目标需要使用相同的程序计算，但也需要从等式中扣除任何先前的目标。

我试图创建一个补丁集来包含所有目标，但我不确定它是否有效。

我的问题是如何创建计算下一个最高影响值的报告函数。我完全陷入了程序的最后一部分。

我最初的记者职能是：

to-report highest-influence
  let available-target patches with [influence > 0] ;and not any? patches with [pcolor = green]
  report max-one-of available-target [influence / distance myself]
end

但我不确定如何让下一个报告函数使用相同的参数，同时也忽略任何以前的目标

to-report next-highest-influence
  ; patches with [influence > 0] and not part of patch set
end

如有任何帮助，我们将不胜感激。我已经提供了完整的代码。

breed [walkers walker]

walkers-own [traveled?  ;; parameter to keep track of if a walker has traveled to a target yet or not 
             target ]

patches-own [influence influence-set] ;highest-influence

to setup
  clear-all
  reset-ticks
  define-patches
  create-walkers num-walkers
  ask walkers [
    setxy 0 0
    set heading 90
    let streets neighbors with [pcolor = black]
    ifelse any? streets in-cone 1 25
        [fd 1]
        [move-to one-of streets in-radius 1]
    set traveled? false    ;; so that walkers know they have not yet moved to a target
    ]
  ask walkers [
    define-target ]
end

to define-patches
  ask n-of 100 patches [
    set pcolor white
    ]
  ask n-of 40 patches with [pcolor = white] [set influence random 5 set pcolor blue set plabel influence]
  ask patches [set influence-set patches with [pcolor = green] ]
end

to define-target        ;; this defines the initial destination of walkers 
  if traveled? = false [
  set target highest-influence
  ask target [set pcolor green]
    face target ]
end

to new-target            ;; this defines subsequent desinations after walkers have reached inital target 
  if traveled? = true [
    set target next-highest-influence
    ask target [set pcolor green + 2]
       face target ]
end

;;;;;;;;;;;;run-time procedure;;;;;;;;;;

to go
   ask walkers [
    if distance target > 1
      [ travel-walkers
        leave-a-trail 
        set traveled? true ]
    if distance target = 1
      [ stop
        new-target
        travel-walkers
        leave-a-trail
       ]
    ]
  tick
end

to travel-walkers  
    ask walkers [
       move-towards-target 
   ]  
end

to move-towards-target
 ask walkers [ 
  ifelse [pcolor] of patch-ahead 1 != white or any? other turtles-here
    [ Move-Function ]
    [ Avoid-Function ]
  ]  
end

to Move-Function
  let t target
  face min-one-of all-possible-moves [distance t]
  fd 1
end

to Avoid-Function
  let t target
  face min-one-of all-possible-moves [distance t]
end

to leave-a-trail
  ask patch-here [set pcolor grey]
end

;;;;;; reporter calculations ;;;;;;
to-report highest-influence
  let available-target patches with [influence > 0] ;and not any? patches with [pcolor = green]
  report max-one-of available-target [influence / distance myself]
end

to-report next-highest-influence
  ; patches with [influence > 0] and not part of patch set
end

to-report all-possible-moves
  report patches in-radius 1 with [pcolor != white and distance myself  <= 1 and distance myself  > 0 and plabel = "" ]
end

Answer 1

您可以使用 member? 原语来做到这一点。查看下面的简化玩具模型（我没有使用您的代码，因为我不确定您想要如何实现，并且我需要设置一些界面部分才能运行它。查看MCVE guidelines）。

turtles-own [ visited-list ]
patches-own [ influence ]

to setup-member?
  ca
  crt 1 [ set visited-list [] ]
  ask patches [ set influence 0 ]
  ask n-of 5 patches [ set influence 5 + random 50 ]
  reset-ticks
end

to go-member?
  ask turtles [
    let target highest-influence
    ifelse target != nobody [
      face target
      ifelse distance target > 1 [
        fd 1
      ] [
        move-to target
        ask target [ set pcolor red]
        set visited-list lput target visited-list
      ]
    ] [ print "No targets remaining." ]
  ]
  tick
end

to-report highest-influence
  let to-visit patches with [ 
    influence > 0 and 
    not member? self [visited-list] of myself ]
  report max-one-of to-visit [ influence / ( distance myself )]
end

报告的 returns 具有最高 influence/distance 值的补丁不是乌龟 visited-list 的成员。最初，没有补丁是列表的成员，但是当海龟访问每个目标时，它将目标添加到 visited-list 以便不再考虑补丁。

Netlogo：找到下一个目标折扣以前的目标

Netlogo: find next target discounting previous targets

netlogo