如何使用 VBA 忽略范围内的绿色三角形错误而不逐个单元格循环？

Question

我有一些正在自动化和分发的大型数据集。我想消除警告用户有关存储为文本的数字的绿色小三角形。我使用了以下代码，但在大量工作表上速度非常慢。

     Range(Cells(1, 1), Cells(lastrow, lColumn)).Select
     'kill those dang green cell triagles
     Dim rngCell As Range, bError As Byte
         For Each rngCell In Selection.Cells

             For bError = 3 To 3 Step 1

                 With rngCell
                     If .Errors(bError).Value Then
                         .Errors(bError).Ignore = True
                     End If
                 End With
             Next bError
         Next rngCell

正如您所看到的，我已经将它减少到 1/7 的时间，因为我没有循环遍历我试图阻止的每个错误，但它仍然非常慢。

我也已经知道

     Application.ErrorCheckingOptions.NumberAsText = False

但我不想使用它，因为我不想更改用户的系统设置。我想要循环的效果而不循环遍历所有单元格。我可以告诉 Excel 停止检查整个范围而不是逐个单元格循环吗？

任何有效且快速的方法都将非常有帮助。提前致谢！！

Answer 1

首选的解决方案是将字符串转换为数字，然后 将其转换为Excel。例如，当我使用 SQL 并且我在数据库中将一些数值存储为 NVARCHAR 时，我将在 SQL 语句中使用 CONVERT(int, colName)将其带入 Excel。这将它作为数字输入，我不再收到该消息。

现在，如果您无法使用此类选项，您可以通过其他方式修复该错误。只需设置值的范围，将存储为文本错误的数字等于自身。

例如：

Sub Test()

    Sheets("Sheet1").Range("A1:A3").Value = Sheets("Sheet1").Range("A1:A3").Value

End Sub

在此示例中，A1:A3 是您不想再存储为文本的值范围。

由于您的数字有前导零，您可以更改这些单元格的格式以添加这些零：

Sub Test()

    Sheets("Sheet1").Range("A1:A3").Value = Sheets("Sheet1").Range("A1:A3").Value
    'This assumes your numbers are 11 digits long
    'Thus 11132 would display as 00000011132
    Sheets("Sheet1").Range("A1:A3").NumberFormat = "00000000000"

End Sub

这会将显示更改为再次显示前导零。如果您以任何方式导出此数据，您可能必须采取措施确保将此特定列导出为文本而不是数字，但如果没有具体细节，我帮不上什么忙。

Answer 2

当范围大于单个单元格时，显而易见的答案 (Range(...).Errors(3).Ignore = True) 似乎不起作用。

经过一些实验，我发现您可以手动 select 单元格范围并单击出现的小弹出菜单并告诉它忽略该范围内的所有错误，但这并不能' 似乎有一个 VBA 等价物。

用宏记录器做这个实验什么也没记录，这通常表明实现此功能的 Microsoft 程序员不称职。

遗憾的是，我认为这意味着除了循环之外没有其他解决方案。

Related

Answer 3

您可以使用工作簿事件打开和关闭用户的系统设置，并在完成后将设置恢复为原始值。

在 ThisWorkbook 对象中，放置一个记录其初始设置的打开事件，然后将其关闭。

Dim MyErrorCheckValue as Boolean

Private Sub Workbook_Open()
    MyErrorCheckValue = Application.ErrorCheckingOptions.NumberAsText
    Application.ErrorCheckingOptions.NumberAsText = False
End Sub

添加 BeforeClose 事件以在关闭文件时将其设置回原始值。

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Application.ErrorCheckingOptions.NumberAsText = MyErrorCheckValue
End Sub

然后添加激活和停用事件，以便在用户打开或查看不同的传播时切换sheet。

Private Sub Workbook_Activate()
    Application.ErrorCheckingOptions.NumberAsText = False
End Sub

Private Sub Workbook_Deactivate()
    Application.ErrorCheckingOptions.NumberAsText = MyErrorCheckValue
End Sub

您可以在 sheet 级别添加类似的事件，以便在工作簿中切换 sheet 时将其打开和关闭。

添加一些错误处理以将其设置回原始值也是明智的，这样您就不会意外地将其留在错误的状态，以防万一您的代码在某处出现错误。

Answer 4

我创建了一个漂亮的程序来将错误放入 'ignore' 列表中：玩得开心

Sub SetInconsistentFormulaErrorsFalse(rng As Range, _
Optional arrErrortypes As Variant = Null, _
Optional bIgnoreErrors As Boolean = True)

Dim cl As Range
Dim i As Integer

If IsNull(arrErrortypes) Then
   arrErrortypes = Array(1, 2, 3, 4, 5, 6, 7, 8, 9)
End If

For i = 0 To UBound(arrErrortypes) - 1
    For Each cl In rng.Cells
        cl.Errors(arrErrortypes(i)).Ignore = bIgnoreErrors
    Next
Next i


Set cl = Nothing

End Sub

Answer 5

楼主分享的代码好像有错误。为了让它工作，我添加了错误的 .Item：

Dim rngCell As Range, bError As Byte
For Each rngCell In Selection.Cells

    For bError = 1 To 4

        With rngCell
            If .Errors.Item(bError).value Then
                .Errors.Item(bError).Ignore = True
            End If
        End With
    Next bError
Next rngCell

如何使用 VBA 忽略范围内的绿色三角形错误而不逐个单元格循环？

How can I use VBA to ignore green triangle error in range without looping cell by cell?

excel

vba

error-checking