React Native - 从 package.json 到 android 构建清单的自动版本名称

Question

目前我有一个 React 本机应用程序，我遇到的问题是在每次构建或提交时更新版本非常耗时。

此外，我启用了 Sentry，所以每次构建时，一些构建都会获得相同的版本，因此一些崩溃很难确定它们的来源。

最后，手动更新版本容易出错。

我如何设置我的构建以在每次构建时生成一个自动版本而忘记所有这些手动任务？

Answer 1

由于我已经为此工作了几天，所以我决定与大家分享我是如何做到的，因为它可以帮助到其他人。

使用的工具：

GitVersion：我们将使用 GitVersion 根据许多因素自动生成语义版本，例如当前分支、标签、提交等。这个工具做得很好，你可以忘记命名你的版本。当然，如果您为提交设置标签，它将使用该标签作为名称。
PowerShell：Microsoft 构建的此命令行OS 可以从Mac、Linux 或Windows 运行，我选择它是因为构建可以与 OS 版本无关。例如，我在 Windows 上开发，但构建机器有 MacOS。

编辑应用程序build.gradle

应用程序gradle只需要在末尾添加一行。在我的例子中，我有 Google Play Services gradle 然后我添加了它。

apply from: 'version.gradle'

version.gradle

此文件应与您的应用位于同一文件夹中gradle，内容如下：

task updatePackage(type: Exec, description: 'Updating package.json') {
    commandLine 'powershell', ' -command ' , '$semver=(gitversion /showvariable Semver); Set-Content -path version.properties -value semver=$semver; npm version --no-git-tag-version --allow-same-version $semver'  
}
preBuild.dependsOn updatePackage

task setVariantVersion {

    doLast {

        if (plugins.hasPlugin('android') || plugins.hasPlugin('android-library')) {

            def autoIncrementVariant = { variant ->
                variant.mergedFlavor.versionName = calculateVersionName()
            }

            if (plugins.hasPlugin('android')){
                //Fails without putting android. first
                android.applicationVariants.all { variant -> autoIncrementVariant(variant) }
            }

            if (plugins.hasPlugin('android-library')) {
                //Probably needs android-library before libraryVariants. Needs testing
                libraryVariants.all { variant -> autoIncrementVariant(variant) }
            }
        }

    }

}
preBuild.dependsOn setVariantVersion
setVariantVersion.mustRunAfter updatePackage

ext {
    versionFile = new File('version.properties')
    calculateVersionName = {
        def version = readVersion()
        def semver = "Unknown"
        if (version != null){
            semver = version.getProperty('semver')
        }
        return semver
    }
}

Properties readVersion() {
    //It gets called once for every variant but all get the same version
    def version = new Properties()
    try {
        file(versionFile).withInputStream { version.load(it) }
    } catch (Exception error) {
        version = null
    } 
    return version
}

现在，让我们回顾一下脚本实际做了什么：

updatePackage：此任务运行在构建的最开始（实际上在 preBuild 之前），它执行 gitversion 以获取当前版本，然后创建一个 version.properties稍后由 gradle 读取以获取版本的文件。
setVariantVersion：这会在每个变体上调用 afterEvaluate。这意味着如果您有多个构建，如调试、发布、质量检查、暂存等，所有构建都将获得相同的版本。对于我的用例，这很好，但您可能想要对此进行调整。
任务顺序：让我困扰的一件事是在文件生成之前版本是运行。这是通过使用 mustRunAfter 标记修复的。

PowerShell 脚本解释

这是第一个得到运行的脚本。让我们回顾一下正在做什么：

$semver=(gitversion /showvariable Semver);
Set-Content -path props.properties -value semver=$semver; 
npm version --no-git-tag-version --allow-same-version $semver

第 1 行：gitversion 有多种类型的版本。如果你运行它没有任何参数，你将得到一个包含许多变体的 json 文件。这里我们说我们只想要 SemVer。（另请参阅 FullSemVer）
第 2 行：创建文件并将内容保存到其中的 PowerShell 方式。这也可以用 > 来完成，但我遇到了编码问题并且没有读取属性文件。
第 3 行：此行更新您的 package.json 版本。默认情况下，它会将新版本的提交保存到 git。 --no-git-tag-version 确保您不会覆盖它。

就是这样。现在每次构建时，版本应该自动生成，您的 package.json 更新并且您的构建应该具有特定的版本名称。

应用中心

由于我使用 App Center 进行构建，我将告诉您如何在构建机器中使用它。您只需要使用自定义脚本。

app-center-pre-build.sh

#!/usr/bin/env sh
#Installing GitVersion
OS=$(uname -s)
if [[ $OS == *"W64"* ]]; then
    echo "Installing GitVersion with Choco"
    choco install GitVersion.Portable -y
else 
    echo "Installing GitVersion with Homebrew"
    brew install --ignore-dependencies gitversion
fi

这是必需的，因为 GitVersion 当前不是构建机器的一部分。此外，您需要在安装时忽略单声道依赖项，否则当 brew 尝试 link 文件时会出现错误。

Answer 2

虽然目前接受的答案可行，但有一种更简单、因此更可靠的方法。您实际上可以直接从 build.gradle.

读取 package.json 中设置的值

修改你的android/app/build.gradle：

// On top of your file import a JSON parser
import groovy.json.JsonSlurper

// Create an easy to use function
def getVersionFromNpm() {
    //  Read and parse package.json file from project root
    def inputFile = new File("$rootDir/../package.json")
    def packageJson = new JsonSlurper().parseText(inputFile.text)

    // Return the version, you can get any value this way
    return packageJson["version"]
}

android {
    defaultConfig {
        applicationId "your.app.id"
        versionName getVersionFromNpm()
    }
}

这样您就不需要预构建脚本或任何东西，它就可以正常工作。

Answer 3

@MacRusher 版本对我来说很好。为了更多的读者，我不得不添加 .toInteger() 以使其工作。因为我使用 yarn version --patch 来自动升级 package.json 中的版本，所以我也只需要使用前两个字符。

这是新版本：

// On top of your file import a JSON parser
import groovy.json.JsonSlurper

def getVersionFromPackageJson() {
    //  Read and parse package.json file from project root
    def inputFile = new File("$rootDir/../package.json")
    def packageJson = new JsonSlurper().parseText(inputFile.text)

    // Return the version, you can get any value this way
    return packageJson["version"].substring(0,2).toInteger()
}

android {
    defaultConfig {
        applicationId "your.app.id"
        versionName getVersionFromPackageJson()
    }
}

React Native - 从 package.json 到 android 构建清单的自动版本名称

React Native - Automatic version name from package.json to android build manifest

android

gradle

node.js

gitversion

react-native

编辑应用程序build.gradle

version.gradle

PowerShell 脚本解释

应用中心

app-center-pre-build.sh