使用 xslt 的组相邻节点

Question

关于group-adjacent函数的问题已经有人问了，我知道。但出于某种原因，我无法让它工作。

我在工作中继承了一个使用 xslt 的项目，而我的老板不理解学习 xslt 的学习曲线有多陡峭以及它与过程编程有多么不同。

尽管如此，我还是下定决心要尽可能地学习它，但我仍然必须在学习的同时使用它。如果您能帮助解决以下问题，我们将不胜感激。

我有一个 xml 格式如下的文档：

<document xml:lang="EN">
  <CRPg>text</CRPg>
  <CRPg>text</CRPg>
  <CRPg>text</CRPg>
  <Section/> <!--section marker-->
  <TOCChap>chapter title</TOCChap>
  <TOCAu>chapter author</TOCAu>
  <TOCChap>chapter title</TOCChap>
  <TOCAu>chapter author</TOCAu>
  <TOCChap>chapter title</TOCChap>
  <TOCAu>chapter author</TOCAu>
  <TOCChap>chapter title</TOCChap>
  <TOCAu>chapter author</TOCAu>
  <Section/> <!--section marker-->
  <Txt>body text</Txt>
  <Txt>body text</Txt>
  <Txt>body text</Txt>
  <Txt>body text</Txt>
</document>

它目前基本上没有层次结构，包含标记以赋予它结构并包含在整个文件中。我正在尝试对所有 TOC 元素进行分组并将它们嵌套在一个包含元素中：

<document xml:lang="EN">
  <CRPg>text</CRPg>
  <CRPg>text</CRPg>
  <CRPg>text</CRPg>
  <Section/> <!--section marker-->
  <Wrapper> <!-- create new element to wrap around TOC and TOCAuth -->
   <TOCChap>chapter title</TOCChap>
   <TOCAu>chapter author</TOCAu>
   <TOCChap>chapter title</TOCChap>
   <TOCAu>chapter author</TOCAu>
   <TOCChap>chapter title</TOCChap>
   <TOCAu>chapter author</TOCAu>
   <TOCChap>chapter title</TOCChap>
   <TOCAu>chapter author</TOCAu>
  </Wrapper>
  <Section/> <!--section marker-->
  <Txt>body text</Txt>
  <Txt>body text</Txt>
  <Txt>body text</Txt>
  <Txt>body text</Txt>
</document>

事实证明这比我预期的要困难。我尝试了以下代码的许多不同版本，并粘贴了看起来最不错误的那个。我意识到它仍然很糟糕：

<xsl:template match="*">
<xsl:for-each-group select="TOCChap | TOCAuth" group-adjacent="self::TOCChap | self::TOCAuth">
  <xsl:choose>
    <xsl:when test="current-grouping-key()">
      <wrapper>
        <xsl:apply-templates select="current-group()"/>

      </wrapper>
    </xsl:when>
    <xsl:otherwise>
      <xsl:apply-templates select="current-group()"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:for-each-group>

提前谢谢你。

Answer 1

您需要这样的 XSLT（如果没有层次结构）：

<xsl:stylesheet version="2.0"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="node() | @*">
        <xsl:copy>
            <xsl:apply-templates select="@* , node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="/*">
        <xsl:copy>
            <xsl:attribute name="xml:lang">EN</xsl:attribute>
            <xsl:for-each-group select="*" group-adjacent="name() = ('TOCChap','TOCAu')">
                <xsl:choose>
                    <xsl:when test="current-grouping-key()">
                        <Wrapper>
                            <xsl:apply-templates select="current-group()"/>
                        </Wrapper>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:apply-templates select="current-group()"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each-group>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

Answer 2

您的尝试无效的三个原因：

您选择了错误的节点集；
您正在使用联合运算符 | 而不是逻辑运算符 or;
您的文档中没有名为 TOCAuth 的元素。

通过将指令更改为解决这三个问题后：

<xsl:for-each-group select="*" group-adjacent="self::TOCChap or self::TOCAu">

您将看到您正在寻找的结果 - 请在此处查看完整的演示：http://xsltransform.net/jyH9rME

--
顺便说一句，您的情况几乎与 XSLT 2.0 规范中给出的使用 group-adjacent 的示例完全相同 - 请参阅此处的最后一个示例：http://www.w3.org/TR/xslt20/#grouping-examples

P.S.

我不禁想知道你为什么不利用 <Section/> 标记将所有你的组放在包装器中 - 例如，应用：

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="/document">
    <xsl:copy>
        <xsl:apply-templates select="@*" />
        <xsl:for-each-group select="*" group-starting-with="Section">
            <wrapper>
                <xsl:apply-templates select="current-group()" />
            </wrapper>  
        </xsl:for-each-group>
    </xsl:copy>
</xsl:template>

<xsl:template match="Section"/>

</xsl:stylesheet>

您的输入将导致：

:<?xml version="1.0" encoding="utf-8"?>
<document xml:lang="EN">
   <wrapper>
      <CRPg>text</CRPg>
      <CRPg>text</CRPg>
      <CRPg>text</CRPg>
   </wrapper>
   <wrapper>
      <TOCChap>chapter title</TOCChap>
      <TOCAu>chapter author</TOCAu>
      <TOCChap>chapter title</TOCChap>
      <TOCAu>chapter author</TOCAu>
      <TOCChap>chapter title</TOCChap>
      <TOCAu>chapter author</TOCAu>
      <TOCChap>chapter title</TOCChap>
      <TOCAu>chapter author</TOCAu>
   </wrapper>
   <wrapper>
      <Txt>body text</Txt>
      <Txt>body text</Txt>
      <Txt>body text</Txt>
      <Txt>body text</Txt>
   </wrapper>
</document>

Answer 3

<xsl:template match="document">
    <xsl:copy>
        <xsl:apply-templates select="@*"/>
        <xsl:for-each-group select="*" group-adjacent="boolean(self::TOCChap | self::TOCAu)">
            <xsl:choose>
                <xsl:when test="current-grouping-key()">
                    <wrapper>
                        <xsl:apply-templates select="current-group()"/>
                    </wrapper>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:apply-templates select="current-group()"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each-group>
    </xsl:copy>

</xsl:template>
<xsl:template match="node() | @*">
    <xsl:copy>
        <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
</xsl:template>

使用 xslt 的组相邻节点

Group-adjacent nodes using xslt

xml

xslt

xslt-2.0

xsl-grouping