使用正确名称的 Suave 发送（zip）文件

Question

我一直在研究使用 Suave 创建 Web 服务器。目前，我正试图让它在 GET 请求中发送一个 zip 文件。我已经成功地让我的应用程序发送了一个文件，但是我在 Postman 中执行请求时收到的文件的名称是 "response" 或 "response.html"，具体取决于 Suave 的 Files 模块中的哪个函数 I采用。也就是说，当我手动将文件重命名为 .zip 时，我可以像打开普通 .zip 文件一样打开和解压缩它，这意味着问题确实出在下载文件的名称上。下面的代码是我现在得到的。

open JSON
open System
open System.Threading
open Suave
open Suave.Filters
open Suave.Operators
open Suave.Successful
open Suave.Web
open System.IO
open Suave.Writers

let sampleJsonPath = @"C:\VS Projects\Research\Sample.json"
let sampleZipPath = @"C:\VS Projects\Research\Sample.zip"
let getJson() =
    File.ReadAllText(sampleJsonPath)

[<EntryPoint>]
let main argv = 
    let cts = new CancellationTokenSource()
    let mimeTypes =
        defaultMimeTypesMap
            @@ (function | ".zip" -> createMimeType "compression/zip" false | _ -> None)

    let config =
        { defaultConfig with 
            mimeTypesMap = mimeTypes
            cancellationToken = cts.Token
        }

    let app = 
        choose 
            [ GET >=> choose
                [ path "/hello" >=> OK "Hello GET"
                path "/jsonString" >=> OK (getJson())
                path "/jsonFile" >=> warbler (fun _ -> getJson() |> JSON)// for only on startup: ... >=> (getJson() |> JSON)
                path "/zip" >=> Files.sendFile sampleZipPath false
                path "/goodbye" >=> OK "Goodbye GET" ]
            POST >=> choose
                [ path "/hello" >=> OK "Hello POST"
                pathScan "/content/%d" (fun param -> OK (sprintf "Found integer:\n%d" param))
                pathScan "/content/%s" (fun param -> OK (sprintf "Found content:\n%s" param))
                path "/goodbye">=> OK "Goodbye POST" ]
            RequestErrors.BAD_REQUEST "Unknown request encountered"
            ]
    let listening, server = startWebServerAsync config app

    Async.Start(server, cts.Token)
    printfn "Ready to receive requests"
    Console.ReadKey true |> ignore

    cts.Cancel()

    0 // return an integer exit code

谷歌搜索到目前为止没有找到任何我可以使用的东西。我还尝试了 Suave 的 Files 模块中的许多其他函数，包括 Files.browseFile sampleZipPath "Sample.zip"（它也给出了一个名为 "response.html" 的文件）和 Files.file sampleZipPath（它给出了一个文件名"response"), 但到目前为止没有成功。

如何提供要发送的文件的名称？

Answer 1

文件名是用 HTTP 响应 header "Content-Disposition" 设置的，Suave 不会自动处理：

   let setFileName name =
     setHeader  "Content-Disposition" (sprintf "inline; filename=\"%s\"" name)

所以，代码将是

path "/zip" >=> setFileName "Sample.zip"
            >=> Files.sendFile sampleZipPath false

根据所需的行为，您可以将 inline; 部分替换为 attachment; 以在浏览器中显示 "Save file" 对话框

使用正确名称的 Suave 发送（zip）文件

Sending (zip) file with Suave with the correct name

f#

suave