VBS 到桌面上的地址文件

Question

我是 VBS 菜鸟所以请原谅这个简单的问题。我创建了一个脚本来在我的桌面上打开一个 .xlsx 文档，并执行运行各种操作。我想将脚本移植给其他用户。也就是说，我如何创建适用于所有用户的路径，即用户桌面变量。在 PowerShell 中，我可以执行 '$env:USERPROFILE + '\Desktop''，它将寻址当前用户的桌面。是否有 VBS 等效项？

我目前拥有的：

Set xl = CreateObject("Excel.application")
xl.Application.Visible = True

Dim wb1
Set wb1 = xl.Application.Workbooks.Open("C:\Users\Username\Desktop\Missed_Scans\Reports\Report.xlsx")
Dim wb2
Set wb2 = xl.Workbooks.Add

wb1.Sheets("Incomplete_ASINs").Range("$A:$J951").AutoFilter 1, "SDF8"
wb1.Sheets("Incomplete_ASINs").Columns("B:D").Copy
wb2.Worksheets(1).Paste
wb2.Worksheets(1).Rows(1).AutoFilter
wb2.SaveAs "C:\Users\Username\Desktop\Missed_Scans\Reports\Missed_Scans.xlsx", 51, , , , False
wb2.Close
wb1.Close False
xl.Quit
Set xl = Nothing

第5行和第13行是需要使用某种类型的用户环境变量的区域。我知道 environ("UserName") 可以提供用户名，但我不确定如何合并它。

Answer 1

只需使用ExpandEnvironmentStrings:

Set osh = CreateObject("wscript.shell")
xl.workbooks.open osh.ExpandEnvironmentStrings("%userprofile%\Desktop\Missed_Scans\Reports\Report.xlsx")

对于第 13 行，您也可以这样写：

wb2.SaveAs osh.ExpandEnvironmentStrings("%userprofile%\Desktop\Missed_Scans\Reports\Missed_Scans.xlsx"), 51, , , , False

更新：

注意：我没有对任何逻辑做任何改动。刚刚删除了错误。

Set xl = CreateObject("Excel.application")
xl.Application.Visible = True

Dim wb1
Set osh = CreateObject("wscript.shell")
Set wb1 = xl.Workbooks.Open(osh.ExpandEnvironmentStrings("%userprofile%\Desktop\Missed_Scans\Reports\Report.xlsx"))
Dim wb2
Set wb2 = xl.Workbooks.Add

wb1.Sheets("Incomplete_ASINs").Range("$A:$J951").AutoFilter 1, "SDF8"
wb1.Sheets("Incomplete_ASINs").Columns("B:D").Copy
wb2.Worksheets(1).Paste
wb2.Worksheets(1).Rows(1).AutoFilter
wb2.SaveAs osh.ExpandEnvironmentStrings("%userprofile%\Desktop\Missed_Scans\Reports\Missed_Scans.xlsx"), 51, , , , False
wb2.Close
wb1.Close False
xl.Quit
Set xl = Nothing

VBS 到桌面上的地址文件

VBS to address file on desktop

vbscript

desktop