SPARQL：查询多种语言的维基数据标签

Question

我正在尝试从维基数据的 SPARQL 端点获取多种语言的标签。下面给出例子here:

SELECT ?country ?country_EN ?country_DE ?country_FR
   WHERE {
     ?country wdt:P31 wd:Q185441. # member state of the European Union
     SERVICE wikibase:label { bd:serviceParam wikibase:language "en".
            ?country rdfs:label ?country_EN.
     }
     SERVICE wikibase:label { bd:serviceParam wikibase:language "de".
            ?country rdfs:label ?country_DE.
     }
     SERVICE wikibase:label { bd:serviceParam wikibase:language "fr".
            ?country rdfs:label ?country_FR.
     }
}

Try it here

但是，这个returns出现如下错误：

Unknown error: there can be only one "run last" join in any group

是否有解决方案可以使用多种语言获取标签？

Answer 1

rdfs:label可以不用wikibase:label服务直接使用：

SELECT ?country ?country_en ?country_de ?country_fr
   WHERE {
     ?country wdt:P31 wd:Q185441. # member state of the European Union
     OPTIONAL {?country rdfs:label ?country_en filter (lang(?country_en) = "en")}.
     OPTIONAL {?country rdfs:label ?country_de filter (lang(?country_de) = "de")}.
     OPTIONAL {?country rdfs:label ?country_fr filter (lang(?country_fr) = "fr")}.
}

Try it here

Answer 2

标签服务优化器adds a hint:Prior hint:runLast true hint标签服务，除非有另一个明确的提示：

LabelServiceUtils.getLabelServiceNodes(op).forEach(service -> {
    if (service.getProperty(QueryHints.RUN_LAST)  != null ||
        service.getProperty(QueryHints.RUN_FIRST) != null) {
        return;
    }
    service.setProperty(QueryHints.RUN_LAST, TRUE);
});

应该在第一个标签服务调用之后添加 hint:Prior hint:runLast false。

您的查询应该是：

SELECT ?country ?country_EN ?country_DE ?country_FR
   WHERE {
     ?country wdt:P463 wd:Q458. # member state of the European Union
     SERVICE wikibase:label { bd:serviceParam wikibase:language "en".
            ?country rdfs:label ?country_EN.
     }
     SERVICE wikibase:label { bd:serviceParam wikibase:language "de".
            ?country rdfs:label ?country_DE.
     } hint:Prior hint:runLast false.
     SERVICE wikibase:label { bd:serviceParam wikibase:language "fr".
            ?country rdfs:label ?country_FR.
     } hint:Prior hint:runLast false.
}

Try it!

显然，使用常规 SPARQL 可以获取多种语言的标签，而且这样不那么冗长。然而，标签服务提供了语言回退，包括 Q-id 的最后一个。

来源：

https://phabricator.wikimedia.org/T175840

SPARQL：查询多种语言的维基数据标签

SPARQL: Querying Wikidata labels for more than one language

sparql

wikidata

blazegraph