Delphi：Object 使用 [weak] 属性的聚合和内存泄漏

Question

我想通过聚合构建一个包含多个 child object 的 class TParent。有些 object 是独立的，而有些也可以依赖于其他 children。所有 children object 都必须引用 parent。我还想尽可能使用接口。

为此，我将 TInterfacedObject 用于 TParent，将 TAggregatedObject 用于 children。由于 child 和 parent 彼此了解，我使用弱引用以避免循环依赖。事实上，这种行为已经在 TAggregatedObject 中定义。当我只使用独立的 child objects (TIndependantChild).

时一切正常

当 child object 也依赖于其他 children 时出现问题，请参阅 TDependantChild 的构造函数。我将对另一个 child object 的引用存储在 fChild 变量中，该变量标有 [weak] 属性，在 Delphi 10 Berlin 中引入。 FastMM4 在关闭时报告内存泄漏：

还会引发导致 System.TMonitor.Destroy 的访问冲突，但这仅在使用 FastMM4 且 ReportMemoryLeaksOnShutDown 为 True 时才会发生。

program Project1;

{$APPTYPE CONSOLE}

uses
  FastMM4,
  System.SysUtils;

type
  IParent = interface
  ['{B11AF925-C62A-4998-855B-268937EF30FB}']
  end;

  IChild = interface
  ['{15C19A4E-3FF2-4639-8957-F28F0F44F8B4}']
  end;

  TIndependantChild = class(TAggregatedObject, IChild)
  end;

  TDependantChild = class(TAggregatedObject, IChild)
  private
    [weak] fChild: IChild;
  public
    constructor Create(const Controller: IInterface; const AChild: IChild); reintroduce;
  end;

  TParent = class(TInterfacedObject, IParent)
  private
    fIndependantChild: TIndependantChild;
    fDependantChild: TDependantChild;
  public
    constructor Create;
    destructor Destroy; override;
  end;

{ TParent }

constructor TParent.Create;
begin
  fIndependantChild := TIndependantChild.Create(Self);
  fDependantChild := TDependantChild.Create(Self, fIndependantChild);
end;

destructor TParent.Destroy;
begin
  fDependantChild.Free;
  fIndependantChild.Free;
  inherited;
end;

{ TDependantChild }

constructor TDependantChild.Create(const Controller: IInterface; const AChild: IChild);
begin
  inherited Create(Controller);
  fChild := AChild;
end;

var
  Owner: IParent; 

begin
  ReportMemoryLeaksOnShutDown := True;
  Owner := TParent.Create;
  Owner := nil;
end.

我发现，使用 [unsafe] 而不是 [weak] 可以解决问题，但是根据 delphi help

It ([unsafe]) should be only used outside the System unit in very rare situations.

因此，我不相信我应该在这里使用 [unsafe]，尤其是当我不明白会发生什么的时候。

那么，这种情况下内存泄漏的原因是什么，如何解决呢？

Answer 1

使用外部 FastMM4 内存管理器时的泄漏和崩溃问题与以下有关用于跟踪弱引用的内部 HashMap 最终确定的问题有关。

[REGRESSION XE2/10.1 Berlin] Unable to use 3rd party memory managers

由于这个问题，无法在 Delphi 10.1 和更新版本中使用第三方内存管理器进行泄漏检测，包括外部 FastMM4。

这就是为什么 [weak] 属性有问题而 [unsafe] 没有问题的原因。

就您的代码而言，您可以在上述情况下安全地使用 [unsafe]。虽然文档中有关于使用 [unsafe] 属性的警告，但该警告实际上并没有解释为什么不应使用 [unsafe]。

长话短说，当 [unsafe] 引用引用的对象实例的生命周期长于引用本身的生命周期时，您可以使用 [unsafe] 属性。

换句话说，你必须确保在它指向的对象实例被释放后，你不会访问[unsafe]引用，仅此而已。

[unsafe]引用在指向的对象被销毁时不会清零，在对象消失后使用这样的引用会导致访问冲突异常。

将 [weak] 属性替换为 [unsafe] 是您所要做的所有事情，以便拥有您提供的正确功能代码。

  TDependantChild = class(TAggregatedObject, IChild)
  private
    [unsafe] fChild: IChild;

Delphi：Object 使用 [weak] 属性的聚合和内存泄漏

Delphi: Object aggregation and memory leaks using [weak] attribute

delphi

memory-leaks

unsafe

weak

aggregation