无法理解 APEX_MAIL 的作业如何运行

Question

我目前正在尝试实现与 oracle 的 APEX_MAIL 包类似的版本。我一切正常，但除非我修改它，否则我无法使工作正常进行。

APEX_MAIL 使用的作业称为 ORACLE_APEX_MAIL_QUEUE

BEGIN
DBMS_SCHEDULER.set_attribute( name => '"APEX_040000"."ORACLE_APEX_MAIL_QUEUE"', attribute => 'job_action', value => 'APEX_040000.WWV_FLOW_MAIL.PUSH_QUEUE');

DBMS_SCHEDULER.set_attribute( name => '"APEX_040000"."ORACLE_APEX_MAIL_QUEUE"', attribute => 'number_of_arguments', value => '2');
DBMS_SCHEDULER.SET_JOB_ARGUMENT_VALUE( 
         job_name => '"APEX_040000"."ORACLE_APEX_MAIL_QUEUE"', 
         argument_position => 1, 
         argument_value => '');
DBMS_SCHEDULER.SET_JOB_ARGUMENT_VALUE( 
         job_name => '"APEX_040000"."ORACLE_APEX_MAIL_QUEUE"', 
         argument_position => 2, 
         argument_value => '');

END; 
/

所以我去包里看看代码是干什么的。我假设推送队列会在队列中发送电子邮件。相反，它再次调用相同的作业！

PROCEDURE PUSH_QUEUE( P_SMTP_HOSTNAME IN VARCHAR2 DEFAULT NULL,
                      P_SMTP_PORTNO   IN VARCHAR2 DEFAULT NULL )
IS
BEGIN
    PUSH_QUEUE_BACKGROUND;
END PUSH_QUEUE;


PROCEDURE PUSH_QUEUE_BACKGROUND
IS
BEGIN
    SYS.DBMS_SCHEDULER.RUN_JOB( JOB_NAME => 'ORACLE_APEX_MAIL_QUEUE', USE_CURRENT_SESSION => FALSE );
EXCEPTION
    WHEN OTHERS THEN
        IF SQLCODE <> -27478 THEN
            RAISE;
        END IF;
END PUSH_QUEUE_BACKGROUND;

所以基本上这项工作什么都不做，但我将其切换为调用 PUSH_QUEUE_IMMEDIATE，它做了我认为应该做的事情。

PROCEDURE PUSH_QUEUE_IMMEDIATE( P_FORCE_YN IN VARCHAR2 DEFAULT 'N')
IS
    L_STATUS            NUMBER;
    L_LOCK_HDL          VARCHAR2(128);
    E_DB_SHUTDOWN       EXCEPTION;
    PRAGMA EXCEPTION_INIT(E_DB_SHUTDOWN, -1089);
BEGIN



    WWV_FLOW_DEBUG.ENABLE_DBMS_OUTPUT;



    SYS.DBMS_LOCK.ALLOCATE_UNIQUE( LOCKNAME => 'APEX_MAIL_QUEUE_LOCK', LOCKHANDLE => L_LOCK_HDL);
    L_STATUS := SYS.DBMS_LOCK.REQUEST( LOCKHANDLE        => L_LOCK_HDL,
                                   LOCKMODE          => SYS.DBMS_LOCK.X_MODE,
                                   TIMEOUT           => 0,
                                   RELEASE_ON_COMMIT => FALSE );
    WWV_FLOW_DEBUG.INFO('APEX Mail Lock status: ' || L_STATUS );




    IF L_STATUS = 0 THEN

        FOR C1 IN ( SELECT   ID, MAIL_SEND_COUNT, LAST_UPDATED_ON
                      FROM WWV_FLOW_MAIL_QUEUE
                     ORDER BY MAIL_SEND_COUNT, LAST_UPDATED_ON) LOOP
            BEGIN
                WWV_FLOW_DEBUG.INFO( 'Pushing email: ' || C1.ID );







                IF  (C1.MAIL_SEND_COUNT = 0) OR (NVL(P_FORCE_YN,'N') = 'Y') OR
                   (C1.MAIL_SEND_COUNT > 0 AND (POWER(2,C1.MAIL_SEND_COUNT)/(60*24) + C1.LAST_UPDATED_ON) < SYSDATE) THEN
                    BACKGROUND( P_ID => C1.ID );
                END IF;
                WWV_FLOW_DEBUG.INFO( 'Pushed email: ' || C1.ID );
            EXCEPTION
                WHEN OTHERS THEN
                    WWV_FLOW_DEBUG.LOG_EXCEPTION;

                    IF L_LOCK_HDL IS NOT NULL THEN
                        L_STATUS := SYS.DBMS_LOCK.RELEASE( L_LOCK_HDL );
                        WWV_FLOW_DEBUG.INFO('APEX Mail released lock' );
                    END IF;
            END;
        END LOOP;
    END IF;



    IF L_LOCK_HDL IS NOT NULL THEN
        L_STATUS := SYS.DBMS_LOCK.RELEASE( L_LOCK_HDL );
        WWV_FLOW_DEBUG.INFO('APEX Mail released lock' );
    END IF;
EXCEPTION WHEN E_DB_SHUTDOWN THEN 
    NULL;
END PUSH_QUEUE_IMMEDIATE;

我正在尝试将 APEX_MAIL 复制到某个点，但如果这样做，我将无法正常工作。谁能指出 APEX_MAIL 在应用程序设置更改或任何其他更改后是否更改了作业的内容？

提前致谢！

Answer 1

APEX_MAIL.PUSH_QUEUE 可用于您自己的代码以立即发送您的邮件（在队列中）。该作业通常调用 PUSH_QUEUE_IMMEDIATE。我不知道您的设置是否曾经是安装错误或您网站上的错误。因此，事实上，它在单独的会话中调用 PUSH_QUEUE_IMMEDIATE 作为 APEX_040000 作业。

由于每个人都可以请求立即发送队列中的所有作业，它确保通过 SYS.DBMS_LOCK.REQUEST 只有一个会话会实际进行传输。

无法理解 APEX_MAIL 的作业如何运行

Unable to understand how APEX_MAIL's job runs

oracle

plsql

dbms-scheduler

oracle11g

oracle-apex