一个有多个子目录的大项目，如何写"CMakeLists.txt"？

Question

我正在进行一个模拟项目：从目标平台获取一个 嵌入式 C 代码库，并尝试在主机上模拟它以进行调试或单步执行代码。

OS：Ubuntu Linux 14.04，IDE：CodeLite，Makefile 生成器：Cmake。我很困惑如何为项目编写CMakeLists.txt。下面是代码库的结构（都是用C写的）：

|ARQSim\  
|-->ARQSim.h  
|-->ARQSim.c  
|-->BaseStationCode\  
|   |->downlink.c  
|   |->neoncopy.c  
|   |->armCore\  
|   |  |->common\  
|   |  |  |->Bsconfig.h  
|   |  |  |->config.h  
|   |  |->MacSource\  
|   |  |  |->lib\  
|   |  |  |  |->arqCommon.h  
|   |  |  |  |->OverTheAir.h  
|   |  |  |->source\  
|   |  |  |  |->beacon.c  
|   |  |  |  |->proxyDhcp.c  
|   |  |  |  |->ARQ\  
|   |  |  |  |  |->arqCommon.c  
|   |  |  |  |  |->arqInterface.c  
|   |  |  |  |  |->fragmentation\  
|   |  |  |  |  |  |->fragBookkeeping.c  
|   |  |  |  |  |  |->fragProcessAck.c  
|   |  |  |  |  |->reassembly\  
|   |  |  |  |  |  |->reasmBookkeeping.c  
|   |  |  |  |  |  |->reasmProcessAck.c

我是 Cmake 的新手。我在 Whosebug 上阅读了很多关于 CMake 和线程的资源。但我每次都感到困惑。我有几个问题：

我是只需要根目录下的一个 CMakeLists.txt 还是每个目录都需要一个不同的 CMakeLists.txt 文件？
如何在CMakeLists.txt中递归添加源文件？
为了生成 MakeFile，我需要在 CMakeLists.txt 中输入哪些基本命令？

一个基于上述代码结构的示例将不胜感激。

Answer 1

Do I need only one CMakeLists.txt at root directory or every directory needs a different CMakeLists.txt file?

您通常会在树的每个级别都有一个 有意义的地方

例如：

root/
+--- CMakeLists.txt             // your root CMakeLists
+--- foo/
|    +--- CMakeLists.txt        // foo component's CMakeLists
|    +--- foo.c
|    +--- tests/
|         +--- CMakeLists.txt   // foo test's CMakeLists
|         +--- foo_tests.c
+--- bar/
     +--- CMakeLists.txt        // bar component's CMakeLists
     +--- bar.c
     +--- bar_impl/             // no CMakeLists for this dir, it is part of bar
     |    +--- bar_impl.c
     +--- tests/
          +--- CMakeLists.txt   // bar test's CMakeLists
          +--- bar_tests.c

项目根目录 CMakeLists.txt:

在项目根目录 CMakeLists.txt 中指定最低 cmake 要求、项目名称，并包含包含各种组件的子目录

root/CMakeLists.txt:

cmake_minimum_required (VERSION 3.5)
project (my_project C)

add_subdirectory(foo)
add_subdirectory(bar)

组件 CMakeLists.txt:

然后在每个组件子目录中，您还有另一个 CMakeLists.txt 文件，您可以在其中添加库、可执行文件等

root/foo/CMakeLists.txt:

add_library(foo foo.c)
target_include_directories(foo PUBLIC ${CMAKE_CURRENT_SOURCE_DIR})

add_subdirectory(tests)

root/foo/tests/CMakeLists.txt:

add_executable(foo_test foo_tests.c)
target_link_libraries(foo_test foo)

您按照此结构进行酒吧等...

root/bar/CMakeLists.txt:

add_library(bar 
    bar.c 
    bar_impl/bar_impl.c)
target_include_directories(bar PUBLIC ${CMAKE_CURRENT_SOURCE_DIR})
target_link_libraries(bar foo)

add_subdirectory(tests)

root/bar/tests/CMakeLists.txt:

add_executable(bar_test bar_tests.c)
target_link_libraries(bar_test bar)

正在生成构建文件：

为了 bootstrap 你的构建，你将 cmake 指向你的 root/CMakeLists.txt

cd root
mkdir build
cd build
cmake ..

（或使用您的 ide 的构建管理器生成其构建配置）

进一步阅读

有关我在这里使用的各种功能的详细信息，请参阅文档：

最后，回答你的第二个问题：

How to add the source files recursively in CMakeLists.txt?

不推荐这样做（有关详细信息，请参阅）。

最好明确列出要包含在目标中的每个文件。

请注意，如果您在几个不同的目录中有源文件，但它们都属于同一个逻辑目标，那么您不需要每个目录都有一个 CMakeLists.txt 文件 - 只需在文件名

示例：

foo/
+--- foo.c
+--- bar.c
+--- baz/
     +--- baz.c
     +--- bang.c

如果你想要一个目标 foo 用于所有上述文件，你可以按如下方式创建它：

add_library(foo 
   foo.c
   bar.c
   baz/baz.c
   baz/bang.c)

或者如果你真的想用一个变量来存储 SRCS

的列表

set(SRCS 
   foo.c
   bar.c
   baz/baz.c
   baz/bang.c)

add_library(foo ${SRCS})

Answer 2

我也在寻找一种更通用的方法来将 CMakeLists.txt 文件添加到我的项目中。我决定编写一个 CMake 生成器（部分原因是我想了解 CMake 的工作原理）：

https://github.com/Aenteas/cmake-generator

它有几个附加功能，例如创建 python 包装器 (SWIG)。

编写一个适合每个人的生成器是不可能的，但我希望它能给你一个想法，以防你想要制作你的定制版本。

一个有多个子目录的大项目，如何写"CMakeLists.txt"？

How to write "CMakeLists.txt" for a big project with multiple subdirectories?

c

linux

makefile

cmake

codelite

项目根目录 CMakeLists.txt:

组件 CMakeLists.txt:

正在生成构建文件：

进一步阅读