使用 Haskell 管道的非平凡协议

Question

我正在尝试弄清楚如何使用 Haskell 管道实现 non-trivial 协议（通过 TCP）。我认为的例子 non-trivial:

读取一些 header 字节，如果它们符合预期，则忽略它们并继续；否则，return 给客户端一个错误。
读取指示字段长度的 N 个字节，然后将该字节数读入字节串。
在客户端和服务器之间执行 back-and-forth 握手，如能力协商。协商后，根据协商的内容调用不同的 server-side 代码。（例如协商服务器和客户端同意的协议版本）
如果客户端未能足够快地协商协议，则连接超时，并向客户端发送错误

到目前为止，我一直在努力...非常感谢任何帮助或指向某些示例代码的指针！

Answer 1

这个问题有点含糊，但如果您正在寻找一个基于先前解析的结果在管道中控制操作的示例，则 netstring 协议的实现可能就足够了：

#!/usr/bin/env stack
-- stack --resolver lts-10.3 script
{-# LANGUAGE ScopedTypeVariables #-}
{-# LANGUAGE OverloadedStrings #-}
import Conduit
import Data.ByteString (ByteString)
import Data.Word8 (_colon, _comma, _0, _9, Word8)
import Control.Exception.Safe (throwString)

netstring :: forall m. MonadThrow m => ConduitM ByteString ByteString m ()
netstring = do
  len <- takeWhileCE (/= _colon) .| foldMCE addDigit 0
  mchar1 <- headCE
  case mchar1 of
    Just c
      | c == _colon -> return ()
      | otherwise -> throwString $ "Didn't find a colon: " ++ show c
    Nothing -> throwString "Missing colon"
  takeCE len
  mchar2 <- headCE
  case mchar2 of
    Just c
      | c == _comma -> return ()
      | otherwise -> throwString $ "Didn't end with a comma: " ++ show c
    Nothing -> throwString "Missing trailing comma"
  where
    addDigit :: Int -> Word8 -> m Int
    addDigit total char
      | char < _0 || char > _9 = throwString "Invalid character in len"
    addDigit total char = return $! total * 10 + fromIntegral (char - _0)

main :: IO ()
main = do
  let bs = "5:hello,6: world,"
  res <- runConduit
       $ yield bs
      .| ((,) <$> (netstring .| foldC) <*> (netstring .| foldC))
  print res

使用 Haskell 管道的非平凡协议

Non trivial protocol using Haskell conduit

haskell

conduit

network-conduit