如何确保我的 IE 选项卡名称正确？

Question

我正在使用此代码从单词 VBA 中获取 Internet Explorer 的实例，并从网页中抓取一些值。我正在循环浏览 4 个项目（以防万一，有时我不小心抓住了一个叫做 "Windows Explorer" 的东西，我不知道那是什么）来抓住 Internet Explorer。但在我开始抓取值之前，我想确保我的选项卡名称是 "Overview - City"。我如何根据选项卡名称进行测试？

Dim shellWins As ShellWindows, IE As InternetExplorer
Dim i As Long

Set shellWins = New ShellWindows

'Find Internet Explorer - if it can't find it, close the program
If shellWins.Count > 0 Then
    For i = 0 To 3
        On Error Resume Next
            If shellWins.Item(i).Name = "Internet Explorer" Then
                Set IE = shellWins.Item(i)
                Exit For
            End If
        On Error GoTo 0

        If i = 3 Then
            MsgBox "Could not find Internet Explorer.", vbExclamation, "Error"
            Exit Sub
        End If
    Next i
Else
    MsgBox "Could not find Internet Explorer.", vbExclamation, "Error"
    Exit Sub
End If

我尝试按照指南 here 进行操作，并使用此位尝试 Debug.Print IE 中的所有活动选项卡名称，一旦我找到它：

Dim IE_Tab As SHDocVw.InternetExplorer
Dim SH_Win As SHDocVw.ShellWindows

For each IE_Tab in SH_Win
    Debug.Print IE_Tab.Name 'This returns nothing?
Next IE_Tab

但是直接windowreturns空白没有错误。我做错了什么？

Answer 1

该选项卡只是另一个 window。您可以使用下面的 GetWebPage 函数循环遍历 windows 并获取您要查找的 URL。

参考文献是微软互联网控制微软 Shell 控制与自动化

Sub Example()
Dim ieWin As InternetExplorer

Set ieWin = CreateObject("InternetExplorer.Application")

    With ieWin
        .Navigate "https://www.google.com/"
        .Visible = True
        .Silent = True
    End With

    Set ieWin = GetWebPage("https://www.google.com/")

End Sub

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'Desc: The Function gets the Internet Explorer window that has the current
'   URL from the sURL Parameter.  The Function Timesout after 30 seconds
'Input parameters:
    'String sURL - The URL to look for
'Output parameters:
    'InternetExplorer ie - the Internet Explorer window holding the webpage
'Result: returns the the Internet Explorer window holding the webpage
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Public Function GetWebPage(sUrl As String) As InternetExplorer
Dim winShell As Shell
Dim dt As Date
dt = DateAdd("s", 300, DateTime.Now)

Dim ie As InternetExplorer

Do While dt > DateTime.Now
    Set winShell = New Shell
    'loop through the windows and check the internet explorer windows
    For Each ie In winShell.Windows
        If ie.LocationURL = sUrl Then
            Set GetWebPage = ie
            Do While ie.Busy
                DoEvents
            Loop
            Exit Do

        Set winShell = Nothing
        End If
    Next ie
    Set winShell = Nothing
    DoEvents
Loop
End Function

Answer 2

下面是一些代码，应该可以找到对打开的 Internet Explorer 选项卡的引用。它通过遍历 Shell.Application.Windows 集合来实现。该函数支持仅查找 WindowName、URL 和 WindowName，并支持指定比较方法或是否要进行类似匹配。我保留了这段代码的后期绑定，以避免需要引用。

代码有注释，有问题可以私信我

代码

Option Explicit

Private Function GetIEWindow(WindowName As String, _
                             ExactMatch As Boolean, _
                             Optional CompareMethod As VbCompareMethod = vbTextCompare, _
                             Optional URL As String) As Object

    Dim Window  As Object
    Dim Windows As Object: Set Windows = CreateObject("Shell.Application").Windows

    For Each Window In Windows
        'Make sure the app is Internet Explorer. Shell Windows can include other apps
        If InStr(1, Window.FullName, "IEXPLORE.EXE", vbTextCompare) > 0 Then
            'Perform exact matches, where the title or url and title match exactly
            If ExactMatch Then
                If Len(URL) = 0 Then
                    If Window.LocationName = WindowName Then
                        Set GetIEWindow = Window
                        Exit Function
                    End If
                Else
                    If Window.LocationName = WindowName And Window.LocationUrl = URL Then
                        Set GetIEWindow = Window
                        Exit Function
                    End If
                End If
            Else
            'Otherwise do a In String match
                If Len(URL) = 0 Then
                    If InStr(1, Window.LocationName, WindowName, CompareMethod) > 0 Then
                        Set GetIEWindow = Window
                        Exit Function
                    End If
                Else
                    If InStr(1, Window.LocationName, WindowName, CompareMethod) > 0 And InStr(1, Window.LocationUrl, URL, CompareMethod) > 0 Then
                        Set GetIEWindow = Window
                        Exit Function
                    End If
                End If
            End If
        End If

    Next

End Function

Sub ExampleUsage()
    Dim IE As Object: Set IE = GetIEWindow("exe", True)

    If Not IE Is Nothing Then
        Debug.Print "I found the IE window"
    Else
        Debug.Print "I didn't find the IE window"
    End If

End Sub

如何确保我的 IE 选项卡名称正确？

How can I make sure my IE tab name is correct?

vba

screen-scraping

ms-word