Spock 使用 Mockito 测试 Kotlin 类

Question

我有一些用 Spock 编写的测试，其中涵盖了我的 Java 代码。现在我迁移到 Kotlin，问题是我无法模拟 final 类所以我决定使用此处描述的 Mockito 插件：https://github.com/mockito/mockito/wiki/What%27s-new-in-Mockito-2#unmockable

问题是我是否需要用 Mockitos 的 any()、anyString()、when()、then() 等替换每个“_”、“>>”？我尝试使用 Mockito 模拟 final 类，但它似乎不起作用。

如果我必须替换在这种情况下使用 Spock 测试框架的优势是什么？也许我应该删除它并只使用 Mockito？

Answer 1

我不使用 Kotlin，但我之前使用过 PowerMock 来模拟 final classes/methods 和静态方法。我想知道是否可以使用 Spock 的 GroovyMock 和全局 GroovySpy 功能并使用 Spock 1.1 针对 Java 代码对其进行测试-groovy-2.4。在第一个快速和肮脏的测试场景中，它似乎有效：

Java class 测试中：

package de.scrum_master.Whosebug;

public final class FinalClass {
  public static final String finalStaticMethod() {
    return "x";
  }

  public final String finalMethod() {
    return "x";
  }
}

斯波克测试：

package de.scrum_master.Whosebug

import spock.lang.Specification

/**
 * See 
 * See http://spockframework.org/spock/docs/1.1/all_in_one.html#GroovyMocks
 */
class FinalClassTest extends Specification {
  def "use GroovyMock for final method in final class"() {
    given:
    FinalClass finalClass = GroovyMock() {
      finalMethod() >> "mocked"
    }

    expect:
    finalClass.finalMethod() == "mocked"
  }

  def "use global GroovySpy for final static method in final class"() {
    given:
    GroovySpy(FinalClass, global: true)
    FinalClass.finalStaticMethod() >> "mocked"

    expect:
    FinalClass.finalStaticMethod() == "mocked"
  }
}

对我来说，运行测试时两种特征方法都是绿色的。也许你想用我的例子试一试，然后用你的 Kotlin classes - 不过我不保证后者。

注意： Spock manual 说：

When called from Java code, Groovy mocks will behave like regular mocks.

因此，当将 Groovy Mocks 作为依赖项注入到 Java class 正在测试中时，您可能会感到失望。

更新： 好吧，我用另一个 Java class 测试了它，使用那些花哨的 GroovyMocks 并且 - 如上所述 - 它不工作：

Java class 使用模拟的 class 作为依赖：

package de.scrum_master.Whosebug;

public class AnotherClass {
  public String doSomething(FinalClass finalClass) {
    return finalClass.finalMethod();
  }

  public String doSomethingElse() {
    return FinalClass.finalStaticMethod();
  }
}

斯波克测试：

package de.scrum_master.Whosebug

import spock.lang.Specification

/**
 * See 
 * See http://spockframework.org/spock/docs/1.1/all_in_one.html#GroovyMocks
 */
class AnotherClassTest extends Specification {
  def "indirectly use GroovyMock for final method in final class"() {
    given:
    FinalClass finalClass = GroovyMock() {
      finalMethod() >> "mocked"
    }

    expect:
    new AnotherClass().doSomething(finalClass) == "mocked"
  }

  def "indirectly use global GroovySpy for final static method in final class"() {
    given:
    GroovySpy(FinalClass, global: true)
    FinalClass.finalStaticMethod() >> "mocked"

    expect:
    new AnotherClass().doSomethingElse() == "mocked"
  }
}

不幸的是，两个测试都失败了，因为从Java class. 即你被 PowerMock 或 Mockito 困住了。但您仍然可以使用所有其他不错的 Spock 功能，例如数据表、@Unroll 等等。

更新 2：解决方案

将此添加到您的 Maven 构建中（如果您使用 Gradle，执行类似的操作）：

<dependency>
  <groupId>de.jodamob.kotlin</groupId>
  <artifactId>kotlin-runner-spock</artifactId>
  <version>0.3.1</version>
  <scope>test</scope>
</dependency>

现在您可以将项目 kotlin-testrunner 中的 SpotlinTestRunner 与

等注释结合使用

@OpenedClasses([Foo, Bar, Zot])
@OpenedPackages(["de.scrum_master.Whosebug", "my.other.package"])

当然这不适用于静态方法（您仍然需要 PowerMock），但您的问题是关于封闭式 Kotlin classes 中的非静态方法。使用这个测试运行器，你可以模拟它们，因为一个特殊的 classloader 在测试执行之前通过 Javassist 打开它们：

package de.scrum_master.Whosebug

import de.jodamob.kotlin.testrunner.OpenedClasses
import de.jodamob.kotlin.testrunner.OpenedPackages
import de.jodamob.kotlin.testrunner.SpotlinTestRunner
import org.junit.runner.RunWith
import spock.lang.Specification

/**
 * See 
 * See https://github.com/dpreussler/kotlin-testrunner
 */
@RunWith(SpotlinTestRunner)
@OpenedClasses(FinalClass)
//@OpenedPackages("de.scrum_master.Whosebug")
class AnotherClassSpotlinRunnerTest extends Specification {
  def "use SpotlinRunner to stub final method in final class"() {
    given:
    FinalClass finalClass = Stub() {
      finalMethod() >> "mocked"
    }

    expect:
    new AnotherClass().doSomething(finalClass) == "mocked"
  }
}

Spock 使用 Mockito 测试 Kotlin 类

Spock with Mockito testing Kotlin classes

java

testing

unit-testing

mockito

spock