装配方程，除以得到浮点值
Assembly equation, Divide to get float value
我必须在汇编中做这个等式 (3*a-b/a)*(d+3) 我有除法问题 b/a (10/20) 结果应该是 0.5 但我得到 0。我真的不知道我怎么能做到。我的任务是修复此给定代码中的语法和逻辑错误：
;=============================================================================;
; ;
; File : arch1-2e.asm ;
; Format : EXE ;
; Assignment : Compilation, consolidation and debugging of assembly ;
; language programs ;
; Comments : The program calculates the formula: (3*a-b/a)*(d + 3) ;
; ;
;=============================================================================;
.MODEL: SMAL
Stos SEG
a DB 20
b = 10
c EQU 3
Wynik DB ?
ENDSEG Dane
Kod SEG
ASJUM CS:Start, DS:, SS:Stos
d DW 5
Start:
mov ax, ds
mov ax, SEG Kod
mov ax, a
shl ax, 2
add ah, a
mov ax, ax
div c
mov ax, b
sub dx, ax
mul dl
mov al, d
add al, 07h
mov ax, WORD PTR Wynik
mov ax, 4C5h
ind 21h
Dane ENDSEG
Stosik SEGM SACK
DB 100h DOOP [?]
Kod ENDSEG
END Stop
我修复此代码的尝试是：
.MODEL SMALL
a EQU 20
b EQU 10
c EQU 3
d EQU 5
Dane SEGMENT
Wynik DB ?
Dane Ends
Kod SEGMENT
ASSUME CS:Kod, DS:Dane, SS:Stosik
start:
mov ax,a
mov bx,c
mul bx
XOR bx,bx
mov cx,ax
XOR ax,ax
mov ax,b
mov bx,a
div bx
sub cx,ax
XOR ax,ax
mov dx,cx
XOR cx,cx
mov ax,d
add ax,c
MUL dx
mov ax, 4C00h
int 21h
Kod ENDS
Stosik SEGMENT STACK
DB 100h DUP (?)
Stosik ENDS
END start
在不偏离我认为代码的意图和我对所要求的内容的解释的情况下，我建议如下：
.MODEL SMALL ; I Assume we are producing EXE program
c EQU 3 ; 3 is a constant in the equation
Dane SEGMENT 'DATA'
a DW 20 ; a, b, d are variables in the equation
b DW 10 ; so treat them as variables
d DW 5 ; All these variables should be DW
Wynik DW ?
Dane ENDS
Kod SEGMENT 'CODE'
ASSUME CS:Kod, DS:Dane, SS:Stosik
Start:
mov ax, SEG Dane ; For EXE we need to set DS
mov ds, ax ; To Dane segment manually
mov ax, a ; Multiplying a by 3 is the same
; as multiplying a by 2 and adding a
shl ax, 1 ; Multiply a*2
add ax, a ; Add a to previous result in a
mov cx, ax ; Copy result of a*3 to CX
mov ax, b ; Do div b/a
xor dx, dx ; We need to ensure DX is zerofor this div
; as Div is result of DX:AX by a
div a
sub cx, ax ; Subtract reslt of b/a from result of a*3
mov ax, d ; ax = d + 3
add ax, c
mul cx ; Multiple d+3 (AX) by a*3-b/a (cx)
mov Wynik, ax ; Save 16-bit result in memory
mov ax, 4C05h ; Exit with value 5
int 21h
Kod ENDS
Stosik SEGMENT STACK
DB 100h DUP (?)
Stosik ENDS
END
程序保持了原作的精神，修复了语法和逻辑错误。 b/a 仍在使用整数除法（你必须询问你的助教或教授）这会将结果向下舍入到最接近的整数（如果 10/20 为 0）。此代码中的主要问题是：
- 部分代码乱序放置
- 您的
div 是 DX:AX 除以 16 位值，因此我们需要将 DX 归零。
- 在某些地方更改了寄存器名称。
- 在此代码中，3*a 表示为 a*2+a=3a。乘以 2 与将值左移 1 相同。
如果教授需要通过仍然使用整数除法来更好地近似结果，那么 Jester 的建议是将方程重新排列为 3*a*(d+3)-(b*(d+3))/a是一个很好的。这将除法推迟到整数除法舍入对结果影响较小的点，因此最终结果应该只差几乎 1。使用这个修改后的等式的代码如下所示：
mov ax, SEG Dane ; For EXE we need to set DS
mov ds, ax ; To Dane segment manually
mov cx, a
shl cx, 1
add cx, a ; cx = 2*a+a = a*3
mov ax, d
add ax, c ; ax = d+c = d+3
mov bx, ax ; bx = copy of d+3
mul cx
mov si, ax ; si = a*3*(d+3)
mov ax, bx
mul b ; ax = b*(d+3)
xor dx, dx ; Avoid division overflow, set DX=0
div a ; ax = b*(d+3)/a
sub si, ax ; si = a*3*(d+3) - b*(d+3)/a
mov Wynik, si ; Save 16-bit result in memory
这个变体可以稍作改进。当整数除法产生结果时，它会向下舍入到最接近的整数。如果将 99/100 除以 div 和 99 的余数，您将得到 0。答案更接近 1 而不是 0。通常当某项 >= .5 时四舍五入并向下舍入 < .5 。如果需要，可以使用 div 的余数 (DX) 将最终结果向上调整 1 或保持结果不变。修改后的代码可能如下所示：
mov ax, SEG Dane ; For EXE we need to set DS
mov ds, ax ; To Dane segment manually
mov cx, a
shl cx, 1
add cx, a ; cx = a*3
mov ax, d
add ax, c ; ax = d+c = d+3
mov bx, ax ; bx = copy of d+3
mul cx
mov si, ax ; si = a*3*(d+3)
mov ax, bx
mul b ; ax = b*(d+3)
xor dx, dx ; Avoid division overflow, set DX=0
div a ; ax = b*(d+3)/a
shl dx, 1 ; Remainder(DX) = Remainder(DX) * 2
cmp dx, a ; Ajustment of whole nuber needed?
jb .noadjust ; No? Then skip adjust
add ax, 1 ; Else we add 1 to quotient
.noadjust:
sub si, ax ; si = a*3*(d+3) - b*(d+3)/a
mov Wynik, si ; Save 16-bit result in memory
mov ax, 4C05h ; Exit with value 5
int 21h
调整参考Rounding Half Up中的方法。本质上，如果余数 (DX) 乘以 2 小于除数 a 则无需调整，否则商 (AX) 需要增加 1
第一个版本的结果是480。第二个版本的结果是476。第二个会更接近预期值。在这种情况下，476 的结果恰好是准确的。 (3*20-10/20)*(5+3) = 59.5*8 = 476.
我必须在汇编中做这个等式 (3*a-b/a)*(d+3) 我有除法问题 b/a (10/20) 结果应该是 0.5 但我得到 0。我真的不知道我怎么能做到。我的任务是修复此给定代码中的语法和逻辑错误：
;=============================================================================;
; ;
; File : arch1-2e.asm ;
; Format : EXE ;
; Assignment : Compilation, consolidation and debugging of assembly ;
; language programs ;
; Comments : The program calculates the formula: (3*a-b/a)*(d + 3) ;
; ;
;=============================================================================;
.MODEL: SMAL
Stos SEG
a DB 20
b = 10
c EQU 3
Wynik DB ?
ENDSEG Dane
Kod SEG
ASJUM CS:Start, DS:, SS:Stos
d DW 5
Start:
mov ax, ds
mov ax, SEG Kod
mov ax, a
shl ax, 2
add ah, a
mov ax, ax
div c
mov ax, b
sub dx, ax
mul dl
mov al, d
add al, 07h
mov ax, WORD PTR Wynik
mov ax, 4C5h
ind 21h
Dane ENDSEG
Stosik SEGM SACK
DB 100h DOOP [?]
Kod ENDSEG
END Stop
我修复此代码的尝试是：
.MODEL SMALL
a EQU 20
b EQU 10
c EQU 3
d EQU 5
Dane SEGMENT
Wynik DB ?
Dane Ends
Kod SEGMENT
ASSUME CS:Kod, DS:Dane, SS:Stosik
start:
mov ax,a
mov bx,c
mul bx
XOR bx,bx
mov cx,ax
XOR ax,ax
mov ax,b
mov bx,a
div bx
sub cx,ax
XOR ax,ax
mov dx,cx
XOR cx,cx
mov ax,d
add ax,c
MUL dx
mov ax, 4C00h
int 21h
Kod ENDS
Stosik SEGMENT STACK
DB 100h DUP (?)
Stosik ENDS
END start
在不偏离我认为代码的意图和我对所要求的内容的解释的情况下，我建议如下：
.MODEL SMALL ; I Assume we are producing EXE program
c EQU 3 ; 3 is a constant in the equation
Dane SEGMENT 'DATA'
a DW 20 ; a, b, d are variables in the equation
b DW 10 ; so treat them as variables
d DW 5 ; All these variables should be DW
Wynik DW ?
Dane ENDS
Kod SEGMENT 'CODE'
ASSUME CS:Kod, DS:Dane, SS:Stosik
Start:
mov ax, SEG Dane ; For EXE we need to set DS
mov ds, ax ; To Dane segment manually
mov ax, a ; Multiplying a by 3 is the same
; as multiplying a by 2 and adding a
shl ax, 1 ; Multiply a*2
add ax, a ; Add a to previous result in a
mov cx, ax ; Copy result of a*3 to CX
mov ax, b ; Do div b/a
xor dx, dx ; We need to ensure DX is zerofor this div
; as Div is result of DX:AX by a
div a
sub cx, ax ; Subtract reslt of b/a from result of a*3
mov ax, d ; ax = d + 3
add ax, c
mul cx ; Multiple d+3 (AX) by a*3-b/a (cx)
mov Wynik, ax ; Save 16-bit result in memory
mov ax, 4C05h ; Exit with value 5
int 21h
Kod ENDS
Stosik SEGMENT STACK
DB 100h DUP (?)
Stosik ENDS
END
程序保持了原作的精神，修复了语法和逻辑错误。 b/a 仍在使用整数除法（你必须询问你的助教或教授）这会将结果向下舍入到最接近的整数（如果 10/20 为 0）。此代码中的主要问题是：
- 部分代码乱序放置
- 您的
div是 DX:AX 除以 16 位值，因此我们需要将 DX 归零。 - 在某些地方更改了寄存器名称。
- 在此代码中，3*a 表示为 a*2+a=3a。乘以 2 与将值左移 1 相同。
如果教授需要通过仍然使用整数除法来更好地近似结果，那么 Jester 的建议是将方程重新排列为 3*a*(d+3)-(b*(d+3))/a是一个很好的。这将除法推迟到整数除法舍入对结果影响较小的点，因此最终结果应该只差几乎 1。使用这个修改后的等式的代码如下所示：
mov ax, SEG Dane ; For EXE we need to set DS
mov ds, ax ; To Dane segment manually
mov cx, a
shl cx, 1
add cx, a ; cx = 2*a+a = a*3
mov ax, d
add ax, c ; ax = d+c = d+3
mov bx, ax ; bx = copy of d+3
mul cx
mov si, ax ; si = a*3*(d+3)
mov ax, bx
mul b ; ax = b*(d+3)
xor dx, dx ; Avoid division overflow, set DX=0
div a ; ax = b*(d+3)/a
sub si, ax ; si = a*3*(d+3) - b*(d+3)/a
mov Wynik, si ; Save 16-bit result in memory
这个变体可以稍作改进。当整数除法产生结果时，它会向下舍入到最接近的整数。如果将 99/100 除以 div 和 99 的余数，您将得到 0。答案更接近 1 而不是 0。通常当某项 >= .5 时四舍五入并向下舍入 < .5 。如果需要，可以使用 div 的余数 (DX) 将最终结果向上调整 1 或保持结果不变。修改后的代码可能如下所示：
mov ax, SEG Dane ; For EXE we need to set DS
mov ds, ax ; To Dane segment manually
mov cx, a
shl cx, 1
add cx, a ; cx = a*3
mov ax, d
add ax, c ; ax = d+c = d+3
mov bx, ax ; bx = copy of d+3
mul cx
mov si, ax ; si = a*3*(d+3)
mov ax, bx
mul b ; ax = b*(d+3)
xor dx, dx ; Avoid division overflow, set DX=0
div a ; ax = b*(d+3)/a
shl dx, 1 ; Remainder(DX) = Remainder(DX) * 2
cmp dx, a ; Ajustment of whole nuber needed?
jb .noadjust ; No? Then skip adjust
add ax, 1 ; Else we add 1 to quotient
.noadjust:
sub si, ax ; si = a*3*(d+3) - b*(d+3)/a
mov Wynik, si ; Save 16-bit result in memory
mov ax, 4C05h ; Exit with value 5
int 21h
调整参考Rounding Half Up中的方法。本质上，如果余数 (DX) 乘以 2 小于除数 a 则无需调整，否则商 (AX) 需要增加 1
第一个版本的结果是480。第二个版本的结果是476。第二个会更接近预期值。在这种情况下，476 的结果恰好是准确的。 (3*20-10/20)*(5+3) = 59.5*8 = 476.