AMPL Cplex error: QP Hessian is not positive semi-definite

Question

我目前正在尝试求解一个 AMPL 模型，该模型使用 minos 为我运行，具有 cplex 和积分变量。

我已经解决了大部分问题（我认为）。从这里帮助自己 "ratio trick"：http://lpsolve.sourceforge.net/5.5/ratio.htm，但现在我从我的一个约束中得到 "QP Hessian is not positive semi-definite." 错误。

我有点知道这个错误是什么意思，但我不确定为什么它会显示这个约束：/

#S
set SOURCE;
#D
set HALFPROD;
#K
set HALFPRODU;
#P
set PROD;

param surmax {SOURCE} >= 0;
param prodmin {PROD} >= 0;
param prodprofit {PROD} >= 0;
param convSDmax >= 0;
param convDKmax >= 0;
param convSD {SOURCE, HALFPROD} >= 0;
param convDK {HALFPROD, HALFPRODU} >= 0;
param convDP {HALFPROD, PROD} >= 0;
param convKP {HALFPRODU, PROD} >= 0;

var xs {SOURCE} >= 0, integer;
var xu {HALFPROD} >= 0, integer;
var xpd {PROD, HALFPROD} >= 0, integer;
var xpk {PROD, HALFPRODU} >= 0, integer;
var isKUsed binary;

var quantityD {j in HALFPROD} = sum {i in SOURCE} convSD[i,j] * xs[i];
var costSur = sum {i in SOURCE} xs[i]*12;

var quantityK {k in HALFPRODU} = (sum {j in HALFPROD} xu[j] * convDK[j,k]) * isKUsed;
var costK = isKUsed * 13000;

var quantityProdD {l in PROD} = sum {j in HALFPROD} xpd[l,j] * convDP[j,l];
var quantityProdK {l in PROD} = sum {k in HALFPRODU} xpk[l,k] * convKP[k,l];
var quantityProd {l in PROD} = quantityProdD[l] + quantityProdK[l];

var profitProd = sum {l in PROD} prodprofit[l] * quantityProd[l];
var balance = profitProd - costSur - costUwod;

subject to OgrSurMax {i in SOURCE}: xs[i] <= surmax[i];
subject to OgrconvSDMax: (sum {i in SOURCE} xs[i]) <= convSDmax;
subject to OgrconvDKMax: (sum {j in HALFPROD} xu[j]) <= convDKmax;
subject to OgrProdMin {l in PROD}: quantityProd[l] >= prodmin[l];
subject to OgrHALFPRODXPD {j in HALFPROD}: (sum {l in PROD} xpd[l,j]) + xu[j] - quantityD[j] <= 0;
#------------------TRAITOR!
subject to OgrHALFPRODXPK {k in HALFPRODU}: (sum {l in PROD} xpk[l,k]) - quantityK[k] <= 0;
#--------------------------

maximize balanceMax: balance;

这是我的模型。

"conv"代表转换：

S->D 和 D->K 是比率 "how much of D I get from converting S?"
D->P 和 K->P 是二进制矩阵，表示 D 或 K 是否可以转换为 P

此模型中的主要参与者是 xpd 和 xpk - 他们说从转换 HALFPROD 或 HALFPRODU 获得了多少 PROD。由于多次转换，我必须跟踪 D 的数量 - 用于 D->K 和 D->P 的 D 的数量必须小于或等于来自 S->D 的 D。这可行，但由于某种原因，相同（甚至更简单）的约束不起作用：/

关于可能是什么问题或如何解决问题的任何线索？

更新：

根据 Erwin Kalvelagens 的回答，我尝试将其线性化。除了 bigM 方法之外，找不到将其线性化的简单方法。我已将我的 quantityD 部分更改为：

param quantityKMAX = 490860;
var quantityK {k in HALFPRODU} >= 0;
s.t. ogrK1 {k in HALFPRODU}: quantityK[k] <= quantityKMAX * isKUsed;
s.t. ogrK2 {k in HALFPRODU}: quantityK[k] <= (sum {j in HALFPROD} xu[j] * convDK[j,k]);
s.t. ogrK3 {k in HALFPRODU}: quantityK[k] <= (sum {j in HALFPROD} xu[j] * convDK[j,k]) - quantityKMAX * (1 - isKUsed);

quantityKMAX 是从转换中获得的最大数量（当将 D 的最大可能数量转换为 "most giving" K 时），但我实际上已经尝试过任意大数字，肯定大于 quantityK.

的任何可能值

有效！

Answer 1

Cplex 只能处理某些类的二次约束（一般来说——除了一些例外——事情必须保持凸）。在变量 quantityK 的定义中，您引入了 Cplex 无法处理的二次表达式。

一个简单的方法就是将问题解决两次：一次使用 isKUsed=0，一次使用 isKUsed=1。然后选择最好的解决方案。

否则你可以将事情线性化。二进制变量乘以连续（或整数）非负变量的乘积不是很难线性化。

AMPL Cplex error: QP Hessian is not positive semi-definite

AMPL Cplex error: QP Hessian is not positive semi-definite

optimization

cplex

ampl